nanocoat/CMakeLists.txt

   1 # ---------------------------------------------------------------------------
   2 # SquirrelJME
   3 #     Copyright (C) Stephanie Gawroriski <xer@multiphasicapps.net>
   4 # ---------------------------------------------------------------------------
   5 # SquirrelJME is under the Mozilla Public License Version 2.0.
   6 # See license.mkd for licensing and copyright information.
   7 # ---------------------------------------------------------------------------
   8 # DESCRIPTION: Defines the base project and the versioning info
   9
  10 # Easier includes
  11 include("${CMAKE_SOURCE_DIR}/cmake/easier-includes.cmake" NO_POLICY_SCOPE)
  12
  13 # Needed for some ancient RetroArch toolchains
  14 if(${CMAKE_VERSION} VERSION_LESS "3.13")
  15         message(STATUS "Ancient CMake has been detected (${CMAKE_VERSION})")
  16         cmake_minimum_required(VERSION 3.7)
  17
  18         # Needs to be this or newer
  19 else()
  20         message(STATUS "Detected CMake (${CMAKE_VERSION})")
  21         cmake_minimum_required(VERSION 3.13)
  22 endif()
  23
  24 # Determine version information
  25 squirreljme_include("identify-squirreljme-version.cmake")
  26
  27 # Soft patching of CMake for older version support
  28 squirreljme_include("cmake-patch.cmake")
  29
  30 # Fixes and otherwise for compatibility
  31 squirreljme_include("pre-fixes.cmake")
  32
  33 # Define project
  34 if(${CMAKE_VERSION} VERSION_LESS "3.12")
  35         project(SquirrelJME
  36                 VERSION ${SQUIRRELJME_VERSION}
  37                 LANGUAGES C)
  38 else()
  39         project(SquirrelJME
  40                 VERSION ${SQUIRRELJME_VERSION}
  41                 DESCRIPTION "SquirrelJME is a Java ME 8 \
  42 Virtual Machine for embedded and Internet of Things devices."
  43                 HOMEPAGE_URL https://squirreljme.cc/
  44                 LANGUAGES C)
  45 endif()
  46
  47 # CMake Utilities, compiled and used during build
  48 squirreljme_include("utils.cmake")
  49
  50 # Platform information
  51 squirreljme_include("platform.cmake")
  52
  53 # Fixes and otherwise for compatibility
  54 squirreljme_include("fixes.cmake")
  55
  56 # Use for all builds
  57 add_compile_definitions(SJME_CONFIG_BUILD_ARCH=${SQUIRRELJME_ARCH})
  58 add_compile_definitions(SJME_CONFIG_BUILD_PLATFORM=${SQUIRRELJME_PLATFORM})
  59
  60 # Win32 Options
  61 squirreljme_include("win32.cmake")
  62
  63 # Hardening options
  64 squirreljme_include("hardening.cmake")
  65
  66 # Is the system JNI available?
  67 squirreljme_include("jni.cmake")
  68
  69 # Doxygen
  70 squirreljme_include("doxygen.cmake")
  71
  72 # Threading and atomics
  73 squirreljme_include("threads.cmake")
  74
  75 # To Emily and Near...
  76 squirreljme_include("i-miss-you.cmake")
  77
  78 # Everything is C99
  79 set(CMAKE_C_STANDARD 99)
  80 set(CMAKE_C_STANDARD_REQUIRED True)
  81
  82 # Assets and otherwise, such as icons, etc.
  83 squirreljme_include("assets.cmake")
  84
  85 # Multi-library declarations
  86 squirreljme_include("multilib.cmake")
  87
  88 # Distribution
  89 squirreljme_include("distrib.cmake")
  90
  91 # Visual studio does not like a bunch of standard C functions, even those
  92 # that take sizes...
  93 if(MSVC)
  94         add_compile_definitions(_CRT_SECURE_NO_WARNINGS=1)
  95 endif()
  96
  97 # Declare Version
  98 add_compile_definitions(
  99         SQUIRRELJME_VERSION_TRIM=${SQUIRRELJME_VERSION})
 100
 101 # Debugging?
 102 if(SQUIRRELJME_IS_DEBUG)
 103         add_compile_definitions(SJME_CONFIG_DEBUG=1)
 104
 105         if(SQUIRRELJME_ENABLE_TESTING)
 106                 add_compile_definitions(SJME_CONFIG_UNIT_TEST=1)
 107         endif()
 108 endif()
 109
 110 # Valgrind Support on UNIX OSes, if debugging is enabled
 111 if(ANDROID OR SQUIRRELJME_IS_UNIX)
 112         if(SQUIRRELJME_IS_DEBUG)
 113                 squirreljme_include("valgrind.cmake")
 114         endif()
 115 endif()
 116
 117 # Where should dynamic libraries go when output?
 118 if(NOT DEFINED SQUIRRELJME_DYLIB_OUTPUT_DIR)
 119         set(SQUIRRELJME_DYLIB_OUTPUT_DIR
 120                 "${CMAKE_BINARY_DIR}")
 121 endif()
 122
 123 # Enable support for testing, this is needed here otherwise testing will not
 124 # work at all! Major headache this has caused...
 125 # From: https://cmake.org/cmake/help/v3.13/command/enable_testing.html
 126 # > Note that ctest expects to find a test file in the build directory root.
 127 # > Therefore, this command should be in the source directory root.
 128 if(SQUIRRELJME_ENABLE_TESTING)
 129         enable_testing()
 130 else()
 131         message(WARNING "Testing was disabled "
 132                 "(${SQUIRRELJME_ENABLE_TESTING})...")
 133 endif()
 134
 135 # CPack for installing
 136 if(SQUIRRELJME_ENABLE_PACKING OR
 137         NOT DEFINED SQUIRRELJME_ENABLE_PACKING)
 138         squirreljme_include("packing.cmake")
 139 endif()
 140
 141 # SquirrelJME Base Library, everything depends on this essentially
 142 add_subdirectory(lib/base)
 143
 144 # Include the base core first because it is completely standalone and it
 145 # uses nothing else
 146 add_subdirectory(src)
 147
 148 # Internal Libraries other than Base
 149 add_subdirectory(lib)
 150
 151 # Tests first since we add to these and when the ROMs register themselves
 152 # they will get their tests added accordingly
 153 if(SQUIRRELJME_ENABLE_TESTING)
 154         add_subdirectory(tests)
 155 else()
 156         message(WARNING "Testing was disabled "
 157                 "(${SQUIRRELJME_ENABLE_TESTING})...")
 158 endif()
 159
 160 # Front ends
 161 add_subdirectory(frontend)
 162
 163 # Directory where the ROM compiled sources exist
 164 add_subdirectory(rom)