armsrc/ldscript

   1 /*
   2 -----------------------------------------------------------------------------
   3  This code is licensed to you under the terms of the GNU GPL, version 2 or,
   4  at your option, any later version. See the LICENSE.txt file for the text of
   5  the license.
   6 -----------------------------------------------------------------------------
   7  Linker script for the ARM binary
   8 -----------------------------------------------------------------------------
   9 */
  10 INCLUDE ../common_arm/ldscript.common
  11
  12 PHDRS
  13 {
  14     text PT_LOAD FLAGS(5);
  15     data PT_LOAD;
  16     bss PT_LOAD;
  17 }
  18
  19 ENTRY(Vector)
  20 SECTIONS
  21 {
  22     .start : {
  23         *(.startos)
  24     } >osimage :text
  25
  26     .text : {
  27         *(.text)
  28         *(.text.*)
  29         *(.eh_frame)
  30         *(.glue_7)
  31         *(.glue_7t)
  32     } >osimage :text
  33
  34     .rodata : {
  35         *(.rodata)
  36         *(.rodata.*)
  37         *(fpga_all_bit.data)
  38         . = ALIGN(8);
  39     } >osimage :text
  40
  41     .data : {
  42         *(.data)
  43         *(.data.*)
  44         *(.ramfunc)
  45         . = ALIGN(4);
  46     } >ram AT>osimage :data
  47
  48     __data_src_start__ = LOADADDR(.data);
  49     __data_start__ = ADDR(.data);
  50     __data_end__ = __data_start__ + SIZEOF(.data);
  51     __os_size__ = SIZEOF(.text) + SIZEOF(.data) + SIZEOF(.rodata);
  52
  53     .bss : {
  54         __bss_start__ = .;
  55         *(.bss)
  56         *(.bss.*)
  57         . = ALIGN(4);
  58         __bss_end__ = .;
  59     } >ram AT>ram :bss
  60
  61     .commonarea (NOLOAD) : {
  62         *(.commonarea)
  63     } >commonarea :NONE
  64 }