configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL$
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage: enabled by default.
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [  --disable-integer-datetimes  disable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   set default port number [[5432]]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [  --disable-shared        do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [  --disable-rpath         do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [  --disable-spinlocks     do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [  --enable-debug          build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [  --enable-profiling      build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # --enable-coverage enables generation of code coverage metrics with gcov
 208 #
 209 PGAC_ARG_BOOL(enable, coverage, no,
 210               [  --enable-coverage       build with coverage testing instrumentation],
 211 [AC_CHECK_PROGS(GCOV, gcov)
 212 if test -z "$GCOV"; then
 213   AC_MSG_ERROR([gcov not found])
 214 fi
 215 AC_CHECK_PROGS(LCOV, lcov)
 216 if test -z "$LCOV"; then
 217   AC_MSG_ERROR([lcov not found])
 218 fi
 219 AC_CHECK_PROGS(GENHTML, genhtml)
 220 if test -z "$GENHTML"; then
 221   AC_MSG_ERROR([genhtml not found])
 222 fi])
 223 AC_SUBST(enable_coverage)
 224
 225 #
 226 # DTrace
 227 #
 228 PGAC_ARG_BOOL(enable, dtrace, no,
 229               [  --enable-dtrace         build with DTrace support],
 230 [AC_DEFINE([ENABLE_DTRACE], 1,
 231            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 232 AC_CHECK_PROGS(DTRACE, dtrace)
 233 if test -z "$DTRACE"; then
 234   AC_MSG_ERROR([dtrace not found])
 235 fi
 236 AC_SUBST(DTRACEFLAGS)])
 237 AC_SUBST(enable_dtrace)
 238
 239 #
 240 # Block size
 241 #
 242 AC_MSG_CHECKING([for block size])
 243 PGAC_ARG_REQ(with, blocksize, [  --with-blocksize=BLOCKSIZE  set table block size in kB [[8]]],
 244              [blocksize=$withval],
 245              [blocksize=8])
 246 case ${blocksize} in
 247   1) BLCKSZ=1024;;
 248   2) BLCKSZ=2048;;
 249   4) BLCKSZ=4096;;
 250   8) BLCKSZ=8192;;
 251  16) BLCKSZ=16384;;
 252  32) BLCKSZ=32768;;
 253   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 254 esac
 255 AC_MSG_RESULT([${blocksize}kB])
 256
 257 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 258  Size of a disk block --- this also limits the size of a tuple.  You
 259  can set it bigger if you need bigger tuples (although TOAST should
 260  reduce the need to have large tuples, since fields can be spread
 261  across multiple tuples).
 262
 263  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 264  is currently 2^15 (32768).  This is determined by the 15-bit widths
 265  of the lp_off and lp_len fields in ItemIdData (see
 266  include/storage/itemid.h).
 267
 268  Changing BLCKSZ requires an initdb.
 269 ])
 270
 271 #
 272 # Relation segment size
 273 #
 274 AC_MSG_CHECKING([for segment size])
 275 PGAC_ARG_REQ(with, segsize, [  --with-segsize=SEGSIZE  set table segment size in GB [[1]]],
 276              [segsize=$withval],
 277              [segsize=1])
 278 # this expression is set up to avoid unnecessary integer overflow
 279 # blocksize is already guaranteed to be a factor of 1024
 280 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 281 test $? -eq 0 || exit 1
 282 AC_MSG_RESULT([${segsize}GB])
 283
 284 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 285  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 286  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 287  relations bigger than that are divided into multiple files.
 288
 289  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 290  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 291  have large file support enabled.  By default, we make the limit 1 GB
 292  to avoid any possible integer-overflow problems within the OS.
 293  A limit smaller than necessary only means we divide a large
 294  relation into more chunks than necessary, so it seems best to err
 295  in the direction of a small limit.
 296
 297  A power-of-2 value is recommended to save a few cycles in md.c,
 298  but is not absolutely required.
 299
 300  Changing RELSEG_SIZE requires an initdb.
 301 ])
 302
 303 #
 304 # WAL block size
 305 #
 306 AC_MSG_CHECKING([for WAL block size])
 307 PGAC_ARG_REQ(with, wal-blocksize, [  --with-wal-blocksize=BLOCKSIZE  set WAL block size in kB [[8]]],
 308              [wal_blocksize=$withval],
 309              [wal_blocksize=8])
 310 case ${wal_blocksize} in
 311   1) XLOG_BLCKSZ=1024;;
 312   2) XLOG_BLCKSZ=2048;;
 313   4) XLOG_BLCKSZ=4096;;
 314   8) XLOG_BLCKSZ=8192;;
 315  16) XLOG_BLCKSZ=16384;;
 316  32) XLOG_BLCKSZ=32768;;
 317  64) XLOG_BLCKSZ=65536;;
 318   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 319 esac
 320 AC_MSG_RESULT([${wal_blocksize}kB])
 321
 322 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 323  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 324  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 325  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 326  buffers, else direct I/O may fail.
 327
 328  Changing XLOG_BLCKSZ requires an initdb.
 329 ])
 330
 331 #
 332 # WAL segment size
 333 #
 334 AC_MSG_CHECKING([for WAL segment size])
 335 PGAC_ARG_REQ(with, wal-segsize, [  --with-wal-segsize=SEGSIZE  set WAL segment size in MB [[16]]],
 336              [wal_segsize=$withval],
 337              [wal_segsize=16])
 338 case ${wal_segsize} in
 339   1) ;;
 340   2) ;;
 341   4) ;;
 342   8) ;;
 343  16) ;;
 344  32) ;;
 345  64) ;;
 346   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 347 esac
 348 AC_MSG_RESULT([${wal_segsize}MB])
 349
 350 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 351  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 352  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 353  XLOG_BLCKSZ).
 354
 355  Changing XLOG_SEG_SIZE requires an initdb.
 356 ])
 357
 358 #
 359 # C compiler
 360 #
 361
 362 # For historical reasons you can also use --with-CC to specify the C compiler
 363 # to use, although the standard way to do this is to set the CC environment
 364 # variable.
 365 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 366
 367 case $template in
 368   aix) pgac_cc_list="gcc xlc";;
 369  irix) pgac_cc_list="cc";; # no gcc
 370     *) pgac_cc_list="gcc cc";;
 371 esac
 372
 373 AC_PROG_CC([$pgac_cc_list])
 374
 375 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 376 # but has idiosyncrasies of its own.  We assume icc will define
 377 # __INTEL_COMPILER regardless of CFLAGS.
 378 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 379 choke me
 380 @%:@endif], [ICC=[yes]], [ICC=[no]])
 381
 382 unset CFLAGS
 383
 384 #
 385 # Read the template
 386 #
 387 . "$srcdir/src/template/$template" || exit
 388
 389 # CFLAGS are selected so:
 390 # If the user specifies something in the environment, that is used.
 391 # else:  If the template file set something, that is used.
 392 # else:  If coverage was enabled, don't set anything.
 393 # else:  If the compiler is GCC, then we use -O2.
 394 # else:  If the compiler is something else, then we use -O.
 395
 396 if test "$ac_env_CFLAGS_set" = set; then
 397   CFLAGS=$ac_env_CFLAGS_value
 398 elif test "${CFLAGS+set}" = set; then
 399   : # (keep what template set)
 400 elif test "$enable_coverage" = yes; then
 401   : # no optimization by default
 402 elif test "$GCC" = yes; then
 403   CFLAGS="-O2"
 404 else
 405   # if the user selected debug mode, don't use -O
 406   if test "$enable_debug" != yes; then
 407     CFLAGS="-O"
 408   fi
 409 fi
 410
 411 # Some versions of GCC support some additional useful warning flags.
 412 # Check whether they are supported, and add them to CFLAGS if so.
 413 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 414
 415 if test "$GCC" = yes -a "$ICC" = no; then
 416   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 417   # These work in some but not all gcc versions
 418   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 419   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 420   # Disable strict-aliasing rules; needed for gcc 3.3+
 421   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 422   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 423   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 424 elif test "$ICC" = yes; then
 425   # Intel's compiler has a bug/misoptimization in checking for
 426   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 427   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 428   # Make sure strict aliasing is off (though this is said to be the default)
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430 elif test x"${CC}" = x"xlc"; then
 431   # AIX xlc has to have strict aliasing turned off too
 432   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 433 fi
 434
 435 # supply -g if --enable-debug
 436 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 437   CFLAGS="$CFLAGS -g"
 438 fi
 439
 440 # enable code coverage if --enable-coverage
 441 if test "$enable_coverage" = yes; then
 442   if test "$GCC" = yes; then
 443     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 444   else
 445     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 446   fi
 447 fi
 448
 449 # enable profiling if --enable-profiling
 450 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 451   if test "$GCC" = yes; then
 452     AC_DEFINE([PROFILE_PID_DIR], 1,
 453            [Define to 1 to allow profiling output to be saved separately for each process.])
 454     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 455   else
 456     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 457   fi
 458 fi
 459
 460 # We already have this in Makefile.win32, but configure needs it too
 461 if test "$PORTNAME" = "win32"; then
 462   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 463 fi
 464
 465 # Check if the compiler still works with the template settings
 466 AC_MSG_CHECKING([whether the C compiler still works])
 467 AC_TRY_LINK([], [return 0;],
 468   [AC_MSG_RESULT(yes)],
 469   [AC_MSG_RESULT(no)
 470    AC_MSG_ERROR([cannot proceed])])
 471
 472 # Defend against gcc -ffast-math
 473 if test "$GCC" = yes; then
 474 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 475 choke me
 476 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 477 fi
 478
 479 AC_PROG_CPP
 480 AC_SUBST(GCC)
 481
 482 # Create compiler version string
 483 if test x"$GCC" = x"yes" ; then
 484   cc_string="GCC `${CC} --version | sed q`"
 485 else
 486   cc_string=$CC
 487 fi
 488 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 489                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 490                    [A string containing the version number, platform, and C compiler])
 491
 492
 493 #
 494 # Set up TAS assembly code if needed; the template file has now had its
 495 # chance to request this.
 496 #
 497 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 498
 499 if test "$need_tas" = yes ; then
 500   TAS=tas.o
 501 else
 502   TAS=""
 503 fi
 504 AC_SUBST(TAS)
 505
 506
 507 #
 508 # Automatic dependency tracking
 509 #
 510 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 511               [autodepend=yes])
 512 AC_SUBST(autodepend)
 513
 514
 515 #
 516 # Enable assert checks
 517 #
 518 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 519               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 520                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 521
 522
 523 #
 524 # Include directories
 525 #
 526 ac_save_IFS=$IFS
 527 IFS="${IFS}${PATH_SEPARATOR}"
 528 # SRCH_INC comes from the template file
 529 for dir in $with_includes $SRCH_INC; do
 530   if test -d "$dir"; then
 531     INCLUDES="$INCLUDES -I$dir"
 532   else
 533     AC_MSG_WARN([*** Include directory $dir does not exist.])
 534   fi
 535 done
 536 IFS=$ac_save_IFS
 537 AC_SUBST(INCLUDES)
 538
 539
 540 #
 541 # Library directories
 542 #
 543 ac_save_IFS=$IFS
 544 IFS="${IFS}${PATH_SEPARATOR}"
 545 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 546 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 547   if test -d "$dir"; then
 548     LIBDIRS="$LIBDIRS -L$dir"
 549   else
 550     AC_MSG_WARN([*** Library directory $dir does not exist.])
 551   fi
 552 done
 553 IFS=$ac_save_IFS
 554
 555 #
 556 # Enable thread-safe client libraries
 557 #
 558 AC_MSG_CHECKING([allow thread-safe client libraries])
 559 if test "$PORTNAME" != "win32"; then
 560 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 561 else
 562 # Win32 should always use threads
 563 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 564 fi
 565
 566 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 567 if test "$enable_thread_safety" = yes -o \
 568         "$enable_thread_safety_force" = yes; then
 569   enable_thread_safety="yes"    # for 'force'
 570   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 571           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 572 fi
 573 AC_MSG_RESULT([$enable_thread_safety])
 574 AC_SUBST(enable_thread_safety)
 575
 576 #
 577 # Optionally build Tcl modules (PL/Tcl)
 578 #
 579 AC_MSG_CHECKING([whether to build with Tcl])
 580 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 581 AC_MSG_RESULT([$with_tcl])
 582 AC_SUBST([with_tcl])
 583
 584 # We see if the path to the Tcl/Tk configuration scripts is specified.
 585 # This will override the use of tclsh to find the paths to search.
 586
 587 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 588
 589 #
 590 # Optionally build Perl modules (PL/Perl)
 591 #
 592 AC_MSG_CHECKING([whether to build Perl modules])
 593 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 594 AC_MSG_RESULT([$with_perl])
 595 AC_SUBST(with_perl)
 596
 597 #
 598 # Optionally build Python modules (PL/Python)
 599 #
 600 AC_MSG_CHECKING([whether to build Python modules])
 601 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 602 AC_MSG_RESULT([$with_python])
 603 AC_SUBST(with_python)
 604
 605 #
 606 # GSSAPI
 607 #
 608 AC_MSG_CHECKING([whether to build with GSSAPI support])
 609 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 610 [
 611   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 612   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 613 ])
 614 AC_MSG_RESULT([$with_gssapi])
 615 AC_SUBST(with_gssapi)
 616
 617 #
 618 # Kerberos 5
 619 #
 620 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 621 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 622 [
 623   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 624   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 625 ])
 626 AC_MSG_RESULT([$with_krb5])
 627 AC_SUBST(with_krb5)
 628
 629
 630 AC_SUBST(krb_srvtab)
 631
 632
 633 #
 634 # Kerberos configuration parameters
 635 #
 636 PGAC_ARG_REQ(with, krb-srvnam,
 637              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 638              [],
 639              [with_krb_srvnam="postgres"])
 640 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 641                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 642
 643
 644 #
 645 # PAM
 646 #
 647 AC_MSG_CHECKING([whether to build with PAM support])
 648 PGAC_ARG_BOOL(with, pam, no,
 649               [  --with-pam              build with PAM support],
 650               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 651 AC_MSG_RESULT([$with_pam])
 652 AC_SUBST(with_pam)
 653
 654
 655 #
 656 # LDAP
 657 #
 658 AC_MSG_CHECKING([whether to build with LDAP support])
 659 PGAC_ARG_BOOL(with, ldap, no,
 660               [  --with-ldap             build with LDAP support],
 661               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 662 AC_MSG_RESULT([$with_ldap])
 663 AC_SUBST(with_ldap)
 664
 665
 666 #
 667 # Bonjour
 668 #
 669 AC_MSG_CHECKING([whether to build with Bonjour support])
 670 PGAC_ARG_BOOL(with, bonjour, no,
 671               [  --with-bonjour          build with Bonjour support],
 672               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 673 AC_MSG_RESULT([$with_bonjour])
 674 AC_SUBST(with_bonjour)
 675
 676
 677 #
 678 # OpenSSL
 679 #
 680 AC_MSG_CHECKING([whether to build with OpenSSL support])
 681 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 682               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 683 AC_MSG_RESULT([$with_openssl])
 684 AC_SUBST(with_openssl)
 685
 686
 687 #
 688 # Readline
 689 #
 690 PGAC_ARG_BOOL(with, readline, yes,
 691               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 692 # readline on MinGW has problems with backslashes in psql and other bugs.
 693 # This is particularly a problem with non-US code pages.
 694 # Therefore disable its use until we understand the cause. 2004-07-20
 695 if test "$PORTNAME" = "win32"; then
 696   if test "$with_readline" = yes; then
 697     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 698     with_readline=no
 699   fi
 700 fi
 701
 702
 703 #
 704 # Prefer libedit
 705 #
 706 PGAC_ARG_BOOL(with, libedit-preferred, no,
 707               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 708
 709
 710 #
 711 # OSSP UUID library
 712 #
 713 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
 714 AC_SUBST(with_ossp_uuid)
 715
 716
 717 #
 718 # XML
 719 #
 720 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 721               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 722
 723 if test "$with_libxml" = yes ; then
 724   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 725   if test -n "$XML2_CONFIG"; then
 726     for pgac_option in `$XML2_CONFIG --cflags`; do
 727       case $pgac_option in
 728         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 729       esac
 730     done
 731     for pgac_option in `$XML2_CONFIG --libs`; do
 732       case $pgac_option in
 733         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 734       esac
 735     done
 736   fi
 737 fi
 738
 739 AC_SUBST(with_libxml)
 740
 741 #
 742 # XSLT
 743 #
 744 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
 745               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 746
 747
 748 AC_SUBST(with_libxslt)
 749
 750 #
 751 # tzdata
 752 #
 753 PGAC_ARG_REQ(with, system-tzdata,
 754              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 755 AC_SUBST(with_system_tzdata)
 756
 757 #
 758 # Zlib
 759 #
 760 PGAC_ARG_BOOL(with, zlib, yes,
 761               [  --without-zlib          do not use Zlib])
 762 AC_SUBST(with_zlib)
 763
 764 #
 765 # Elf
 766 #
 767
 768 # Assume system is ELF if it predefines __ELF__ as 1,
 769 # otherwise believe host_os based default.
 770 case $host_os in
 771     freebsd1*|freebsd2*) elf=no;;
 772     freebsd3*|freebsd4*) elf=yes;;
 773 esac
 774
 775 AC_EGREP_CPP(yes,
 776 [#if __ELF__
 777   yes
 778 #endif
 779 ],
 780 [ELF_SYS=true],
 781 [if test "X$elf" = "Xyes" ; then
 782   ELF_SYS=true
 783 else
 784   ELF_SYS=
 785 fi])
 786 AC_SUBST(ELF_SYS)
 787
 788 #
 789 # Assignments
 790 #
 791
 792 CPPFLAGS="$CPPFLAGS $INCLUDES"
 793 LDFLAGS="$LDFLAGS $LIBDIRS"
 794
 795 AC_ARG_VAR(LDFLAGS_SL)
 796
 797 PGAC_PROG_LD
 798 AC_SUBST(LD)
 799 AC_SUBST(with_gnu_ld)
 800 case $host_os in sysv5*)
 801   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 802   [
 803     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 804     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 805     LDFLAGS=$pgac_save_LDFLAGS
 806   ])
 807   ld_R_works=$pgac_cv_prog_ld_R
 808   AC_SUBST(ld_R_works)
 809 esac
 810 AC_PROG_RANLIB
 811 PGAC_CHECK_STRIP
 812
 813 AC_PATH_PROG(TAR, tar)
 814 AC_PROG_LN_S
 815 AC_PROG_AWK
 816
 817 PGAC_PATH_BISON
 818 PGAC_PATH_FLEX
 819
 820 PGAC_PATH_PERL
 821 if test "$with_perl" = yes; then
 822   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 823   PGAC_CHECK_PERL_EMBED_LDFLAGS
 824 fi
 825
 826 if test "$with_python" = yes; then
 827   PGAC_PATH_PYTHON
 828   PGAC_CHECK_PYTHON_EMBED_SETUP
 829 fi
 830
 831 # Supply a numeric version string for use by 3rd party add-ons
 832 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 833 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 834 tr '.' '        ' |
 835 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 836 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 837
 838 ##
 839 ## Libraries
 840 ##
 841 ## Most libraries are included only if they demonstrably provide a function
 842 ## we need, but libm is an exception: always include it, because there are
 843 ## too many compilers that play cute optimization games that will break
 844 ## probes for standard functions such as pow().
 845 ##
 846
 847 AC_CHECK_LIB(m, main)
 848 AC_SEARCH_LIBS(setproctitle, util)
 849 AC_SEARCH_LIBS(dlopen, dl)
 850 AC_SEARCH_LIBS(socket, [socket wsock32])
 851 AC_SEARCH_LIBS(shl_load, dld)
 852 # We only use libld in port/dynloader/aix.c
 853 case $host_os in
 854      aix*)
 855         AC_SEARCH_LIBS(ldopen, ld)
 856         ;;
 857 esac
 858 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 859 AC_SEARCH_LIBS(crypt, crypt)
 860 # Solaris:
 861 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 862 # Cygwin:
 863 AC_SEARCH_LIBS(shmget, cygipc)
 864
 865 if test "$with_readline" = yes; then
 866   PGAC_CHECK_READLINE
 867   if test x"$pgac_cv_check_readline" = x"no"; then
 868     AC_MSG_ERROR([readline library not found
 869 If you have readline already installed, see config.log for details on the
 870 failure.  It is possible the compiler isn't looking in the proper directory.
 871 Use --without-readline to disable readline support.])
 872   fi
 873 fi
 874
 875 if test "$with_zlib" = yes; then
 876   AC_CHECK_LIB(z, inflate, [],
 877                [AC_MSG_ERROR([zlib library not found
 878 If you have zlib already installed, see config.log for details on the
 879 failure.  It is possible the compiler isn't looking in the proper directory.
 880 Use --without-zlib to disable zlib support.])])
 881 fi
 882
 883 if test "$enable_spinlocks" = yes; then
 884   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 885 else
 886   AC_MSG_WARN([
 887 *** Not using spinlocks will cause poor performance.])
 888 fi
 889
 890 if test "$with_gssapi" = yes ; then
 891   if test "$PORTNAME" != "win32"; then
 892     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 893                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 894   else
 895     LIBS="$LIBS -lgssapi32"
 896   fi
 897 fi
 898
 899 if test "$with_krb5" = yes ; then
 900   if test "$PORTNAME" != "win32"; then
 901      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 902                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 903      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 904                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 905   else
 906      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 907                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 908   fi
 909 fi
 910
 911 if test "$with_openssl" = yes ; then
 912   dnl Order matters!
 913   if test "$PORTNAME" != "win32"; then
 914      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 915      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 916   else
 917      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 918      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 919   fi
 920 fi
 921
 922 if test "$with_pam" = yes ; then
 923   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 924 fi
 925
 926 if test "$with_libxml" = yes ; then
 927   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 928 fi
 929
 930 if test "$with_libxslt" = yes ; then
 931   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 932 fi
 933
 934 # for contrib/uuid-ossp
 935 if test "$with_ossp_uuid" = yes ; then
 936   AC_CHECK_LIB(ossp-uuid, uuid_export,
 937     [OSSP_UUID_LIBS="-lossp-uuid"],
 938     [AC_CHECK_LIB(uuid, uuid_export,
 939       [OSSP_UUID_LIBS="-luuid"],
 940       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 941 fi
 942 AC_SUBST(OSSP_UUID_LIBS)
 943
 944
 945 ##
 946 ## Header files
 947 ##
 948
 949 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 950 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 951
 952 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 953 # netinet/in.h is included first.
 954 AC_CHECK_HEADERS(netinet/in.h)
 955 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 956 [AC_INCLUDES_DEFAULT
 957 #ifdef HAVE_NETINET_IN_H
 958 #include <netinet/in.h>
 959 #endif
 960 ])
 961
 962 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 963   AC_CHECK_HEADERS(readline/readline.h, [],
 964         [AC_CHECK_HEADERS(readline.h, [],
 965                 [AC_MSG_ERROR([readline header not found
 966 If you have readline already installed, see config.log for details on the
 967 failure.  It is possible the compiler isn't looking in the proper directory.
 968 Use --without-readline to disable readline support.])])])
 969   AC_CHECK_HEADERS(readline/history.h, [],
 970         [AC_CHECK_HEADERS(history.h, [],
 971                 [AC_MSG_ERROR([history header not found
 972 If you have readline already installed, see config.log for details on the
 973 failure.  It is possible the compiler isn't looking in the proper directory.
 974 Use --without-readline to disable readline support.])])])
 975 fi
 976
 977 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 978 # Some installations of libedit usurp /usr/include/readline/, which seems
 979 # bad practice, since in combined installations readline will have its headers
 980 # there.  We might have to resort to AC_EGREP checks to make sure we found
 981 # the proper header...
 982   AC_CHECK_HEADERS(editline/readline.h, [],
 983         [AC_CHECK_HEADERS(readline.h, [],
 984                 [AC_CHECK_HEADERS(readline/readline.h, [],
 985                         [AC_MSG_ERROR([readline header not found
 986 If you have libedit already installed, see config.log for details on the
 987 failure.  It is possible the compiler isn't looking in the proper directory.
 988 Use --without-readline to disable libedit support.])])])])
 989 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 990 # not be there at all.  Hence, don't complain if not found.  We must check
 991 # though, since in yet other versions it is an independent header.
 992   AC_CHECK_HEADERS(editline/history.h, [],
 993         [AC_CHECK_HEADERS(history.h, [],
 994                 [AC_CHECK_HEADERS(readline/history.h)])])
 995 fi
 996
 997 if test "$with_zlib" = yes; then
 998   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 999 If you have zlib already installed, see config.log for details on the
1000 failure.  It is possible the compiler isn't looking in the proper directory.
1001 Use --without-zlib to disable zlib support.])])
1002 fi
1003
1004 if test "$with_gssapi" = yes ; then
1005   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1006         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1007 fi
1008
1009 if test "$with_krb5" = yes ; then
1010   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1011 fi
1012
1013 if test "$with_openssl" = yes ; then
1014   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1015   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1016   AC_CHECK_FUNCS([ERR_set_mark])
1017 fi
1018
1019 if test "$with_pam" = yes ; then
1020   AC_CHECK_HEADERS(security/pam_appl.h, [],
1021                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1022                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1023 fi
1024
1025 if test "$with_libxml" = yes ; then
1026   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1027 fi
1028
1029 if test "$with_libxslt" = yes ; then
1030   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1031 fi
1032
1033 if test "$with_ldap" = yes ; then
1034   if test "$PORTNAME" != "win32"; then
1035      AC_CHECK_HEADERS(ldap.h, [],
1036                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1037   else
1038      AC_CHECK_HEADERS(winldap.h, [],
1039                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1040                       [AC_INCLUDES_DEFAULT
1041 #include <windows.h>
1042                       ])
1043   fi
1044 fi
1045
1046 if test "$with_bonjour" = yes ; then
1047   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1048 fi
1049
1050 # for contrib/uuid-ossp
1051 if test "$with_ossp_uuid" = yes ; then
1052   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1053     AC_CHECK_HEADERS(uuid.h, [],
1054       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1055 fi
1056
1057
1058 ##
1059 ## Types, structures, compiler characteristics
1060 ##
1061
1062 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1063 AC_C_BIGENDIAN
1064 AC_C_CONST
1065 AC_C_INLINE
1066 AC_C_STRINGIZE
1067 PGAC_C_SIGNED
1068 AC_C_VOLATILE
1069 PGAC_C_FUNCNAME_SUPPORT
1070 PGAC_STRUCT_TIMEZONE
1071 PGAC_UNION_SEMUN
1072 PGAC_STRUCT_SOCKADDR_UN
1073 PGAC_STRUCT_SOCKADDR_STORAGE
1074 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1075 PGAC_STRUCT_ADDRINFO
1076
1077 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1078 [#include <sys/param.h>
1079 #include <sys/types.h>
1080 #include <sys/socket.h>
1081 #include <sys/ucred.h>])
1082
1083 AC_CHECK_TYPES([struct option], [], [],
1084 [#ifdef HAVE_GETOPT_H
1085 #include <getopt.h>
1086 #endif])
1087
1088 if test "$with_zlib" = yes; then
1089   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1090   # did not).  While we could work around the lack of z_streamp, it
1091   # seems unwise to encourage people to use such old zlib versions...
1092   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1093 Use --without-zlib to disable zlib support.])],
1094                 [#include <zlib.h>])
1095 fi
1096
1097 if test "$with_krb5" = yes; then
1098 # Check for differences between MIT and Heimdal (KTH) releases
1099   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1100                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1101                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1102                                      [#include <krb5.h>])],
1103                    [#include <krb5.h>])
1104   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1105                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1106                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1107                                      [#include <krb5.h>])],
1108                    [#include <krb5.h>])
1109
1110 # Win32 requires headers to be loaded for __stdcall, so can't use
1111 # AC_CHECK_FUNCS here.
1112   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1113   AC_TRY_LINK([#include <krb5.h>],
1114               [krb5_free_unparsed_name(NULL,NULL);],
1115               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1116 AC_MSG_RESULT(yes)],
1117               [AC_MSG_RESULT(no)])
1118 fi
1119
1120
1121 ##
1122 ## Functions, global variables
1123 ##
1124
1125 PGAC_VAR_INT_TIMEZONE
1126 AC_FUNC_ACCEPT_ARGTYPES
1127 PGAC_FUNC_GETTIMEOFDAY_1ARG
1128
1129 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1130
1131 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1132 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1133 AC_CHECK_DECLS([strlcat, strlcpy])
1134 # This is probably only present on Darwin, but may as well check always
1135 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1136
1137 HAVE_IPV6=no
1138 AC_CHECK_TYPE([struct sockaddr_in6],
1139         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1140          HAVE_IPV6=yes],
1141         [],
1142 [$ac_includes_default
1143 #include <netinet/in.h>])
1144 AC_SUBST(HAVE_IPV6)
1145
1146 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1147 [AC_TRY_LINK(
1148 [#include <machine/vmparam.h>
1149 #include <sys/exec.h>
1150 ],
1151 [PS_STRINGS->ps_nargvstr = 1;
1152 PS_STRINGS->ps_argvstr = "foo";],
1153 [pgac_cv_var_PS_STRINGS=yes],
1154 [pgac_cv_var_PS_STRINGS=no])])
1155 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1156   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1157 fi
1158
1159
1160 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1161 # is missing.  Yes, there are machines that have only one.  We may
1162 # also decide to use snprintf.c if snprintf() is present but does not
1163 # have all the features we need --- see below.
1164
1165 if test "$PORTNAME" = "win32"; then
1166   # Win32 gets snprintf.c built unconditionally.
1167   #
1168   # To properly translate all NLS languages strings, we must support the
1169   # *printf() %$ format, which allows *printf() arguments to be selected
1170   # by position in the translated string.
1171   #
1172   # libintl versions < 0.13 use the native *printf() functions, and Win32
1173   # *printf() doesn't understand %$, so we must use our /port versions,
1174   # which do understand %$. libintl versions >= 0.13 include their own
1175   # *printf versions on Win32.  The libintl 0.13 release note text is:
1176   #
1177   #   C format strings with positions, as they arise when a translator
1178   #   needs to reorder a sentence, are now supported on all platforms.
1179   #   On those few platforms (NetBSD and Woe32) for which the native
1180   #   printf()/fprintf()/... functions don't support such format
1181   #   strings, replacements are provided through <libintl.h>.
1182   #
1183   # We could use libintl >= 0.13's *printf() if we were sure that we had
1184   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1185   # to guarantee that, it is best to just use our own, so we are sure to
1186   # get %$ support. In include/port.h we disable the *printf() macros
1187   # that might have been defined by libintl.
1188   #
1189   # We do this unconditionally whether NLS is used or not so we are sure
1190   # that all Win32 libraries and binaries behave the same.
1191   pgac_need_repl_snprintf=yes
1192 else
1193   pgac_need_repl_snprintf=no
1194   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1195   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1196 fi
1197
1198
1199 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1200 # include/c.h will provide declarations.  Note this is a separate test
1201 # from whether the functions exist in the C library --- there are
1202 # systems that have the functions but don't bother to declare them :-(
1203
1204 AC_CHECK_DECLS([snprintf, vsnprintf])
1205
1206
1207 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1208 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1209 [AC_TRY_LINK([
1210 #include <math.h>
1211 double glob_double;
1212 ],
1213 [return isinf(glob_double) ? 0 : 1;],
1214 [ac_cv_func_isinf=yes],
1215 [ac_cv_func_isinf=no])])
1216
1217 if test $ac_cv_func_isinf = yes ; then
1218   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1219 else
1220   AC_LIBOBJ(isinf)
1221   # Look for a way to implement a substitute for isinf()
1222   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1223 fi
1224
1225 # Some versions of libedit contain strlcpy(); so disregard that library while
1226 # checking for these standard libc functions.
1227 pgac_save_LIBS="$LIBS"
1228 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1229
1230 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1231
1232 LIBS="$pgac_save_LIBS"
1233
1234 # System's version of getaddrinfo(), if any, may be used only if we found
1235 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1236 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1237 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1238 # because we want to use our own getaddrinfo.c on Windows anyway.)
1239 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1240   AC_REPLACE_FUNCS([getaddrinfo])
1241 else
1242   AC_LIBOBJ(getaddrinfo)
1243 fi
1244
1245 # Similarly, use system's getopt_long() only if system provides struct option.
1246 # Solaris' getopt() doesn't do what we want for long options, so always use
1247 # our versions on that platform.
1248 if test "$PORTNAME" = "solaris"; then
1249   AC_LIBOBJ(getopt)
1250   AC_LIBOBJ(getopt_long)
1251 elif test x"$ac_cv_type_struct_option" = xyes ; then
1252   AC_REPLACE_FUNCS([getopt_long])
1253 else
1254   AC_LIBOBJ(getopt_long)
1255 fi
1256
1257 # Win32 support
1258 if test "$PORTNAME" = "win32"; then
1259 AC_REPLACE_FUNCS(gettimeofday)
1260 AC_LIBOBJ(kill)
1261 AC_LIBOBJ(open)
1262 AC_LIBOBJ(rand)
1263 AC_LIBOBJ(win32error)
1264 AC_DEFINE([HAVE_SYMLINK], 1,
1265           [Define to 1 if you have the `symlink' function.])
1266 fi
1267
1268 if test "$with_readline" = yes; then
1269   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1270   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1271   AC_CHECK_FUNCS([replace_history_entry])
1272 fi
1273
1274
1275 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1276 dnl (especially on GNU libc)
1277 dnl See also comments in c.h.
1278 AC_MSG_CHECKING(for sigsetjmp)
1279 AC_TRY_LINK([#include <setjmp.h>],
1280             [sigjmp_buf x; sigsetjmp(x, 1);],
1281             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1282 AC_MSG_RESULT(yes)],
1283             [AC_MSG_RESULT(no)])
1284
1285 AC_DECL_SYS_SIGLIST
1286
1287 AC_CHECK_FUNC(syslog,
1288               [AC_CHECK_HEADER(syslog.h,
1289                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1290
1291 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1292 [AC_TRY_LINK([#include <unistd.h>],
1293   [extern int optreset; optreset = 1;],
1294   [pgac_cv_var_int_optreset=yes],
1295   [pgac_cv_var_int_optreset=no])])
1296 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1297   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1298 fi
1299
1300 AC_CHECK_FUNCS([strtoll strtoq], [break])
1301 AC_CHECK_FUNCS([strtoull strtouq], [break])
1302
1303 # Check for one of atexit() or on_exit()
1304 AC_CHECK_FUNCS(atexit, [],
1305                [AC_CHECK_FUNCS(on_exit, [],
1306                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1307
1308 AC_REPLACE_FUNCS(fseeko)
1309 case $host_os in
1310         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1311         bsdi*|netbsd*)
1312                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1313                 ac_cv_func_fseeko=yes;;
1314         *)
1315                 AC_FUNC_FSEEKO;;
1316 esac
1317
1318
1319 #
1320 # Pthreads
1321 #
1322 # For each platform, we need to know about any special compile and link
1323 # libraries, and whether the normal C function names are thread-safe.
1324 # See the comment at the top of src/port/thread.c for more information.
1325 # WIN32 doesn't need the pthread tests;  it always uses threads
1326 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1327 ACX_PTHREAD     # set thread flags
1328
1329 # Some platforms use these, so just defineed them.  They can't hurt if they
1330 # are not supported.
1331 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1332
1333
1334 # At this point, we don't want to muck with the compiler name for threading.
1335 # Let's see who fails, perhaps AIX.  2004-04-23
1336 if test "$PTHREAD_CC" != "$CC"; then
1337 AC_MSG_ERROR([
1338 PostgreSQL does not support platforms that require a special compiler
1339 for thread safety.])
1340 fi
1341
1342 if test "$THREAD_SUPPORT" = no; then
1343 AC_MSG_ERROR([cannot enable threads on this platform
1344 This platform is known to not support thread-safe programs.  For details,
1345 compile and run src/bin/pg_thread_test.])
1346 fi
1347
1348 # Check for *_r functions
1349 _CFLAGS="$CFLAGS"
1350 _LIBS="$LIBS"
1351 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1352 LIBS="$LIBS $PTHREAD_LIBS"
1353
1354 if test "$PORTNAME" != "win32"; then
1355 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1356 fi
1357
1358 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1359
1360 # Do test here with the proper thread flags
1361 PGAC_FUNC_GETPWUID_R_5ARG
1362 PGAC_FUNC_STRERROR_R_INT
1363
1364 CFLAGS="$_CFLAGS"
1365 LIBS="$_LIBS"
1366
1367 else
1368 # do not use values from template file
1369 PTHREAD_CFLAGS=
1370 PTHREAD_LIBS=
1371 fi
1372
1373 AC_SUBST(PTHREAD_CFLAGS)
1374 AC_SUBST(PTHREAD_LIBS)
1375
1376
1377 # We can test for libldap_r only after we know PTHREAD_LIBS
1378 if test "$with_ldap" = yes ; then
1379   _LIBS="$LIBS"
1380   if test "$PORTNAME" != "win32"; then
1381     AC_CHECK_LIB(ldap, ldap_bind, [],
1382                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1383                  [$EXTRA_LDAP_LIBS])
1384     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1385     if test "$enable_thread_safety" = yes; then
1386       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1387       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1388                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1389                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1390       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1391     else
1392       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1393     fi
1394   else
1395     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1396     LDAP_LIBS_FE="-lwldap32"
1397     LDAP_LIBS_BE="-lwldap32"
1398   fi
1399   LIBS="$_LIBS"
1400 fi
1401 AC_SUBST(LDAP_LIBS_FE)
1402 AC_SUBST(LDAP_LIBS_BE)
1403
1404
1405 # This test makes sure that run tests work at all.  Sometimes a shared
1406 # library is found by the linker, but the runtime linker can't find it.
1407 # This check should come after all modifications of compiler or linker
1408 # variables, and before any other run tests.
1409 AC_MSG_CHECKING([test program])
1410 AC_TRY_RUN([int main() { return 0; }],
1411 [AC_MSG_RESULT(ok)],
1412 [AC_MSG_RESULT(failed)
1413 AC_MSG_ERROR([[
1414 Could not execute a simple test program.  This may be a problem
1415 related to locating shared libraries.  Check the file 'config.log'
1416 for the exact reason.]])],
1417 [AC_MSG_RESULT([cross-compiling])])
1418
1419 # --------------------
1420 # Run tests below here
1421 # --------------------
1422
1423 # Force use of our snprintf if system's doesn't do arg control
1424 # See comment above at snprintf test for details.
1425 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1426   PGAC_FUNC_PRINTF_ARG_CONTROL
1427   if test $pgac_cv_printf_arg_control != yes ; then
1428     pgac_need_repl_snprintf=yes
1429   fi
1430 fi
1431
1432
1433 dnl Check to see if we have a working 64-bit integer type.
1434 dnl This breaks down into two steps:
1435 dnl (1) figure out if the compiler has a 64-bit int type with working
1436 dnl arithmetic, and if so
1437 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1438 dnl snprintf is the only library routine we really need for int8 support.)
1439 dnl It's entirely possible to have a compiler that handles a 64-bit type
1440 dnl when the C library doesn't; this is fairly likely when using gcc on
1441 dnl an older platform, for example.
1442 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1443 dnl we force our own version of snprintf() to be used instead.
1444 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1445
1446 PGAC_TYPE_64BIT_INT([long int])
1447
1448 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1449   PGAC_TYPE_64BIT_INT([long long int])
1450 fi
1451
1452
1453 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1454
1455 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1456   AC_TRY_COMPILE([
1457 #define INT64CONST(x)  x##LL
1458 long long int foo = INT64CONST(0x1234567890123456);
1459 ],
1460         [],
1461         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1462         [])
1463 fi
1464
1465
1466 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1467 # we found we need to use "long long int", better check.  We cope with
1468 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1469 # work, fall back to our own snprintf emulation (which we know uses %lld).
1470
1471 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1472   if test $pgac_need_repl_snprintf = no; then
1473     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1474     if test "$LONG_LONG_INT_FORMAT" = ""; then
1475       # Force usage of our own snprintf, since system snprintf is broken
1476       pgac_need_repl_snprintf=yes
1477       LONG_LONG_INT_FORMAT='%lld'
1478     fi
1479   else
1480     # Here if we previously decided we needed to use our own snprintf
1481     LONG_LONG_INT_FORMAT='%lld'
1482   fi
1483   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1484   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1485   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1486 else
1487   # Here if we are not using 'long long int' at all
1488   INT64_FORMAT='"%ld"'
1489   UINT64_FORMAT='"%lu"'
1490 fi
1491
1492 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1493                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1494
1495 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1496                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1497
1498 # Now we have checked all the reasons to replace snprintf
1499 if test $pgac_need_repl_snprintf = yes; then
1500   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1501   AC_LIBOBJ(snprintf)
1502 fi
1503
1504 # Need a #define for the size of Datum (unsigned long)
1505 AC_CHECK_SIZEOF([unsigned long])
1506
1507 # And one for the size of size_t (enables tweaks for > 32bit address space)
1508 AC_CHECK_SIZEOF([size_t])
1509
1510 # Decide whether float4 is passed by value: user-selectable, enabled by default
1511 AC_MSG_CHECKING([whether to build with float4 passed by value])
1512 PGAC_ARG_BOOL(enable, float4-byval, yes, [  --disable-float4-byval  disable float4 passed by value],
1513               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1514                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1515                float4passbyval=true],
1516               [float4passbyval=false])
1517 AC_MSG_RESULT([$enable_float4_byval])
1518 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1519
1520 # Decide whether float8 is passed by value.
1521 # Note: this setting also controls int8 and related types such as timestamp.
1522 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1523 # If not, trying to select it is an error.
1524 AC_MSG_CHECKING([whether to build with float8 passed by value])
1525 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1526   PGAC_ARG_BOOL(enable, float8-byval, yes, [  --disable-float8-byval  disable float8 passed by value])
1527 else
1528   PGAC_ARG_BOOL(enable, float8-byval, no, [  --disable-float8-byval  disable float8 passed by value])
1529   if test "$enable_float8_byval" = yes ; then
1530     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1531   fi
1532 fi
1533 if test "$enable_float8_byval" = yes ; then
1534   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1535             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1536   float8passbyval=true
1537 else
1538   float8passbyval=false
1539 fi
1540 AC_MSG_RESULT([$enable_float8_byval])
1541 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1542
1543 # Determine memory alignment requirements for the basic C data types.
1544
1545 AC_CHECK_ALIGNOF(short)
1546 AC_CHECK_ALIGNOF(int)
1547 AC_CHECK_ALIGNOF(long)
1548 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1549   AC_CHECK_ALIGNOF(long long int)
1550 fi
1551 AC_CHECK_ALIGNOF(double)
1552
1553 # Compute maximum alignment of any basic type.
1554 # We assume long's alignment is at least as strong as char, short, or int;
1555 # but we must check long long (if it exists) and double.
1556
1557 MAX_ALIGNOF=$ac_cv_alignof_long
1558 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1559   MAX_ALIGNOF=$ac_cv_alignof_double
1560 fi
1561 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1562   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1563 fi
1564 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1565
1566
1567 # Some platforms predefine the types int8, int16, etc.  Only check
1568 # a (hopefully) representative subset.
1569 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1570 [#include <stdio.h>
1571 #ifdef HAVE_SUPPORTDEFS_H
1572 #include <SupportDefs.h>
1573 #endif])
1574
1575 # We also check for sig_atomic_t, which *should* be defined per ANSI
1576 # C, but is missing on some old platforms.
1577 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1578
1579
1580 # If the user did not disable integer datetimes, check that
1581 # there is a working 64-bit integral type to use.
1582 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1583    test x"$HAVE_LONG_INT_64" = x"no" &&
1584    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1585    test x"$HAVE_INT64" = x"no" ; then
1586   AC_MSG_ERROR([
1587 Integer-based datetime support requires a 64-bit integer type,
1588 but no such type could be found. The --disable-integer-datetimes
1589 configure option can be used to disable integer-based storage
1590 of datetime values.])
1591 fi
1592
1593
1594 if test "$PORTNAME" != "win32"
1595 then
1596 PGAC_FUNC_POSIX_SIGNALS
1597 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1598   AC_MSG_ERROR([
1599 Thread-safety requires POSIX signals, which are not supported by this
1600 operating system.])
1601 fi
1602 fi
1603
1604 if test $ac_cv_func_fseeko = yes; then
1605 AC_SYS_LARGEFILE
1606 fi
1607
1608 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1609 AC_CHECK_SIZEOF([off_t])
1610
1611 # If we don't have largefile support, can't handle segsize >= 2GB.
1612 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1613    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1614 fi
1615
1616 # SunOS doesn't handle negative byte comparisons properly with +/- return
1617 AC_FUNC_MEMCMP
1618
1619
1620 # Select semaphore implementation type.
1621 if test "$PORTNAME" != "win32"; then
1622   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1623     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1624     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1625   else
1626     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1627       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1628       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1629     else
1630       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1631       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1632     fi
1633   fi
1634 else
1635   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1636   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1637 fi
1638
1639
1640 # Select shared-memory implementation type.
1641 if test "$PORTNAME" != "win32"; then
1642   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1643   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1644 else
1645   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1646   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1647 fi
1648
1649 # If not set in template file, set bytes to use libc memset()
1650 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1651   MEMSET_LOOP_LIMIT=1024
1652 fi
1653 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1654
1655
1656 if test "$enable_nls" = yes ; then
1657   PGAC_CHECK_GETTEXT
1658 fi
1659
1660 # Check for Tcl configuration script tclConfig.sh
1661 if test "$with_tcl" = yes; then
1662     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1663     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1664                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1665     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1666     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1667     ac_save_CPPFLAGS=$CPPFLAGS
1668     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1669     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1670     CPPFLAGS=$ac_save_CPPFLAGS
1671 fi
1672
1673 #
1674 # Check for DocBook and tools
1675 #
1676 PGAC_PROG_NSGMLS
1677 PGAC_PROG_JADE
1678 PGAC_CHECK_DOCBOOK(4.2)
1679 PGAC_PATH_DOCBOOK_STYLESHEETS
1680 PGAC_PATH_COLLATEINDEX
1681 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1682
1683 # Thread testing
1684
1685 # We have to run the thread test near the end so we have all our symbols
1686 # defined.  Cross compiling throws a warning.
1687 #
1688 if test "$enable_thread_safety_force" = yes; then
1689 if test "$PORTNAME" != "win32"
1690 then
1691   AC_MSG_WARN([
1692 *** Skipping thread test program.  --enable-thread-safety-force was used.
1693 *** Run the program in src/test/thread on the your machine and add proper
1694 *** locking function calls to your applications to guarantee thread safety.
1695 ])
1696 else
1697 AC_MSG_WARN([*** skipping thread test on Win32])
1698 fi
1699 elif test "$enable_thread_safety" = yes; then
1700 if test "$PORTNAME" != "win32"
1701 then
1702 AC_MSG_CHECKING([thread safety of required library functions])
1703
1704 _CFLAGS="$CFLAGS"
1705 _LIBS="$LIBS"
1706 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1707 LIBS="$LIBS $PTHREAD_LIBS"
1708 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1709   [AC_MSG_RESULT(yes)],
1710   [AC_MSG_RESULT(no)
1711   AC_MSG_ERROR([thread test program failed
1712 This platform is not thread-safe.  Check the file 'config.log'for the
1713 exact reason.
1714
1715 You can use the configure option --enable-thread-safety-force to force
1716 threads to be enabled.  But you must then run the program in
1717 src/test/thread and add locking function calls to your applications to
1718 guarantee thread safety.])],
1719   [AC_MSG_RESULT(maybe)
1720   AC_MSG_WARN([
1721 *** Skipping thread test program because of cross-compile build.
1722 *** Run the program in src/test/thread on the target machine.
1723 ])])
1724 CFLAGS="$_CFLAGS"
1725 LIBS="$_LIBS"
1726 else
1727 AC_MSG_WARN([*** skipping thread test on Win32])
1728 fi
1729 fi
1730
1731 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1732 # This is much easier than trying to filter LIBS to the minimum for each
1733 # executable.  (Note that shared library links won't use this switch, though.)
1734 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1735 # libreadline; therefore we postpone testing it until we know what library
1736 # dependencies readline has.  The test code will try to link with $LIBS.
1737 if test "$with_readline" = yes; then
1738   link_test_func=readline
1739 else
1740   link_test_func=exit
1741 fi
1742 if test "$PORTNAME" != "darwin"; then
1743   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1744 else
1745   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1746   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1747 fi
1748
1749
1750 # Begin output steps
1751
1752 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1753 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1754 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1755
1756 # prepare build tree if outside source tree
1757 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1758 # Note 2: /bin/pwd might be better than shell's built-in at getting
1759 #         a symlink-free name.
1760 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1761   vpath_build=no
1762 else
1763   vpath_build=yes
1764   if test "$no_create" != yes; then
1765     _AS_ECHO_N([preparing build tree... ])
1766     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1767     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1768       || AC_MSG_ERROR(failed)
1769     AC_MSG_RESULT(done)
1770   fi
1771 fi
1772 AC_SUBST(vpath_build)
1773
1774
1775 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1776
1777 AC_CONFIG_LINKS([
1778   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1779   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1780   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1781   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1782   src/include/pg_config_os.h:src/include/port/${template}.h
1783   src/Makefile.port:src/makefiles/Makefile.${template}
1784 ])
1785
1786 if test "$PORTNAME" = "win32"; then
1787 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1788 # Links sometimes fail undetected on Mingw -
1789 # so here we detect it and warn the user
1790 for FILE in $CONFIG_LINKS
1791  do
1792         # test -e works for symlinks in the MinGW console
1793         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1794  done
1795 ])
1796 fi
1797
1798 AC_CONFIG_HEADERS([src/include/pg_config.h],
1799 [
1800 # Update timestamp for pg_config.h (see Makefile.global)
1801 echo >src/include/stamp-h
1802 ])
1803
1804 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1805
1806 AC_OUTPUT
1807
1808 # Warn about unknown options
1809 PGAC_ARG_CHECK