bin/tools/doxyFilt.awk

   1 # -----------------------------------------------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright held by original author
   6 #    \\/     M anipulation  |
   7 # -----------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     doxyFilt.awk
  27 #
  28 # Description
  29 #     Converts cocoon style sentinel strings into doxygen style strings
  30 #
  31 #     Assumes comment strings are formatted as follows
  32 #         //- general description
  33 #         //  more information
  34 #         //  and even more information
  35 #     This should be re-formatted as the following
  36 #         //! general description
  37 #         /*!
  38 #         more information
  39 #         and even more information
  40 #         */
  41 #     The intermediate "/*! ... */" block is left-justified to handle
  42 #     possible verbatim text
  43 # -----------------------------------------------------------------------------
  44
  45 BEGIN {
  46     state = 0
  47 }
  48
  49 /^ *\/\/-/ {
  50     state = 1
  51     sub(/\/\/-/, "//!")
  52     print
  53     next
  54 }
  55
  56
  57 /^ *\/\// {
  58     # start comment block
  59     if (state == 1)
  60     {
  61         printf "/*!\n"
  62         state = 2
  63     }
  64
  65     # inside comment block
  66     if (state == 2)
  67     {
  68         if (!sub(/^ *\/\/  /, ""))
  69         {
  70             sub(/^ *\/\//, "")
  71         }
  72     }
  73
  74     print
  75     next
  76 }
  77
  78
  79 {
  80     # end comment block
  81     if (state == 2)
  82     {
  83         printf "*/\n"
  84     }
  85     state = 0
  86     print
  87     next
  88 }
  89
  90 # -----------------------------------------------------------------------------