bin/tools/doxyFilt.sed

   1 # -----------------------------------------------------------------------------
   2 # Script
   3 #     doxyFilt.sed
   4 #
   5 # Description
   6 #     Transform human-readable tags such as 'Description' into the Doxygen
   7 #     equivalent
   8 # -----------------------------------------------------------------------------
   9
  10 /^License/,/\*\//{
  11 /^License/,/MA 0211.-130. USA/{
  12 s?^License.*?\*\/\
  13 \/\*! @file %filePath%\
  14 <b>Original source file</b> <a href="%filePath%">%fileName%</a>\
  15 ?
  16 /^    /d
  17 }
  18
  19 # remove entry
  20 /^Primitive *$/{
  21 N
  22 N
  23 d
  24 }
  25
  26 # remove entry
  27 /^Implementation *$/{
  28 N
  29 N
  30 d
  31 }
  32
  33 # remove entry
  34 /^Application *$/{
  35 N
  36 N
  37 d
  38 }
  39
  40 # remove entry
  41 /^Type *$/{
  42 N
  43 N
  44 d
  45 }
  46
  47 # remove entry
  48 /^Global *$/{
  49 N
  50 N
  51 d
  52 }
  53
  54
  55 # Class
  56 #     Foam::className
  57 # =>
  58 # @class Foam::className
  59 #
  60 /^Class *$/,/^[^ ]/{
  61 /^Class/d
  62 s/^    /@class /
  63 }
  64
  65
  66 # Namespace
  67 #     namespaceName
  68 # =>
  69 # @namespace namespaceName
  70 #
  71 /^Namespace *$/,/^[^ ]/{
  72 /^Namespace/d
  73 s/^    /@namespace /
  74 }
  75
  76
  77 # Typedef
  78 #     Foam::def
  79 # =>
  80 # @class Foam::def
  81 # This is not strictly correct, but makes it easier to find the typedefs
  82 /^Typedef *$/,/^[^ ]/{
  83 /^Typedef/d
  84 s/^    /@class /
  85 }
  86
  87
  88 # add anchor and use @brief
  89 # the first paragraph will be 'brief' and the others 'detail'
  90 /^Description *$/,/^[^ ]/{
  91 /^Description/c\
  92 <a class="anchor" name="Description"></a>\
  93 @brief
  94 s/^    //
  95 }
  96
  97 /^Usage *$/,/^[^ ]/{
  98 /^Usage/c\
  99 @par Usage
 100 s/^    //
 101 }
 102
 103
 104 /^See *Also *$/,/^[^ ]/{
 105 /^See *Also/c\
 106 @see
 107 s/^    //
 108 }
 109
 110 /^Author *$/,/^[^ ]/{
 111 /^Author/c\
 112 @author
 113 s/^    //
 114 }
 115
 116 /^Note *$/,/^[^ ]/{
 117 /^Note/c\
 118 @note
 119 s/^    //
 120 }
 121
 122
 123 /^To[Dd]o *$/,/^[^ ]/{
 124 /^To[Dd]o/c\
 125 @todo
 126 s/^    //
 127 }
 128
 129 /^Warning *$/,/^[^ ]/{
 130 /^Warning/c\
 131 @warning
 132 s/^    //
 133 }
 134
 135 /^Deprecated *$/,/^[^ ]/{
 136 /^Deprecated/c\
 137 @deprecated
 138 s/^    //
 139 }
 140
 141 /SourceFiles/,/^[ ]*$/{
 142 s?SourceFiles?@par Source files\
 143 <ul>\
 144   <li><a href="%filePath%">%fileName%</a></li>?
 145 s?^[ ]*$?</ul>\
 146 ?
 147 s? *\([a-zA-Z0-9]*\.[a-zA-Z]*\)?  <li><a href="%dirName%/\1">\1</a></li>?
 148 }
 149
 150 s/.*\*\//\*\//
 151
 152 }
 153
 154 # -----------------------------------------------------------------------------