hwrf-baseline-20120103-1354/util/src/plotgrids.F

   1 program plotgrids
   2
   3    use map_utils
   4
   5    implicit none
   6
   7    ! Parameters
   8    integer, parameter :: MAX_DOMAINS = 21
   9
  10    ! Variables
  11    integer :: iproj_type, n_domains, io_form_output, dyn_opt
  12    integer :: i, j, max_dom, funit, io_form_geogrid
  13    integer :: interval_seconds
  14
  15    integer, dimension(MAX_DOMAINS) :: parent_grid_ratio, parent_id, ixdim, jydim
  16    integer, dimension(MAX_DOMAINS) :: i_parent_start, j_parent_start, &
  17                         s_we, e_we, s_sn, e_sn, &
  18                         start_year, start_month, start_day, start_hour, &
  19                         end_year,   end_month,   end_day,   end_hour
  20    logical, dimension(MAX_DOMAINS) :: active_grid
  21
  22    real :: known_lat, known_lon, stand_lon, truelat1, truelat2, known_x, known_y, &
  23            dxkm, dykm, ref_lat, ref_lon, ref_x, ref_y
  24    real :: dx, dy
  25    real :: ri, rj, rlats, rlons, rlate, rlone
  26    real :: polat , rot
  27    real :: rparent_gridpts
  28    real :: xa,xb,ya,yb,xxa,xxy,yya,yyb
  29    real :: xs, xe, ys, ye
  30    integer :: jproj, jgrid, jlts, iusout, idot, ier
  31    integer :: ltype , idom
  32
  33    real, dimension(MAX_DOMAINS) :: parent_ll_x, parent_ll_y, parent_ur_x, parent_ur_y
  34
  35    character (len=128) :: geog_data_path, opt_output_from_geogrid_path, opt_geogrid_tbl_path
  36    character (len=128), dimension(MAX_DOMAINS) :: geog_data_res
  37    character (len=128) :: map_proj
  38    character (len=128), dimension(MAX_DOMAINS) :: start_date, end_date
  39    character (len=3) :: wrf_core
  40    character (len=1) :: gridtype
  41
  42    logical :: do_tiled_output
  43    integer :: debug_level
  44    logical :: is_used
  45
  46    type (proj_info) :: map_projection
  47
  48    namelist /share/ wrf_core, max_dom, start_date, end_date, &
  49                      start_year, end_year, start_month, end_month, &
  50                      start_day, end_day, start_hour, end_hour, &
  51                      interval_seconds, io_form_geogrid, opt_output_from_geogrid_path, &
  52                      debug_level, active_grid
  53    namelist /geogrid/ parent_id, parent_grid_ratio, &
  54                       i_parent_start, j_parent_start, s_we, e_we, s_sn, e_sn, &
  55                       map_proj, ref_x, ref_y, ref_lat, ref_lon, &
  56                       truelat1, truelat2, stand_lon, dx, dy, &
  57                       geog_data_res, geog_data_path, opt_geogrid_tbl_path
  58
  59    ! Set defaults for namelist variables
  60    debug_level = 0
  61    io_form_geogrid = 2
  62    wrf_core = 'ARW'
  63    max_dom = 1
  64    geog_data_path = 'NOT_SPECIFIED'
  65    ref_x = NAN
  66    ref_y = NAN
  67    ref_lat = NAN
  68    ref_lon = NAN
  69    dx = 10000.
  70    dy = 10000.
  71    map_proj = 'Lambert'
  72    truelat1 = NAN
  73    truelat2 = NAN
  74    stand_lon = NAN
  75    do i=1,MAX_DOMAINS
  76       geog_data_res(i) = 'default'
  77       parent_id(i) = 1
  78       parent_grid_ratio(i) = INVALID
  79       s_we(i) = 1
  80       e_we(i) = INVALID
  81       s_sn(i) = 1
  82       e_sn(i) = INVALID
  83       start_year(i) = 0
  84       start_month(i) = 0
  85       start_day(i) = 0
  86       start_hour(i) = 0
  87       end_year(i) = 0
  88       end_month(i) = 0
  89       end_day(i) = 0
  90       end_hour(i) = 0
  91       start_date(i) = '0000-00-00_00:00:00'
  92       end_date(i) = '0000-00-00_00:00:00'
  93    end do
  94    opt_output_from_geogrid_path = './'
  95    opt_geogrid_tbl_path = 'geogrid/'
  96    interval_seconds = INVALID
  97
  98    ! Read parameters from Fortran namelist
  99    do funit=10,100
 100       inquire(unit=funit, opened=is_used)
 101       if (.not. is_used) exit
 102    end do
 103    open(funit,file='namelist.wps',status='old',form='formatted',err=1000)
 104    read(funit,share)
 105    read(funit,geogrid)
 106    close(funit)
 107
 108    dxkm = dx
 109    dykm = dy
 110
 111    known_lat = ref_lat
 112    known_lon = ref_lon
 113    known_x = ref_x
 114    known_y = ref_y
 115
 116    ! Convert wrf_core to uppercase letters
 117    do i=1,3
 118       if (ichar(wrf_core(i:i)) >= 97) wrf_core(i:i) = char(ichar(wrf_core(i:i))-32)
 119    end do
 120
 121    ! Before doing anything else, we must have a valid grid type
 122    gridtype = ' '
 123    if (wrf_core == 'ARW') then
 124       gridtype = 'C'
 125       dyn_opt = 2
 126    else if (wrf_core == 'NMM') then
 127       gridtype = 'E'
 128       dyn_opt = 4
 129    end if
 130
 131    if (gridtype /= 'C' .and. gridtype /= 'E') then
 132       write(6,*) 'A valid wrf_core must be specified in the namelist. '// &
 133                  'Currently, only "ARW" and "NMM" are supported.'
 134       stop
 135    end if
 136
 137    if (max_dom > MAX_DOMAINS) then
 138       write(6,*) 'In namelist, max_dom must be <= ',MAX_DOMAINS,'. To run with more'// &
 139                 ' than ',MAX_DOMAINS,' domains, increase the MAX_DOMAINS parameter.'
 140       stop
 141    end if
 142
 143    ! Every domain must have a valid parent id
 144    do i=2,max_dom
 145       if (parent_id(i) <= 0 .or. parent_id(i) >= i) then
 146          write(6,*) 'In namelist, the parent_id of domain ',i,' must be in '// &
 147                    'the range 1 to ',i-1
 148           stop
 149       end if
 150    end do
 151
 152    ! Convert map_proj to uppercase letters
 153    do i=1,len(map_proj)
 154       if (ichar(map_proj(i:i)) >= 97) map_proj(i:i) = char(ichar(map_proj(i:i))-32)
 155    end do
 156
 157    ! Assign parameters to module variables
 158    if ((index(map_proj, 'LAMBERT') /= 0) .and. &
 159        (len_trim(map_proj) == len('LAMBERT'))) then
 160       iproj_type = PROJ_LC
 161       rot=truelat1
 162       polat=truelat2
 163       jproj = 3
 164
 165    else if ((index(map_proj, 'MERCATOR') /= 0) .and. &
 166             (len_trim(map_proj) == len('MERCATOR'))) then
 167       iproj_type = PROJ_MERC
 168       rot=0.
 169       polat=0.
 170       jproj = 9
 171
 172    else if ((index(map_proj, 'POLAR') /= 0) .and. &
 173             (len_trim(map_proj) == len('POLAR'))) then
 174       iproj_type = PROJ_PS
 175       rot=0.
 176       polat=SIGN(90., ref_lat)
 177       jproj = 1
 178
 179    else if ((index(map_proj, 'ROTATED_LL') /= 0) .and. &
 180             (len_trim(map_proj) == len('ROTATED_LL'))) then
 181       iproj_type = PROJ_ROTLL
 182
 183    else
 184          write(6,*) 'In namelist, invalid map_proj specified. Valid '// &
 185                     'projections are "lambert", "mercator", "polar", '// &
 186                     'and "rotated_ll".'
 187          stop
 188    end if
 189
 190    n_domains = max_dom
 191
 192    do i=1,n_domains
 193       ixdim(i) = e_we(i) - s_we(i) + 1
 194       jydim(i) = e_sn(i) - s_sn(i) + 1
 195    end do
 196
 197    ! If the user hasn't supplied a known_x and known_y, assume the center of domain 1
 198    if (known_x == NAN) known_x = ixdim(1) / 2.
 199    if (known_y == NAN) known_y = jydim(1) / 2.
 200
 201    ! Checks specific to C grid
 202    if (gridtype == 'C') then
 203
 204       ! C grid does not support the rotated lat/lon projection
 205       if (iproj_type == PROJ_ROTLL) then
 206          write(6,*) 'Rotated lat/lon projection is not supported for the ARW core. '// &
 207                     'Valid projecitons are "lambert", "mercator", and "polar".'
 208          stop
 209       end if
 210
 211       ! Check that nests have an acceptable number of grid points in each dimension
 212       do i=2,n_domains
 213          rparent_gridpts = real(ixdim(i)-1)/real(parent_grid_ratio(i))
 214          if (floor(rparent_gridpts) /= ceiling(rparent_gridpts)) then
 215             write(6,*) 'For nest ',i,' (e_we-s_we+1) must be one greater than an '// &
 216                        'integer multiple of the parent_grid_ratio.'
 217             stop
 218          end if
 219          rparent_gridpts = real(jydim(i)-1)/real(parent_grid_ratio(i))
 220          if (floor(rparent_gridpts) /= ceiling(rparent_gridpts)) then
 221             write(6,*) 'For nest ',i,' (e_sn-s_sn+1) must be one greater than an '// &
 222                        'integer multiple of the parent_grid_ratio.'
 223             stop
 224          end if
 225       end do
 226    end if
 227
 228    ! Checks specific to E grid
 229    if (gridtype == 'E') then
 230
 231       ! E grid supports only the rotated lat/lon projection
 232       if (iproj_type /= PROJ_ROTLL) then
 233          write(6,*) 'Rotated lat/lon is the only supported projection for the NMM core.'
 234          stop
 235       end if
 236
 237       ! Check that the parent_grid_ratio is set to 3 for all nests
 238       do i=2,n_domains
 239          if (parent_grid_ratio(i) /= 3) then
 240             write(6,*) 'The parent_grid_ratio must be set to 3 for the NMM core.'
 241             stop
 242          end if
 243       end do
 244
 245       CALL plot_e_grid ( ref_lat , -1. * ref_lon , &
 246                          dy , dx, &
 247                          n_domains , &
 248                          e_we , e_sn , &
 249                          parent_id , parent_grid_ratio , &
 250                          i_parent_start , j_parent_start )
 251       stop
 252    end if
 253
 254    do i=1,n_domains
 255       parent_ll_x(i) = real(i_parent_start(i))
 256       parent_ll_y(i) = real(j_parent_start(i))
 257       parent_ur_x(i) = real(i_parent_start(i))+real(ixdim(i))/real(parent_grid_ratio(i))-1.
 258       parent_ur_y(i) = real(j_parent_start(i))+real(jydim(i))/real(parent_grid_ratio(i))-1.
 259    end do
 260
 261    call map_init(map_projection)
 262
 263    call map_set(iproj_type, map_projection, &
 264                 lat1=known_lat, &
 265                 lon1=known_lon, &
 266                 knowni=known_x, &
 267                 knownj=known_y, &
 268                 dx=dx, &
 269                 stdlon=stand_lon, &
 270                 truelat1=truelat1, &
 271                 truelat2=truelat2, &
 272                 ixdim=ixdim(1), &
 273                 jydim=jydim(1))
 274
 275    call ij_to_latlon(map_projection, 0.5, 0.5, rlats, rlons)
 276    call ij_to_latlon(map_projection, real(e_we(1))-0.5, real(e_sn(1))-0.5, rlate, rlone)
 277
 278    call opngks
 279
 280    ! Set some colors
 281    call gscr(1, 0, 1.00, 1.00, 1.00)
 282    call gscr(1, 1, 0.00, 0.00, 0.00)
 283
 284    ! Do not grind them with details
 285    jgrid=10
 286    jlts=-2
 287    iusout=1
 288    idot=0
 289
 290    call supmap(jproj,polat,stand_lon,rot,&
 291                rlats,rlons,rlate,rlone, &
 292                jlts,jgrid,iusout,idot,ier)
 293
 294    call setusv('LW',1000)
 295    call perim(e_we(1)-1,1,e_sn(1)-1,1)
 296    call getset(xa,xb,ya,yb,xxa,xxy,yya,yyb,ltype)
 297    call set   (xa,xb,ya,yb, &
 298          1.,real(e_we(1)),1.,real(e_sn(1)),ltype)
 299
 300    do idom = 2 , max_dom
 301       call getxy ( xs, xe, ys, ye, &
 302                    idom , max_dom , &
 303                    e_we , e_sn , &
 304                    parent_id , parent_grid_ratio , &
 305                    i_parent_start , j_parent_start )
 306       call line ( xs , ys , xe , ys )
 307       call line ( xe , ys , xe , ye )
 308       call line ( xe , ye , xs , ye )
 309       call line ( xs , ye , xs , ys )
 310    end do
 311
 312    call frame
 313
 314    write(6,*) ' '
 315    write(6,*) 'Creating plot in NCAR Graphics metafile...'
 316    write(6,*) ' '
 317
 318    call clsgks
 319
 320    write(6,*) ' *** Successful completion of program plotgrids.exe *** '
 321
 322
 323    stop
 324
 325 1000 write(6,*) 'Error opening namelist.wps'
 326    stop
 327
 328 end program plotgrids
 329
 330 subroutine getxy ( xs, xe, ys, ye, &
 331                    dom_id , num_domains , &
 332                    e_we , e_sn , &
 333                    parent_id , parent_grid_ratio , &
 334                    i_parent_start , j_parent_start )
 335
 336    implicit none
 337
 338    integer , intent(in) :: dom_id
 339    integer , intent(in) :: num_domains
 340    integer , intent(in) , dimension(num_domains):: e_we , e_sn , &
 341                                                    parent_id , parent_grid_ratio , &
 342                                                    i_parent_start , j_parent_start
 343    real , intent(out) :: xs, xe, ys, ye
 344
 345
 346    !  local vars
 347
 348    integer :: idom
 349
 350    xs = 0.
 351    xe = e_we(dom_id) -1
 352    ys = 0.
 353    ye = e_sn(dom_id) -1
 354
 355    idom = dom_id
 356    compute_xy : DO
 357
 358       xs = (i_parent_start(idom) + xs  -1 ) / &
 359            real(parent_grid_ratio(parent_id(idom)))
 360       xe = xe / real(parent_grid_ratio(idom))
 361
 362       ys = (j_parent_start(idom) + ys  -1 ) / &
 363            real(parent_grid_ratio(parent_id(idom)))
 364       ye = ye / real(parent_grid_ratio(idom))
 365
 366       idom = parent_id(idom)
 367       if ( idom .EQ. 1 ) then
 368          exit compute_xy
 369       end if
 370
 371    END DO compute_xy
 372
 373    xs = xs + 1
 374    xe = xs + xe
 375    ys = ys + 1
 376    ye = ys + ye
 377
 378 end subroutine getxy
 379
 380 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 381 !!!!!!  E GRID MAP INFO BELOW     !!!!!!!!!!!!!!
 382 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 383
 384 SUBROUTINE plot_e_grid ( rlat0d , rlon0d , dphd , dlmd, &
 385                          n_domains , &
 386                          e_we , e_sn , &
 387                          parent_id , parent_grid_ratio , &
 388                          i_parent_start , j_parent_start )
 389
 390 !  This routine generates a gmeta file of the area covered by an Arakawa e-grid.
 391 !  We assume that NCAR Graphics has not been called yet (and will be closed
 392 !  upon exit).  The required input fields are as from the WPS namelist file.
 393
 394    IMPLICIT NONE
 395
 396 !  15 April 2005 NCEP/EMC
 397 !    The Code and some instructions are provided by Tom BLACK to
 398 !    NCAR/DTC Meral Demirtas
 399
 400 !  4 May 2005  NCAR/DTC Meral DEMIRTAS
 401 !    - An include file (plot_inc) is added to get
 402 !    Domain size: IM,JM
 403 !    Central latitute and longnitute: RLAT0D,RLON0D
 404 !    Horizontal resolution: DPHD, DLMD
 405
 406 !  Feb 2007 NCAR/MMM
 407 !    Turn into f90
 408 !    Add implicit none
 409 !    Remove non-mapping portions
 410 !    Make part of WPS domain plotting utility
 411
 412 !  Dec 2008 NCAR/DTC
 413 !    Pass additional arguments to enable plotting of nests
 414
 415    !  Input map parameters for E grid.
 416
 417    REAL , INTENT(IN)    :: rlat0d , & ! latitude of grid center (degrees)
 418                            rlon0d     ! longitude of grid center (degrees, times -1)
 419
 420    REAL , INTENT(IN)    :: dphd , &   ! angular distance between rows (degrees)
 421                            dlmd       ! angular distance between adjacent H and V points (degrees)
 422
 423    INTEGER , INTENT(in) :: n_domains  ! number of domains
 424    INTEGER , INTENT(in) , DIMENSION(n_domains):: e_we , &
 425                                                  e_sn , &
 426                                                  parent_id , &
 427                                                  parent_grid_ratio , &
 428                                                  i_parent_start , &
 429                                                  j_parent_start
 430
 431    !  Some local vars
 432
 433    REAL :: rlat1d , &
 434            rlon1d
 435
 436    INTEGER :: im, &     ! number of H points in odd rows
 437               jm , &    ! number of rows
 438               ngpwe , &
 439               ngpsn , &
 440               ilowl , &
 441               jlowl
 442
 443    INTEGER :: imt , imtjm
 444    REAL :: latlft,lonlft,latrgt,lonrgt
 445
 446    im = e_we(1)-1
 447    jm = e_sn(1)-1
 448
 449    imt=2*im-1
 450    imtjm=imt*jm
 451    rlat1d=rlat0d
 452    rlon1d=rlon0d
 453    ngpwe=2*im-1
 454    ngpsn=jm
 455
 456    !  Get lat and lon of left and right points.
 457
 458    CALL corners ( rlat1d,rlon1d,im,jm,rlat0d,rlon0d,dphd,dlmd,&
 459                   ngpwe,ngpsn,ilowl,jlowl,latlft,lonlft,latrgt,lonrgt)
 460
 461    !  With corner points, make map background.
 462
 463    CALL mapbkg_egrid ( imt,jm,ilowl,jlowl,ngpwe,ngpsn,&
 464                        rlat0d,rlon0d,latlft,lonlft,latrgt,lonrgt,&
 465                        dlmd,dphd,&
 466                        n_domains,&
 467                        e_we,e_sn,&
 468                        parent_id,parent_grid_ratio,&
 469                        i_parent_start,j_parent_start)
 470
 471 END SUBROUTINE plot_e_grid
 472
 473 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 474
 475 SUBROUTINE corners ( glatd,glond,im,jm,tph0d,tlm0d,dphd,dlmd,&
 476                      ngpwe,ngpsn,ilowl,jlowl,glatl,glonl,glatr,glonr)
 477
 478    IMPLICIT NONE
 479
 480    REAL , INTENT(IN) :: glatd,glond,tph0d,tlm0d,dphd,dlmd,&
 481                         glatl,glonl,glatr,glonr
 482
 483    INTEGER , INTENT(IN) :: im,jm,ngpwe,ngpsn
 484    INTEGER , INTENT(OUT) :: ilowl,jlowl
 485
 486    !  Local vars
 487
 488    REAL , PARAMETER :: d2r = 1.74532925E-2 , r2D = 1./D2R
 489
 490    REAL :: glat , glon , dph , dlm , tph0 , tlm0
 491    REAL :: x , y , z , tlat , tlon , tlat1 , tlat2 , tlon1 , tlon2
 492    REAL :: row , col
 493    REAL :: dlm1 , dlm2 , d1 , d2 , d3 , d4 , dmin
 494
 495    INTEGER :: jmt , ii , jj , iuppr , juppr
 496    INTEGER :: nrow , ncol
 497
 498    jmt = jm/2+1
 499
 500    !  Convert from geodetic to transformed coordinates (degrees).
 501
 502    glat = glatd * d2r
 503    glon = glond * d2r
 504    dph = dphd * d2r
 505    dlm = dlmd * d2r
 506    tph0 = tph0d * d2r
 507    tlm0 = tlm0d * d2r
 508
 509    x = COS(tph0) * COS(glat) * COS(glon-tlm0)+SIN(tph0) * SIN(glat)
 510    y = -COS(glat) * SIN(glon-tlm0)
 511    z = COS(tph0) * SIN(glat)-SIN(tph0) * COS(glat) * COS(glon-tlm0)
 512    tlat = r2d * ATAN(z/SQRT(x*x + y*y))
 513    tlon = r2d * ATAN(y/x)
 514
 515    !  Find the real (non-integer) row and column of the input location on
 516    !  the filled e-grid.
 517
 518    row = tlat/dphd+jmt
 519    col = tlon/dlmd+im
 520    nrow = INT(row)
 521    ncol = INT(col)
 522    tlat = tlat * d2r
 523    tlon = tlon * d2r
 524
 525 !               E2     E3
 526 !
 527 !
 528 !                  X
 529 !               E1     E4
 530
 531    tlat1 = (nrow-jmt) * dph
 532    tlat2 = tlat1+dph
 533    tlon1 = (ncol-im) * dlm
 534    tlon2 = tlon1+dlm
 535
 536    dlm1 = tlon-tlon1
 537    dlm2 = tlon-tlon2
 538
 539    d1 = ACOS(COS(tlat) * COS(tlat1) * COS(dlm1)+SIN(tlat) * SIN(tlat1))
 540    d2 = ACOS(COS(tlat) * COS(tlat2) * COS(dlm1)+SIN(tlat) * SIN(tlat2))
 541    d3 = ACOS(COS(tlat) * COS(tlat2) * COS(dlm2)+SIN(tlat) * SIN(tlat2))
 542    d4 = ACOS(COS(tlat) * COS(tlat1) * COS(dlm2)+SIN(tlat) * SIN(tlat1))
 543
 544    dmin = MIN(d1,d2,d3,d4)
 545
 546    IF      ( ABS(dmin-d1) .LT. 1.e-6 ) THEN
 547      ii = ncol
 548      jj = nrow
 549    ELSE IF ( ABS(dmin-d2) .LT. 1.e-6 ) THEN
 550      ii = ncol
 551      jj = nrow+1
 552    ELSE IF ( ABS(dmin-d3) .LT. 1.e-6 ) THEN
 553      ii = ncol+1
 554      jj = nrow+1
 555    ELSE IF ( ABS(dmin-d4) .LT. 1.e-6 ) THEN
 556      ii = ncol+1
 557      jj = nrow
 558    END IF
 559
 560    !  Now find the i and j of the lower left corner of the desired grid
 561    !  region and of the upper right.
 562
 563    ilowl = ii-ngpwe/2
 564    jlowl = jj-ngpsn/2
 565    iuppr = ii+ngpwe/2
 566    juppr = jj+ngpsn/2
 567
 568    !  Find their geodetic coordinates.
 569
 570    CALL e2t2g(ilowl,jlowl,im,jm,tph0d,tlm0d,dphd,dlmd,glatl,glonl)
 571    CALL e2t2g(iuppr,juppr,im,jm,tph0d,tlm0d,dphd,dlmd,glatr,glonr)
 572
 573 END SUBROUTINE corners
 574
 575 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 576
 577 SUBROUTINE mapbkg_egrid ( imt,jm,ilowl,jlowl,ngpwe,ngpsn,&
 578                           rlat0d,rlon0d,glatl,glonl,glatr,glonr,&
 579                           dlmd,dphd,&
 580                           n_domains,&
 581                           e_we,e_sn,&
 582                           parent_id,parent_grid_ratio,&
 583                           i_parent_start , j_parent_start )
 584
 585 !  IMPLICIT NONE
 586
 587    INTEGER , INTENT(in) :: n_domains
 588    INTEGER , INTENT(in) , DIMENSION(n_domains):: e_we , e_sn , &
 589                                                  parent_id , parent_grid_ratio , &
 590                                                  i_parent_start , j_parent_start
 591
 592    !  Some local vars
 593
 594    CHARACTER (LEN=97) :: string
 595    INTEGER :: i
 596    REAL :: xs, xe, ys, ye
 597
 598    !  Yet more center lon messing around, hoo boy.
 599
 600 !  clonx=180.-rlon0d
 601    clonx=-rlon0d
 602
 603    !  Open up NCAR Graphics
 604
 605    CALL opngks
 606    CALL gopwk(8,9,3)
 607    CALL gsclip(0)
 608
 609    !  Make the background white, and the foreground black.
 610
 611    CALL gscr ( 1 , 0 , 1., 1., 1. )
 612    CALL gscr ( 1 , 1 , 0., 0., 0. )
 613
 614    !  Line width default thickness.
 615
 616    CALL setusv('LW',1000)
 617
 618    !  Make map outline a solid line, not dots.
 619
 620    CALL mapsti('MV',8)
 621    CALL mapsti('DO',0)
 622
 623    !  Map outlines are political and states.
 624
 625    CALL mapstc('OU','PS')
 626
 627    !  Cylindrical equidistant.
 628
 629    CALL maproj('CE',rlat0d,clonx,0.)
 630
 631    !  Specify corner points.
 632
 633    CALL mapset('CO',glatl,glonl,glatr,glonr)
 634
 635    !  Lat lon lines every 5 degrees.
 636
 637    CALL mapsti('GR',5)
 638
 639    !  Map takes up this much real estate.
 640
 641    CALL mappos( 0.05 , 0.95 , 0.05 , 0.95 )
 642
 643    !  Initialize and draw map.
 644
 645    CALL mapint
 646    CALL mapdrw
 647
 648    !  Line width twice default thickness.
 649
 650    CALL setusv('LW',2000)
 651
 652    !  Add approx grid point tick marks
 653
 654    CALL perim(((imt+3)/2)-1,1,jm-1,1)
 655
 656    !  Line width default thickness.
 657
 658    CALL setusv('LW',1000)
 659
 660    !  Put on a quicky description.
 661
 662    WRITE ( string , FMT = '("E-GRID E_WE = ",I4,", E_SN = ",I4 , &
 663                             &", DX = ",F6.4,", DY = ",F6.4 , &
 664                             &", REF_LAT = ",F8.3,", REF_LON = ",F8.3)') &
 665                             (imt+3)/2,jm+1,dlmd,dphd,rlat0d,-1.*rlon0d
 666    CALL getset(xa,xb,ya,yb,xxa,xxy,yya,yyb,ltype)
 667    CALL pchiqu(xxa,yya-(yyb-yya)/20.,string,8.,0.,-1.)
 668    CALL set   (xa,xb,ya,yb,&
 669                1.,real(e_we(1)),1.,real(e_sn(1)),ltype)
 670
 671    !  Line width twice default thickness.
 672
 673    CALL setusv('LW',2000)
 674
 675    !  Draw a box for each nest.
 676
 677    do i=2 , n_domains
 678       call getxy ( xs, xe, ys, ye, &
 679                    i , n_domains , &
 680                    e_we , e_sn , &
 681                    parent_id , parent_grid_ratio , &
 682                    i_parent_start , j_parent_start )
 683
 684       call line ( xs , ys , xe , ys )
 685       call line ( xe , ys , xe , ye )
 686       call line ( xe , ye , xs , ye )
 687       call line ( xs , ye , xs , ys )
 688    end do
 689
 690    CALL frame
 691
 692    !  Close workstation and NCAR Grpahics.
 693
 694    CALL gclwk(8)
 695    CALL clsgks
 696
 697 END SUBROUTINE mapbkg_egrid
 698
 699 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 700
 701 SUBROUTINE e2t2g ( ncol,nrow,im,jm,tph0d,tlm0d,dphd,dlmd,glatd,glond)
 702
 703 !  IMPLICIT NONE
 704
 705    REAL , PARAMETER :: D2R=1.74532925E-2 , R2D=1./D2R
 706
 707    DPH=DPHD*D2R
 708    DLM=DLMD*D2R
 709    TPH0=TPH0D*D2R
 710    TLM0=TLM0D*D2R
 711
 712 !***  FIND THE TRANSFORMED LAT (POSITIVE NORTH) AND LON (POSITIVE EAST)
 713
 714    TLATD=(NROW-(JM+1)/2)*DPHD
 715    TLOND=(NCOL-IM)*DLMD
 716
 717 !***  NOW CONVERT TO GEODETIC LAT (POSITIVE NORTH) AND LON (POSITIVE EAST)
 718
 719    TLATR=TLATD*D2R
 720    TLONR=TLOND*D2R
 721    ARG1=SIN(TLATR)*COS(TPH0)+COS(TLATR)*SIN(TPH0)*COS(TLONR)
 722    GLATR=ASIN(ARG1)
 723    GLATD=GLATR*R2D
 724    ARG2=COS(TLATR)*COS(TLONR)/(COS(GLATR)*COS(TPH0))- &
 725         TAN(GLATR)*TAN(TPH0)
 726    IF(ABS(ARG2).GT.1.)ARG2=ABS(ARG2)/ARG2
 727    FCTR=1.
 728    IF(TLOND.GT.0.)FCTR=-1.
 729    GLOND=TLM0D+FCTR*ACOS(ARG2)*R2D
 730    GLOND=-GLOND
 731
 732 END SUBROUTINE e2t2g