etc/cshrc

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright held by original author
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     etc/cshrc
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from ~/.login or ~/.cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 setenv WM_PROJECT OpenFOAM
  35 setenv WM_PROJECT_VERSION 1.6-ext
  36
  37 # helps to easily write #ifdefs to detect a dev-version
  38 setenv FOAM_DEV 1
  39
  40 ###############################################################################
  41 # USER EDITABLE PART
  42 #
  43 #    either setenv FOAM_INST_DIR before sourcing this file or set
  44 #    foamInstall below to where OpenFOAM is installed
  45 #
  46 # Location of FOAM installation
  47 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  48 set foamInstall = $HOME/$WM_PROJECT
  49 # set foamInstall = ~$WM_PROJECT
  50 # set foamInstall = /usr/local/$WM_PROJECT
  51 # set foamInstall = /opt/$WM_PROJECT
  52 #
  53 # END OF (NORMAL) USER EDITABLE PART
  54 ###############################################################################
  55
  56 # note the location for later use (eg, in job scripts)
  57 if ( ! $?FOAM_INST_DIR ) setenv FOAM_INST_DIR $foamInstall
  58
  59 # The old dirs to be cleaned from the various environment variables
  60 # - remove anything under top-level directory.
  61 # NB: the WM_PROJECT_INST_DIR might not be identical between versions
  62 set foamOldDirs="$FOAM_INST_DIR $HOME/$WM_PROJECT/$LOGNAME"
  63
  64 # Location of site/user files
  65 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  66 setenv WM_PROJECT_INST_DIR $FOAM_INST_DIR
  67 setenv WM_PROJECT_DIR $WM_PROJECT_INST_DIR/$WM_PROJECT-$WM_PROJECT_VERSION
  68 setenv WM_PROJECT_USER_DIR $HOME/$WM_PROJECT/$LOGNAME-$WM_PROJECT_VERSION
  69
  70
  71 # Location of third-party software
  72 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  73 #setenv WM_THIRD_PARTY_DIR $WM_PROJECT_INST_DIR/ThirdParty-$WM_PROJECT_VERSION
  74 setenv WM_THIRD_PARTY_DIR $WM_PROJECT_DIR/ThirdParty
  75
  76 # Source files, possibly with some verbosity
  77 alias _foamSource 'if ($?FOAM_VERBOSE && $?prompt) echo "Sourcing: \!*"; source \!*'
  78
  79 # Add in preset user or site preferences:
  80 set foamPrefs=`$WM_PROJECT_DIR/bin/foamEtcFile prefs.csh`
  81 if ( $status == 0 ) then
  82     _foamSource $foamPrefs
  83 endif
  84 unset foamPrefs
  85
  86 # Evaluate command-line parameters
  87 while ( $#argv > 0 )
  88     switch ($argv[1])
  89     case *=:
  90         # name=       -> unsetenv name
  91         eval "unsetenv $argv[1]:s/=//"
  92         breaksw
  93     case *=*:
  94         # name=value  -> setenv name value
  95         eval "setenv $argv[1]:s/=/ /"
  96         breaksw
  97     endsw
  98     shift
  99 end
 100
 101
 102 # Operating System/Platform
 103 # ~~~~~~~~~~~~~~~~~~~~~~~~~
 104 # WM_OSTYPE = POSIX | ????
 105 if ( ! $?WM_OSTYPE ) setenv WM_OSTYPE POSIX
 106
 107
 108 # Compiler: set to Gcc, Gcc43 or Icc (for Intel's icc)
 109 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 110 #if ( ! $?WM_COMPILER ) setenv WM_COMPILER Gcc
 111 setenv WM_COMPILER Gcc
 112 #setenv WM_COMPILER Icc
 113
 114 setenv WM_COMPILER_ARCH
 115 setenv WM_COMPILER_LIB_ARCH
 116
 117
 118 # Compilation options (architecture, precision, optimised, debug or profiling)
 119 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 120 setenv WM_NCOMPPROCS 4
 121
 122 # WM_ARCH_OPTION = 32 | 64
 123 if ( ! $?WM_ARCH_OPTION ) setenv WM_ARCH_OPTION 64
 124
 125 # WM_PRECISION_OPTION = DP | SP
 126 if ( ! $?WM_PRECISION_OPTION ) setenv WM_PRECISION_OPTION DP
 127
 128 # WM_COMPILE_OPTION = Opt | Debug | Prof
 129 #if ( ! $?WM_COMPILE_OPTION ) setenv WM_COMPILE_OPTION Opt
 130 setenv WM_COMPILE_OPTION Opt
 131 #setenv WM_COMPILE_OPTION Debug
 132
 133 # WM_MPLIB = | OPENMPI | MPICH | MPICH-GM | HPMPI | GAMMA | MPI | QSMPI
 134 if ( ! $?WM_MPLIB ) setenv WM_MPLIB OPENMPI
 135
 136
 137 # Run options (floating-point signal handling and memory initialisation)
 138 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 139 setenv FOAM_SIGFPE
 140 # setenv FOAM_SETNAN
 141
 142
 143 # Detect system type and set environment variables
 144 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 145 setenv WM_ARCH `uname -s`
 146
 147 switch ($WM_ARCH)
 148 case Linux:
 149     setenv WM_ARCH linux
 150
 151     switch (`uname -m`)
 152     case i686:
 153         breaksw
 154
 155     case x86_64:
 156         switch ($WM_ARCH_OPTION)
 157         case 32:
 158             setenv WM_ARCH linux
 159             setenv WM_COMPILER_ARCH '-64'
 160             setenv WM_CFLAGS '-m32 -fPIC'
 161             setenv WM_CXXFLAGS '-m32 -fPIC'
 162             setenv WM_LDFLAGS '-m32'
 163             breaksw
 164
 165         case 64:
 166             setenv WM_ARCH linux64
 167             setenv WM_COMPILER_LIB_ARCH 64
 168             setenv WM_CFLAGS '-m64 -fPIC'
 169             setenv WM_CXXFLAGS '-m64 -fPIC'
 170             setenv WM_LDFLAGS '-m64'
 171             breaksw
 172
 173         default:
 174             echo Unknown WM_ARCH_OPTION $WM_ARCH_OPTION, should be 32 or 64
 175             breaksw
 176
 177         endsw
 178         breaksw
 179
 180     case ia64:
 181         setenv WM_ARCH linuxIA64
 182         setenv WM_COMPILER I64
 183         breaksw
 184
 185     case mips64:
 186         setenv WM_ARCH SiCortex64
 187         setenv WM_COMPILER_LIB_ARCH 64
 188         setenv WM_CFLAGS '-mabi=64 -fPIC'
 189         setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 190         setenv WM_LDFLAGS '-mabi=64 -G0'
 191         setenv WM_MPLIB MPI
 192         ;;
 193
 194     case ppc64:
 195         setenv WM_ARCH linuxPPC64
 196         setenv WM_COMPILER_LIB_ARCH 64
 197         setenv WM_CFLAGS '-m64 -fPIC'
 198         setenv WM_CXXFLAGS '-m64 -fPIC'
 199         setenv WM_LDFLAGS '-m64'
 200         breaksw
 201
 202     default:
 203         echo Unknown processor type `uname -m` for Linux
 204         breaksw
 205
 206     endsw
 207     breaksw
 208
 209 case Darwin:
 210     switch (`uname -p`)
 211     case powerpc:
 212         setenv WM_ARCH darwinPpc
 213         breaksw
 214     case i386:
 215         setenv WM_ARCH darwinIntel
 216         breaksw
 217     default:
 218         echo "This seems to be an Intel-Mac please tell me the output of 'uname -p'. Bernhard."
 219         setenv WM_ARCH darwinIntel
 220         breaksw
 221     endsw
 222     switch ($WM_ARCH_OPTION)
 223     case 32:
 224         setenv WM_CFLAGS '-m32 -fPIC'
 225         setenv WM_CXXFLAGS '-m32 -fPIC'
 226         setenv WM_LDFLAGS '-m32'
 227         breaksw;
 228     case 64:
 229         setenv WM_ARCH ${WM_ARCH}64
 230         setenv WM_CFLAGS '-m64 -fPIC'
 231         setenv WM_CXXFLAGS '-m64 -fPIC'
 232         setenv WM_LDFLAGS '-m64'
 233         breaksw;
 234     default:
 235         echo "Unknown WM_ARCH_OPTION $WM_ARCH_OPTION, should be 32 or 64"
 236         breaksw
 237     endsw
 238
 239     # Make sure that binaries use the best features of the used OS-Version
 240     setenv MACOSX_DEPLOYMENT_TARGET `sw_vers -productVersion`
 241
 242     # Use Mac-Ports-Compiler instead of Apple-gcc-4.2
 243     switch ($WM_COMPILER)
 244     case Gcc43:
 245         setenv WM_CC 'gcc-mp-4.3'
 246         setenv WM_CXX 'g++-mp-4.3'
 247         breaksw;
 248     case Gcc44:
 249         setenv WM_CC 'gcc-mp-4.4'
 250         setenv WM_CXX 'g++-mp-4.4'
 251         breaksw;
 252     case Gcc45:
 253         setenv WM_CC 'gcc-mp-4.5'
 254         setenv WM_CXX 'g++-mp-4.5'
 255         breaksw;
 256     endsw
 257     setenv WM_COMPILER ""
 258     breaksw
 259
 260 case SunOS:
 261     setenv WM_ARCH SunOS64
 262     setenv WM_COMPILER_LIB_ARCH 64
 263     setenv WM_CFLAGS '-mabi=64 -fPIC'
 264     setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 265     setenv WM_LDFLAGS '-mabi=64 -G0'
 266     setenv WM_MPLIB FJMPI
 267     breaksw
 268
 269 default:
 270     echo
 271     echo "Your '$WM_ARCH' operating system is not supported by this release"
 272     echo "of OpenFOAM. For further assistance, please contact www.OpenFOAM.org"
 273     echo
 274     breaksw
 275
 276 endsw
 277
 278
 279 # Clean standard environment variables (path/PATH, LD_LIBRARY_PATH, MANPATH)
 280 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 281 set cleanProg=$WM_PROJECT_DIR/bin/foamCleanPath
 282
 283 if (! $?LD_LIBRARY_PATH ) then
 284     setenv LD_LIBRARY_PATH ''
 285 endif
 286 if (! $?MANPATH) then
 287     setenv MANPATH ''
 288 endif
 289
 290 #- Clean path/PATH
 291 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 292 set cleanEnv=`$cleanProg "$colonPath" "$foamOldDirs"`
 293 if ( $status == 0 ) then
 294     set path=`echo "$cleanEnv" | sed -e 's/:/ /g'`
 295 endif
 296
 297 #- Clean LD_LIBRARY_PATH
 298 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH" "$foamOldDirs"`
 299
 300 #- Clean MANPATH
 301 setenv MANPATH `$cleanProg "$MANPATH" "$foamOldDirs"`
 302
 303
 304 # Source project setup files
 305 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 306 _foamSource $WM_PROJECT_DIR/etc/settings.csh
 307 _foamSource $WM_PROJECT_DIR/etc/aliases.csh
 308
 309 # Source user setup files for optional packages
 310 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 311 # _foamSource $WM_PROJECT_DIR/etc/apps/paraview/cshrc
 312 #_foamSource $WM_PROJECT_DIR/etc/apps/paraview3/cshrc
 313 # _foamSource $WM_PROJECT_DIR/etc/apps/ensight/cshrc
 314
 315
 316 # Clean environment paths again. Only remove duplicates
 317 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 318 #- Clean path/PATH
 319 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 320 set cleanEnv=`$cleanProg "$colonPath"`
 321 if ( $status == 0 ) then
 322     set path=`echo "$cleanEnv" | sed -e 's/:/ /g'`
 323 endif
 324
 325 #- Clean LD_LIBRARY_PATH
 326 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH"`
 327
 328 #- Clean MANPATH
 329 setenv MANPATH `$cleanProg "$MANPATH"`:
 330
 331 #- Clean LD_PRELOAD
 332 if ( $?LD_PRELOAD ) then
 333     setenv LD_PRELOAD `$cleanProg "$LD_PRELOAD"`
 334 endif
 335
 336 #- Clean DYLD_LIBRARY_PATH
 337 if ( $?DYLD_LIBRARY_PATH ) then
 338     setenv DYLD_LIBRARY_PATH `$cleanProg "$DYLD_LIBRARY_PATH"`
 339 endif
 340
 341 # cleanup environment:
 342 # ~~~~~~~~~~~~~~~~~~~~
 343 unset cleanEnv cleanProg colonPath foamInstall foamOldDirs
 344 unalias _foamSource
 345
 346 # -----------------------------------------------------------------------------
 347