config/perl.m4

   1 # $PostgreSQL$
   2
   3
   4 # PGAC_PATH_PERL
   5 # --------------
   6 AC_DEFUN([PGAC_PATH_PERL],
   7 [AC_PATH_PROG(PERL, perl)])
   8
   9
  10 # PGAC_CHECK_PERL_CONFIG(NAME)
  11 # ----------------------------
  12 AC_DEFUN([PGAC_CHECK_PERL_CONFIG],
  13 [AC_REQUIRE([PGAC_PATH_PERL])
  14 AC_MSG_CHECKING([for Perl $1])
  15 perl_$1=`$PERL -MConfig -e 'print $Config{$1}'`
  16 AC_SUBST(perl_$1)dnl
  17 AC_MSG_RESULT([$perl_$1])])
  18
  19
  20 # PGAC_CHECK_PERL_CONFIGS(NAMES)
  21 # ------------------------------
  22 AC_DEFUN([PGAC_CHECK_PERL_CONFIGS],
  23 [m4_foreach([pgac_item], [$1], [PGAC_CHECK_PERL_CONFIG(pgac_item)])])
  24
  25
  26 # PGAC_CHECK_PERL_EMBED_LDFLAGS
  27 # -----------------------------
  28 AC_DEFUN([PGAC_CHECK_PERL_EMBED_LDFLAGS],
  29 [AC_REQUIRE([PGAC_PATH_PERL])
  30 AC_MSG_CHECKING(for flags to link embedded Perl)
  31 pgac_tmp1=`$PERL -MExtUtils::Embed -e ldopts`
  32 pgac_tmp2=`$PERL -MConfig -e 'print $Config{ccdlflags}'`
  33 perl_embed_ldflags=`echo X"$pgac_tmp1" | sed "s/^X//;s%$pgac_tmp2%%"`
  34 AC_SUBST(perl_embed_ldflags)dnl
  35 if test -z "$perl_embed_ldflags" ; then
  36         AC_MSG_RESULT(no)
  37         AC_MSG_ERROR([could not determine flags for linking embedded Perl.
  38 This probably means that ExtUtils::Embed or ExtUtils::MakeMaker is not
  39 installed.])
  40 else
  41         AC_MSG_RESULT([$perl_embed_ldflags])
  42 fi
  43 ])# PGAC_CHECK_PERL_EMBED_LDFLAGS