etc/settings.csh

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright held by original author
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     etc/settings.csh
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from OpenFOAM-??/etc/cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 # prefix to PATH
  35 alias _foamAddPath 'set path=(\!* $path)'
  36 # prefix to LD_LIBRARY_PATH
  37 alias _foamAddLib 'setenv LD_LIBRARY_PATH \!*\:${LD_LIBRARY_PATH}'
  38
  39 # location of the jobControl directory
  40 setenv FOAM_JOB_DIR $WM_PROJECT_INST_DIR/jobControl
  41
  42 # wmake configuration
  43 setenv WM_DIR $WM_PROJECT_DIR/wmake
  44 setenv WM_LINK_LANGUAGE c++
  45 setenv WM_OPTIONS $WM_ARCH$WM_COMPILER$WM_PRECISION_OPTION$WM_COMPILE_OPTION
  46 set path=($WM_DIR $path)
  47
  48 #setenv WM_DECOMP_INC -DCELL_DECOMP
  49 #setenv WM_DECOMP_LIBS "-lcellDecompFiniteElement -lcellDecompositionMotionSolver"
  50 setenv WM_DECOMP_INC -DFACE_DECOMP
  51 setenv WM_DECOMP_LIBS "-lfaceDecompFiniteElement -lfaceDecompositionMotionSolver"
  52
  53 # base configuration
  54 setenv FOAM_APP $WM_PROJECT_DIR/applications
  55 setenv FOAM_APPBIN $WM_PROJECT_DIR/applications/bin/$WM_OPTIONS
  56 setenv FOAM_LIB $WM_PROJECT_DIR/lib
  57 setenv FOAM_LIBBIN $WM_PROJECT_DIR/lib/$WM_OPTIONS
  58 setenv FOAM_SRC $WM_PROJECT_DIR/src
  59
  60 # shared site configuration - similar naming convention as ~OpenFOAM expansion
  61 setenv FOAM_SITE_APPBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/bin/$WM_OPTIONS
  62 setenv FOAM_SITE_LIBBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/lib/$WM_OPTIONS
  63
  64 # user configuration
  65 setenv FOAM_USER_APPBIN $WM_PROJECT_USER_DIR/applications/bin/$WM_OPTIONS
  66 setenv FOAM_USER_LIBBIN $WM_PROJECT_USER_DIR/lib/$WM_OPTIONS
  67
  68 # convenience
  69 setenv FOAM_TUTORIALS $WM_PROJECT_DIR/tutorials
  70 setenv FOAM_UTILITIES $FOAM_APP/utilities
  71 setenv FOAM_SOLVERS $FOAM_APP/solvers
  72 setenv FOAM_RUN $WM_PROJECT_USER_DIR/run
  73
  74 # add OpenFOAM scripts and wmake to the path
  75 set path=($WM_DIR $WM_PROJECT_DIR/bin $path)
  76
  77 _foamAddPath $FOAM_APPBIN
  78 _foamAddPath $FOAM_SITE_APPBIN
  79 _foamAddPath $FOAM_USER_APPBIN
  80  # Make sure to pick up dummy versions of external libraries last
  81 _foamAddLib  $FOAM_LIBBIN/dummy
  82 _foamAddLib  $FOAM_LIBBIN
  83 _foamAddLib  $FOAM_SITE_LIBBIN
  84 _foamAddLib  $FOAM_USER_LIBBIN
  85
  86
  87 # Select compiler installation
  88 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  89 # compilerInstall = OpenFOAM | System
  90 #set compilerInstall=OpenFOAM
  91 #set compilerInstall=System
  92 if ( ! $?compilerInstall ) then
  93     setenv compilerInstall System
  94 endif
  95
  96 switch ("$compilerInstall")
  97 case OpenFOAM:
  98     switch ("$WM_COMPILER")
  99     case Gcc:
 100         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.3.3/platforms/$WM_ARCH$WM_COMPILER_ARCH
 101         _foamAddLib $WM_THIRD_PARTY_DIR/mpfr-2.4.1/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
 102         _foamAddLib $WM_THIRD_PARTY_DIR/gmp-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
 103     breaksw
 104     case Gcc45:
 105         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.5.1/platforms/$WM_OPTIONS
 106         _foamSource  $WM_THIRD_PARTY_DIR/packages/gmp-5.0.1/platforms/$WM_OPTIONS/etc/gmp-5.0.1.csh
 107         _foamSource  $WM_THIRD_PARTY_DIR/packages/mpfr-3.0.1/platforms/$WM_OPTIONS/etc/mpfr-3.0.1.csh
 108         _foamSource  $WM_THIRD_PARTY_DIR/packages/mpc-0.8.2/platforms/$WM_OPTIONS/etc/mpc-0.8.2.csh
 109         _foamSource  $WM_THIRD_PARTY_DIR/packages/gcc-4.5.1/platforms/$WM_OPTIONS/etc/gcc-4.5.1.csh
 110     breaksw
 111     case Gcc44:
 112         _foamSource  $WM_THIRD_PARTY_DIR/packages/mpfr-3.0.1/platforms/$WM_OPTIONS/etc/mpfr-3.0.1.csh
 113         _foamSource  $WM_THIRD_PARTY_DIR/packages/gmp-5.0.1/platforms/$WM_OPTIONS/etc/gmp-5.0.1.csh
 114         _foamSource  $WM_THIRD_PARTY_DIR/packages/gcc-4.4.5/platforms/$WM_OPTIONS/etc/gcc-4.4.5.csh
 115     breaksw
 116     case Gcc43:
 117         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.3.3/platforms/$WM_ARCH$WM_COMPILER_ARCH
 118         _foamAddLib $WM_THIRD_PARTY_DIR/mpfr-2.4.1/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
 119         _foamAddLib $WM_THIRD_PARTY_DIR/gmp-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
 120     breaksw
 121     case Gcc42:
 122         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH
 123     breaksw
 124     endsw
 125
 126     # Check that the compiler directory can be found
 127     if ( ! -d "$WM_COMPILER_DIR" ) then
 128         echo
 129         echo "Warning in $WM_PROJECT_DIR/etc/settings.csh:"
 130         echo "    Cannot find $WM_COMPILER_DIR installation."
 131         echo "    Please install this compiler version or if you wish to use the system compiler,"
 132         echo "    change the 'compilerInstall' setting to 'System' in this file"
 133         echo
 134     endif
 135
 136     _foamAddPath ${WM_COMPILER_DIR}/bin
 137     _foamAddLib  ${WM_COMPILER_DIR}/lib${WM_COMPILER_LIB_ARCH}
 138     _foamAddLib  ${WM_COMPILER_DIR}/lib
 139
 140     breaksw
 141 endsw
 142
 143
 144 switch ("$WM_COMPILER")
 145 case Gcc*:
 146     setenv WM_CC 'gcc'
 147     setenv WM_CXX 'g++'
 148     breaksw
 149 case Icc:
 150     setenv WM_CC 'icc'
 151     setenv WM_CXX 'icpc'
 152     breaksw
 153 endsw
 154
 155 # Communications library
 156 # ~~~~~~~~~~~~~~~~~~~~~~
 157
 158 unset MPI_ARCH_PATH
 159
 160 set mpi_version=unknown
 161
 162 switch ("$WM_MPLIB")
 163 case OPENMPI:
 164     if (-d $WM_THIRD_PARTY_DIR/packages/openmpi-1.4.3/platforms/$WM_OPTIONS ) then
 165         set mpi_version=openmpi-1.4.3
 166
 167         if ($?FOAM_VERBOSE && $?prompt) then
 168             echo "Using openmpi-1.4.3 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 169         endif
 170         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 171
 172     else if (-d $WM_THIRD_PARTY_DIR/packages/openmpi-1.5/platforms/$WM_OPTIONS ) then
 173         set mpi_version=openmpi-1.5
 174
 175         if ($?FOAM_VERBOSE && $?prompt) then
 176             echo "Using openmpi-1.5 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 177         endif
 178         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 179     endif
 180
 181     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 182     unset mpi_version
 183     breaksw
 184
 185 case SYSTEMOPENMPI:
 186     set mpi_version=openmpi-system
 187
 188     # make sure not the "old" mpi is used
 189     # Not sure if this is necessary anymore.
 190     # export OPAL_PREFIX=
 191
 192     # Make sure OPENMPI_BIN_DIR is set and valid
 193     if ($?OPENMPI_BIN_DIR != 0 ) then
 194         if (-d "${OPENMPI_BIN_DIR}" ) then
 195             # User defined value specified for OPENMPI_BIN_DIR
 196             #
 197             # WARNING:
 198             #          We assume this path specified by $OPENMPI_BIN_DIR is valid
 199             #          We assume the command mpicc is located somewhere under this path
 200             #          We assume the file mpi.h is located somewhere under this path
 201             #
 202             #          Otherwise, please double check your openmpi installation, you are
 203             #          probably missing the openmpi runtime and/or development packages
 204             #          available for your system.
 205             #
 206             _foamAddPath $OPENMPI_BIN_DIR
 207          endif
 208     else
 209         # Here, we assume your environment is already set for running
 210         # and developping with openmpi.
 211         #
 212         # Initialize OPENMPI_BIN_DIR using the path to mpicc
 213         set mpicc_cmd=`which mpicc`
 214         setenv OPENMPI_BIN_DIR `dirname $mpicc_cmd`
 215         unset mpicc_cmd
 216     endif
 217
 218     # Make sure OPENMPI_LIB_DIR is set
 219     if ( $?OPENMPI_LIB_DIR == 0 ) then
 220         # Initialize OPENMPI_LIB_DIR using the path to mpicc
 221         setenv OPENMPI_LIB_DIR "`mpicc --showme:libdirs`"
 222     endif
 223
 224     # Make sure the dynamic libraries are accessible
 225     if( $?OPENMPI_LIB_DIR != 0 ) then
 226         _foamAddLib $OPENMPI_LIB_DIR
 227     endif
 228
 229     setenv MPI_HOME `dirname $OPENMPI_BIN_DIR`
 230     setenv MPI_ARCH_PATH $MPI_HOME
 231     setenv OPAL_PREFIX $MPI_ARCH_PATH
 232
 233     # We initialize the rest of the environment using mpicc --showme:
 234     if ($?OPENMPI_INCLUDE_DIR == 0) then
 235         setenv OPENMPI_INCLUDE_DIR "`mpicc --showme:incdirs`"
 236     endif
 237
 238     if (${?OPENMPI_COMPILE_FLAGS} == 0) then
 239         setenv OPENMPI_COMPILE_FLAGS "`mpicc --showme:compile`"
 240     endif
 241
 242     if (${?OPENMPI_COMPILE_FLAGS} == 0) then
 243         setenv OPENMPI_COMPILE_FLAGS "`mpicc --showme:compile`"
 244     endif
 245
 246     if (${?OPENMPI_LINK_FLAGS} == 0) then
 247         setenv OPENMPI_LINK_FLAGS "`mpicc --showme:link`"
 248     endif
 249
 250     #
 251     # WARNING: We assume the file mpi.h will be available under the directories identified
 252     #          by the variable $OPENMPI_INCLUDE_DIR. Otherwise, please double check your
 253     #          system openmpi installation.
 254
 255     # Set compilation flags here instead of in wmake/rules/../mplibSYSTEMOPENMPI
 256     setenv PINC "$OPENMPI_COMPILE_FLAGS"
 257     setenv PLIBS "$OPENMPI_LINK_FLAGS"
 258
 259     # No longer needed, but we keep this as a reference, just in case...
 260     #libDir `echo "$PLIBS" | sed -e 's/.*-L\([^ ]*\).*/\1/'`
 261     #_foamAddLib $libDir
 262
 263     if ($?FOAM_VERBOSE && $?prompt) then
 264         echo "Using system installed OpenMPI:"
 265         echo "    OPENMPI_BIN_DIR       : $OPENMPI_BIN_DIR"
 266         echo "    OPENMPI_LIB_DIR       : $OPENMPI_LIB_DIR"
 267         echo "    OPENMPI_INCLUDE_DIR   : $OPENMPI_INCLUDE_DIR"
 268         echo "    OPENMPI_COMPILE_FLAGS : $OPENMPI_COMPILE_FLAGS"
 269         echo "    OPENMPI_LINK_FLAGS    : $OPENMPI_LINK_FLAGS"
 270         echo ""
 271         echo "    MPI_HOME              : $MPI_HOME"
 272         echo "    MPI_ARCH_PATH         : $MPI_ARCH_PATH"
 273         echo "    OPAL_PREFIX           : $OPAL_PREFIX"
 274         echo "    PINC                  : $PINC"
 275         echo "    PLIBS                 : $PLIBS"
 276     endif
 277
 278     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 279     unset mpi_version
 280     breaksw
 281
 282 case MPICH:
 283     set mpi_version=mpich-1.2.4
 284     setenv MPI_HOME $WM_THIRD_PARTY_DIR/$mpi_version
 285     setenv MPI_ARCH_PATH $MPI_HOME/platforms/$WM_OPTIONS
 286     setenv MPICH_ROOT $MPI_ARCH_PATH
 287
 288     _foamAddPath $MPI_ARCH_PATH/bin
 289     _foamAddLib  $MPI_ARCH_PATH/lib
 290
 291     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 292     unset mpi_version
 293     breaksw
 294
 295 case MPICH-GM:
 296     setenv MPI_ARCH_PATH /opt/mpi
 297     setenv MPICH_PATH $MPI_ARCH_PATH
 298     setenv MPICH_ROOT $MPI_ARCH_PATH
 299     setenv GM_LIB_PATH /opt/gm/lib64
 300
 301     _foamAddPath $MPI_ARCH_PATH/bin
 302     _foamAddLib  $MPI_ARCH_PATH/lib
 303     _foamAddLib  $GM_LIB_PATH
 304
 305     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpich-gm
 306     breaksw
 307
 308 case HPMPI:
 309     setenv MPI_HOME /opt/hpmpi
 310     setenv MPI_ARCH_PATH $MPI_HOME
 311     setenv MPICH_ROOT=$MPI_ARCH_PATH
 312
 313     _foamAddPath $MPI_ARCH_PATH/bin
 314
 315     switch (`uname -m`)
 316     case i686:
 317         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia32
 318         breaksw
 319     case x86_64:
 320         _foamAddLib $MPI_ARCH_PATH/lib/linux_amd64
 321         breaksw
 322     case ia64:
 323         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia64
 324         breaksw
 325     default:
 326         echo Unknown processor type `uname -m` for Linux
 327         breaksw
 328     endsw
 329
 330     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/hpmpi
 331     breaksw
 332
 333 case GAMMA:
 334     setenv MPI_ARCH_PATH /usr
 335     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/gamma
 336     breaksw
 337
 338 case MPI:
 339     setenv MPI_ARCH_PATH /opt/mpi
 340     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpi
 341     breaksw
 342
 343 case FJMPI:
 344     setenv MPI_ARCH_PATH /opt/FJSVmpi2
 345     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpi
 346     _foamAddPath $MPI_ARCH_PATH/bin
 347     _foamAddLib  $MPI_ARCH_PATH/lib/sparcv9
 348     _foamAddLib  /opt/FSUNf90/lib/sparcv9
 349     _foamAddLib  /opt/FJSVpnidt/lib
 350     breaksw
 351
 352 case QSMPI:
 353     setenv MPI_ARCH_PATH /usr/lib/mpi
 354     setenv FOAM_MPI_LIBBIN FOAM_LIBBIN/qsmpi
 355
 356     _foamAddPath $MPI_ARCH_PATH/bin
 357     _foamAddLib $MPI_ARCH_PATH/lib
 358
 359     breaksw
 360
 361 default:
 362     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/dummy
 363     breaksw
 364 endsw
 365
 366 _foamAddLib $FOAM_MPI_LIBBIN
 367
 368
 369 # Set the minimum MPI buffer size (used by all platforms except SGI MPI)
 370 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 371 set minBufferSize=20000000
 372
 373 if ( $?MPI_BUFFER_SIZE ) then
 374     if ( $MPI_BUFFER_SIZE < $minBufferSize ) then
 375         setenv MPI_BUFFER_SIZE $minBufferSize
 376     endif
 377 else
 378     setenv MPI_BUFFER_SIZE $minBufferSize
 379 endif
 380
 381
 382 # CGAL library if available
 383 # ~~~~~~~~~~~~~~~~~~~~~~~~~
 384 if ( $?CGAL_LIB_DIR ) then
 385     _foamAddLib $CGAL_LIB_DIR
 386 endif
 387
 388 # Mesquite library if available
 389 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 390 if ( $?MESQUITE_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/mesquite-2.1.2/platforms/$WM_OPTIONS ) then
 391     _foamSource $WM_THIRD_PARTY_DIR/packages/mesquite-2.1.2/platforms/$WM_OPTIONS/etc/mesquite-2.1.2.csh
 392 endif
 393
 394 # Metis library if available
 395 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 396 if ( $?METIS_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/metis-5.0pre2/platforms/$WM_OPTIONS ) then
 397     _foamSource $WM_THIRD_PARTY_DIR/packages/metis-5.0pre2/platforms/$WM_OPTIONS/etc/metis-5.0pre2.csh
 398 endif
 399
 400 # ParMetis library if available
 401 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 402 if ( $?PARMETIS_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/ParMetis-3.1.1/platforms/$WM_OPTIONS ) then
 403     _foamSource $WM_THIRD_PARTY_DIR/packages/ParMetis-3.1.1/platforms/$WM_OPTIONS/etc/ParMetis-3.1.1.csh
 404 endif
 405
 406 # ParMGridGen library if available
 407 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 408 if ( $?PARMGRIDGEN_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/ParMGridGen-1.0/platforms/$WM_OPTIONS ) then
 409     _foamSource $WM_THIRD_PARTY_DIR/packages/ParMGridGen-1.0/platforms/$WM_OPTIONS/etc/ParMGridGen-1.0.csh
 410 endif
 411
 412 # Load Libccmio library
 413 # ~~~~~~~~~~~~~~~~~~~~~
 414 if ( $?LIBCCMIO_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/libccmio-2.6.1/platforms/$WM_OPTIONS ) then
 415     _foamSource $WM_THIRD_PARTY_DIR/packages/libccmio-2.6.1/platforms/$WM_OPTIONS/etc/libccmio-2.6.1.csh
 416 endif
 417
 418
 419 # Scotch library if available
 420 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 421 if ( $?SCOTCH_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/scotch-5.1.10b/platforms/$WM_OPTIONS ) then
 422     _foamSource $WM_THIRD_PARTY_DIR/packages/scotch-5.1.10b/platforms/$WM_OPTIONS/etc/scotch-5.1.10b.csh
 423 endif
 424
 425 # Switch on the hoard memory allocator if available
 426 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 427 #if ( -f $FOAM_LIBBIN/libhoard.so ) then
 428 #    setenv LD_PRELOAD $FOAM_LIBBIN/libhoard.so:${LD_PRELOAD}
 429 #endif
 430
 431 # Third party packages
 432
 433 # cmake
 434 # ~~~~~
 435 if ( $?CMAKE_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/cmake-2.8.8/platforms/$WM_OPTIONS ) then
 436     _foamSource $WM_THIRD_PARTY_DIR/packages/cmake-2.8.8/platforms/$WM_OPTIONS/etc/cmake-2.8.8.csh
 437 endif
 438
 439 # Python
 440 # ~~~~~
 441 if ( $?PYTHON_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/Python-2.7/platforms/$WM_OPTIONS ) then
 442     _foamSource $WM_THIRD_PARTY_DIR/packages/Python-2.7/platforms/$WM_OPTIONS/etc/Python-2.7.csh
 443 endif
 444
 445 # QT
 446 # ~~~~~
 447 if ( $?QT_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/qt-everywhere-opensource-src-4.7.4/platforms/$WM_OPTIONS )then
 448     _foamSource $WM_THIRD_PARTY_DIR/packages/qt-everywhere-opensource-src-4.7.4/platforms/$WM_OPTIONS/etc/qt-everywhere-opensource-src-4.7.4.csh
 449 endif
 450
 451 # PARAVIEW
 452 # ~~~~~
 453 if ( $?PARAVIEW_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.12.0/platforms/$WM_OPTIONS ) then
 454     _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.12.0/platforms/$WM_OPTIONS/etc/ParaView-3.12.0.csh
 455 #if ( $?PARAVIEW_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.8.1/platforms/$WM_OPTIONS ) then
 456 #    _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.8.1/platforms/$WM_OPTIONS/etc/ParaView-3.8.1.csh
 457 endif
 458
 459 if ( $WM_ARCH == "darwinIntel" || $WM_ARCH == "darwinIntel64" ) then
 460     setenv DYLD_LIBRARY_PATH ${LD_LIBRARY_PATH}
 461 endif
 462
 463 # cleanup environment:
 464 # ~~~~~~~~~~~~~~~~~~~~
 465 unalias _foamAddPath
 466 unalias _foamAddLib
 467 unset minBufferSize
 468
 469 # -----------------------------------------------------------------------------