bin/tools/doxyFilter.sed

   1 # -----------------------------------------------------------------------------
   2 # Script
   3 #     doxyFilter.sed
   4 #
   5 # Description
   6 #     Transform human-readable tags such as 'Description' into the Doxygen
   7 #     equivalent
   8 # -----------------------------------------------------------------------------
   9
  10 # new FSF address
  11 /^License/,/\*\//{
  12 /^License/,\%http://www.gnu.org/licenses%{
  13 s?^License.*?\*\/\
  14 \/\*! \\file %filePath%\
  15 <b>Original source file</b> <a href="%filePath%">%fileName%</a>\
  16 \
  17 \
  18 \
  19 \
  20 \
  21 \
  22 \
  23 \
  24 ?
  25 /^    /d
  26 }
  27
  28
  29 # remove entry
  30 /^Application *$/{
  31 N
  32 N
  33 d
  34 }
  35
  36
  37 # remove entry
  38 /^Global *$/{
  39 N
  40 N
  41 d
  42 }
  43
  44
  45 # Primitive
  46 #     typename
  47 # =>
  48 # \\relates typename
  49 #
  50 /^Primitive *$/,/^[^ ]/{
  51 s/^Primitive *$//
  52 s/^    /\\relates /
  53 }
  54
  55
  56 # Class
  57 #     Foam::className
  58 # =>
  59 # \\class Foam::className
  60 #
  61 /^Class *$/,/^[^ ]/{
  62 s/^Class *$//
  63 s/^    /\\class /
  64 }
  65
  66
  67 # Namespace
  68 #     namespaceName
  69 # =>
  70 # \namespace namespaceName
  71 #
  72 /^Namespace *$/,/^[^ ]/{
  73 s/^Namespace//
  74 s/^    /\\namespace /
  75 }
  76
  77
  78 # Typedef
  79 #     Foam::def
  80 # =>
  81 # \typedef Foam::def
  82 /^Typedef *$/,/^[^ ]/{
  83 s/^Typedef//
  84 s/^    /\\typedef /
  85 }
  86
  87
  88 # add anchor and use \brief
  89 # the first paragraph will be 'brief' and the others 'detail'
  90 /^Description *$/,/^[^ ]/{
  91 /^Description/c\
  92 <a class="anchor" name="Description"></a> \\brief
  93 s/^    //
  94 }
  95
  96 /^Usage *$/,/^[^ ]/{
  97 /^Usage/c\
  98 \\par Usage
  99 s/^    //
 100 }
 101
 102
 103 /^See *Also *$/,/^[^ ]/{
 104 /^See *Also/c\
 105 \\see
 106 s/^    //
 107 }
 108
 109 /^Note *$/,/^[^ ]/{
 110 /^Note/c\
 111 \\note
 112 s/^    //
 113 }
 114
 115
 116 # remove ToDo paragraph to avoid them showing on related pages
 117 /^To[Dd]o *$/,/^[^ ]/{
 118 s/^To[Dd]o *$//
 119 s/^    .*//
 120 }
 121
 122
 123 /^Warning *$/,/^[^ ]/{
 124 /^Warning/c\
 125 \\warning
 126 s/^    //
 127 }
 128
 129
 130 /^Deprecated *$/,/^[^ ]/{
 131 /^Deprecated/c\
 132 \\deprecated
 133 s/^    //
 134 }
 135
 136
 137 /^SourceFiles *$/,/^$/{
 138 s?SourceFiles?\\par Source files\
 139 <ul><li><a href="%filePath%">%fileName%</a></li>?
 140 s? *\([a-zA-Z0-9]*\.[a-zA-Z]*\)?  <li><a href="%dirName%/\1">\1</a></li>?
 141 s?^$?</ul>?
 142 }
 143
 144 /fileName%<\/a><\/li>$/{
 145 N
 146 s?\n$?</ul>?g
 147 s/<\/li>\n/<\/li> /
 148 s? *\([a-zA-Z0-9]*\.[a-zA-Z]*\)?  <li><a href="%dirName%/\1">\1</a></li>?
 149 }
 150
 151 s/.*\*\//\*\//
 152
 153 }
 154
 155 # -----------------------------------------------------------------------------