ungrib/src/ngl/w3/getgbm.f

   1 C-----------------------------------------------------------------------
   2       SUBROUTINE GETGBM(LUGB,LUGI,JF,J,JPDS,JGDS,
   3      &                  MBUF,CBUF,NLEN,NNUM,MNUM,
   4      &                  KF,K,KPDS,KGDS,LB,F,IRET)
   5 C$$$  SUBPROGRAM DOCUMENTATION BLOCK
   6 C
   7 C SUBPROGRAM: GETGBM         FINDS AND UNPACKS A GRIB MESSAGE
   8 C   PRGMMR: IREDELL          ORG: W/NMC23     DATE: 94-04-01
   9 C
  10 C ABSTRACT: FIND AND UNPACK A GRIB MESSAGE.
  11 C   READ A GRIB INDEX FILE (OR OPTIONALLY THE GRIB FILE ITSELF)
  12 C   TO GET THE INDEX BUFFER (I.E. TABLE OF CONTENTS) FOR THE GRIB FILE.
  13 C   FIND IN THE INDEX BUFFER A REFERENCE TO THE GRIB MESSAGE REQUESTED.
  14 C   THE GRIB MESSAGE REQUEST SPECIFIES THE NUMBER OF MESSAGES TO SKIP
  15 C   AND THE UNPACKED PDS AND GDS PARAMETERS.  (A REQUESTED PARAMETER
  16 C   OF -1 MEANS TO ALLOW ANY VALUE OF THIS PARAMETER TO BE FOUND.)
  17 C   IF THE REQUESTED GRIB MESSAGE IS FOUND, THEN IT IS READ FROM THE
  18 C   GRIB FILE AND UNPACKED.  ITS MESSAGE NUMBER IS RETURNED ALONG WITH
  19 C   THE UNPACKED PDS AND GDS PARAMETERS, THE UNPACKED BITMAP (IF ANY),
  20 C   AND THE UNPACKED DATA.  IF THE GRIB MESSAGE IS NOT FOUND, THEN THE
  21 C   RETURN CODE WILL BE NONZERO.
  22 C
  23 C PROGRAM HISTORY LOG:
  24 C   94-04-01  IREDELL
  25 C   95-10-31  IREDELL     MODULARIZED PORTIONS OF CODE INTO SUBPROGRAMS
  26 C                         AND ALLOWED FOR UNSPECIFIED INDEX FILE
  27 C   04-07-22  CHUANG     ADD NBITSS TO THE ARGUMENT LIST OF GETGB1R THAT
  28 C                        IS CALLED IN THIS SUBROUTINE
  29 C   10-03-02  WANG       INCREASE MSK1 TO 256000000 FOR NEMSIO FILES
  30 C
  31 C USAGE:    CALL GETGBM(LUGB,LUGI,JF,J,JPDS,JGDS,
  32 C    &                  MBUF,CBUF,NLEN,NNUM,MNUM,
  33 C    &                  KF,K,KPDS,KGDS,LB,F,IRET)
  34 C   INPUT ARGUMENTS:
  35 C     LUGB         INTEGER UNIT OF THE UNBLOCKED GRIB DATA FILE
  36 C     LUGI         INTEGER UNIT OF THE UNBLOCKED GRIB INDEX FILE
  37 C                  (=0 TO GET INDEX BUFFER FROM THE GRIB FILE)
  38 C     JF           INTEGER MAXIMUM NUMBER OF DATA POINTS TO UNPACK
  39 C     J            INTEGER NUMBER OF MESSAGES TO SKIP
  40 C                  (=0 TO SEARCH FROM BEGINNING)
  41 C                  (<0 TO READ INDEX BUFFER AND SKIP -1-J MESSAGES)
  42 C     JPDS         INTEGER (200) PDS PARAMETERS FOR WHICH TO SEARCH
  43 C                  (=-1 FOR WILDCARD)
  44 C          (1)   - ID OF CENTER
  45 C          (2)   - GENERATING PROCESS ID NUMBER
  46 C          (3)   - GRID DEFINITION
  47 C          (4)   - GDS/BMS FLAG (RIGHT ADJ COPY OF OCTET 8)
  48 C          (5)   - INDICATOR OF PARAMETER
  49 C          (6)   - TYPE OF LEVEL
  50 C          (7)   - HEIGHT/PRESSURE , ETC OF LEVEL
  51 C          (8)   - YEAR INCLUDING (CENTURY-1)
  52 C          (9)   - MONTH OF YEAR
  53 C          (10)  - DAY OF MONTH
  54 C          (11)  - HOUR OF DAY
  55 C          (12)  - MINUTE OF HOUR
  56 C          (13)  - INDICATOR OF FORECAST TIME UNIT
  57 C          (14)  - TIME RANGE 1
  58 C          (15)  - TIME RANGE 2
  59 C          (16)  - TIME RANGE FLAG
  60 C          (17)  - NUMBER INCLUDED IN AVERAGE
  61 C          (18)  - VERSION NR OF GRIB SPECIFICATION
  62 C          (19)  - VERSION NR OF PARAMETER TABLE
  63 C          (20)  - NR MISSING FROM AVERAGE/ACCUMULATION
  64 C          (21)  - CENTURY OF REFERENCE TIME OF DATA
  65 C          (22)  - UNITS DECIMAL SCALE FACTOR
  66 C          (23)  - SUBCENTER NUMBER
  67 C          (24)  - PDS BYTE 29, FOR NMC ENSEMBLE PRODUCTS
  68 C                  128 IF FORECAST FIELD ERROR
  69 C                   64 IF BIAS CORRECTED FCST FIELD
  70 C                   32 IF SMOOTHED FIELD
  71 C                  WARNING: CAN BE COMBINATION OF MORE THAN 1
  72 C          (25)  - PDS BYTE 30, NOT USED
  73 C     JGDS         INTEGER (200) GDS PARAMETERS FOR WHICH TO SEARCH
  74 C                  (ONLY SEARCHED IF JPDS(3)=255)
  75 C                  (=-1 FOR WILDCARD)
  76 C          (1)   - DATA REPRESENTATION TYPE
  77 C          (19)  - NUMBER OF VERTICAL COORDINATE PARAMETERS
  78 C          (20)  - OCTET NUMBER OF THE LIST OF VERTICAL COORDINATE
  79 C                  PARAMETERS
  80 C                  OR
  81 C                  OCTET NUMBER OF THE LIST OF NUMBERS OF POINTS
  82 C                  IN EACH ROW
  83 C                  OR
  84 C                  255 IF NEITHER ARE PRESENT
  85 C          (21)  - FOR GRIDS WITH PL, NUMBER OF POINTS IN GRID
  86 C          (22)  - NUMBER OF WORDS IN EACH ROW
  87 C       LATITUDE/LONGITUDE GRIDS
  88 C          (2)   - N(I) NR POINTS ON LATITUDE CIRCLE
  89 C          (3)   - N(J) NR POINTS ON LONGITUDE MERIDIAN
  90 C          (4)   - LA(1) LATITUDE OF ORIGIN
  91 C          (5)   - LO(1) LONGITUDE OF ORIGIN
  92 C          (6)   - RESOLUTION FLAG (RIGHT ADJ COPY OF OCTET 17)
  93 C          (7)   - LA(2) LATITUDE OF EXTREME POINT
  94 C          (8)   - LO(2) LONGITUDE OF EXTREME POINT
  95 C          (9)   - DI LONGITUDINAL DIRECTION OF INCREMENT
  96 C          (10)  - DJ LATITUDINAL DIRECTION INCREMENT
  97 C          (11)  - SCANNING MODE FLAG (RIGHT ADJ COPY OF OCTET 28)
  98 C       GAUSSIAN  GRIDS
  99 C          (2)   - N(I) NR POINTS ON LATITUDE CIRCLE
 100 C          (3)   - N(J) NR POINTS ON LONGITUDE MERIDIAN
 101 C          (4)   - LA(1) LATITUDE OF ORIGIN
 102 C          (5)   - LO(1) LONGITUDE OF ORIGIN
 103 C          (6)   - RESOLUTION FLAG  (RIGHT ADJ COPY OF OCTET 17)
 104 C          (7)   - LA(2) LATITUDE OF EXTREME POINT
 105 C          (8)   - LO(2) LONGITUDE OF EXTREME POINT
 106 C          (9)   - DI LONGITUDINAL DIRECTION OF INCREMENT
 107 C          (10)  - N - NR OF CIRCLES POLE TO EQUATOR
 108 C          (11)  - SCANNING MODE FLAG (RIGHT ADJ COPY OF OCTET 28)
 109 C          (12)  - NV - NR OF VERT COORD PARAMETERS
 110 C          (13)  - PV - OCTET NR OF LIST OF VERT COORD PARAMETERS
 111 C                             OR
 112 C                  PL - LOCATION OF THE LIST OF NUMBERS OF POINTS IN
 113 C                       EACH ROW (IF NO VERT COORD PARAMETERS
 114 C                       ARE PRESENT
 115 C                             OR
 116 C                  255 IF NEITHER ARE PRESENT
 117 C       POLAR STEREOGRAPHIC GRIDS
 118 C          (2)   - N(I) NR POINTS ALONG LAT CIRCLE
 119 C          (3)   - N(J) NR POINTS ALONG LON CIRCLE
 120 C          (4)   - LA(1) LATITUDE OF ORIGIN
 121 C          (5)   - LO(1) LONGITUDE OF ORIGIN
 122 C          (6)   - RESOLUTION FLAG  (RIGHT ADJ COPY OF OCTET 17)
 123 C          (7)   - LOV GRID ORIENTATION
 124 C          (8)   - DX - X DIRECTION INCREMENT
 125 C          (9)   - DY - Y DIRECTION INCREMENT
 126 C          (10)  - PROJECTION CENTER FLAG
 127 C          (11)  - SCANNING MODE (RIGHT ADJ COPY OF OCTET 28)
 128 C       SPHERICAL HARMONIC COEFFICIENTS
 129 C          (2)   - J PENTAGONAL RESOLUTION PARAMETER
 130 C          (3)   - K      "          "         "
 131 C          (4)   - M      "          "         "
 132 C          (5)   - REPRESENTATION TYPE
 133 C          (6)   - COEFFICIENT STORAGE MODE
 134 C       MERCATOR GRIDS
 135 C          (2)   - N(I) NR POINTS ON LATITUDE CIRCLE
 136 C          (3)   - N(J) NR POINTS ON LONGITUDE MERIDIAN
 137 C          (4)   - LA(1) LATITUDE OF ORIGIN
 138 C          (5)   - LO(1) LONGITUDE OF ORIGIN
 139 C          (6)   - RESOLUTION FLAG (RIGHT ADJ COPY OF OCTET 17)
 140 C          (7)   - LA(2) LATITUDE OF LAST GRID POINT
 141 C          (8)   - LO(2) LONGITUDE OF LAST GRID POINT
 142 C          (9)   - LATIT - LATITUDE OF PROJECTION INTERSECTION
 143 C          (10)  - RESERVED
 144 C          (11)  - SCANNING MODE FLAG (RIGHT ADJ COPY OF OCTET 28)
 145 C          (12)  - LONGITUDINAL DIR GRID LENGTH
 146 C          (13)  - LATITUDINAL DIR GRID LENGTH
 147 C       LAMBERT CONFORMAL GRIDS
 148 C          (2)   - NX NR POINTS ALONG X-AXIS
 149 C          (3)   - NY NR POINTS ALONG Y-AXIS
 150 C          (4)   - LA1 LAT OF ORIGIN (LOWER LEFT)
 151 C          (5)   - LO1 LON OF ORIGIN (LOWER LEFT)
 152 C          (6)   - RESOLUTION (RIGHT ADJ COPY OF OCTET 17)
 153 C          (7)   - LOV - ORIENTATION OF GRID
 154 C          (8)   - DX - X-DIR INCREMENT
 155 C          (9)   - DY - Y-DIR INCREMENT
 156 C          (10)  - PROJECTION CENTER FLAG
 157 C          (11)  - SCANNING MODE FLAG (RIGHT ADJ COPY OF OCTET 28)
 158 C          (12)  - LATIN 1 - FIRST LAT FROM POLE OF SECANT CONE INTER
 159 C          (13)  - LATIN 2 - SECOND LAT FROM POLE OF SECANT CONE INTER
 160 C     MBUF         INTEGER LENGTH OF INDEX BUFFER IN BYTES
 161 C     CBUF         CHARACTER*1 (MBUF) INDEX BUFFER
 162 C                  (INITIALIZE BY SETTING J=-1)
 163 C     NLEN         INTEGER LENGTH OF EACH INDEX RECORD IN BYTES
 164 C                  (INITIALIZE BY SETTING J=-1)
 165 C     NNUM         INTEGER NUMBER OF INDEX RECORDS
 166 C                  (INITIALIZE BY SETTING J=-1)
 167 C     MNUM         INTEGER NUMBER OF INDEX RECORDS SKIPPED
 168 C                  (INITIALIZE BY SETTING J=-1)
 169 C   OUTPUT ARGUMENTS:
 170 C     CBUF         CHARACTER*1 (MBUF) INDEX BUFFER
 171 C     NLEN         INTEGER LENGTH OF EACH INDEX RECORD IN BYTES
 172 C     NNUM         INTEGER NUMBER OF INDEX RECORDS
 173 C     MNUM         INTEGER NUMBER OF INDEX RECORDS SKIPPED
 174 C     KF           INTEGER NUMBER OF DATA POINTS UNPACKED
 175 C     K            INTEGER MESSAGE NUMBER UNPACKED
 176 C                  (CAN BE SAME AS J IN CALLING PROGRAM
 177 C                  IN ORDER TO FACILITATE MULTIPLE SEARCHES)
 178 C     KPDS         INTEGER (200) UNPACKED PDS PARAMETERS
 179 C     KGDS         INTEGER (200) UNPACKED GDS PARAMETERS
 180 C     LB           LOGICAL*1 (KF) UNPACKED BITMAP IF PRESENT
 181 C     F            REAL (KF) UNPACKED DATA
 182 C     IRET         INTEGER RETURN CODE
 183 C                    0      ALL OK
 184 C                    96     ERROR READING INDEX FILE
 185 C                    97     ERROR READING GRIB FILE
 186 C                    98     NUMBER OF DATA POINTS GREATER THAN JF
 187 C                    99     REQUEST NOT FOUND
 188 C                    OTHER  W3FI63 GRIB UNPACKER RETURN CODE
 189 C
 190 C SUBPROGRAMS CALLED:
 191 C   GETGI          READ INDEX FILE
 192 C   GETGIR         READ INDEX BUFFER FROM GRIB FILE
 193 C   GETGB1S        SEARCH INDEX RECORDS
 194 C   GETGB1R        READ AND UNPACK GRIB RECORD
 195 C   LENGDS         RETURN THE LENGTH OF A GRID
 196 C
 197 C REMARKS: SPECIFY AN INDEX FILE IF FEASIBLE TO INCREASE SPEED.
 198 C   SUBPROGRAM CAN BE CALLED FROM A MULTIPROCESSING ENVIRONMENT.
 199 C   DO NOT ENGAGE THE SAME LOGICAL UNIT FROM MORE THAN ONE PROCESSOR.
 200 C
 201 C ATTRIBUTES:
 202 C   LANGUAGE: FORTRAN 77
 203 C   MACHINE:  CRAY, WORKSTATIONS
 204 C
 205 C$$$
 206       INTEGER JPDS(200),JGDS(200)
 207       INTEGER KPDS(200),KGDS(200)
 208       CHARACTER CBUF(MBUF)
 209       LOGICAL*1 LB(JF)
 210       REAL F(JF)
 211       PARAMETER(MSK1=256000000,MSK2=4000)
 212       INTEGER JENS(200),KENS(200)
 213 C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 214 C  SEARCH PREVIOUS INDEX BUFFER IF POSSIBLE
 215       JENS=-1
 216       IF(J.GE.0) THEN
 217         IF(MNUM.GE.0) THEN
 218           IRGI=0
 219         ELSE
 220           MNUM=-1-MNUM
 221           IRGI=1
 222         ENDIF
 223         JR=J-MNUM
 224         IF(JR.GE.0.AND.(JR.LT.NNUM.OR.IRGI.EQ.0)) THEN
 225           CALL GETGB1S(CBUF,NLEN,NNUM,JR,JPDS,JGDS,JENS,
 226      &                 KR,KPDS,KGDS,KENS,LSKIP,LGRIB,IRGS)
 227           IF(IRGS.EQ.0) K=KR+MNUM
 228           IF(IRGI.EQ.1.AND.IRGS.EQ.0) MNUM=-1-MNUM
 229           IF(IRGI.EQ.1.AND.IRGS.GT.0) MNUM=MNUM+NNUM
 230         ELSE
 231           MNUM=J
 232           IRGI=1
 233           IRGS=1
 234         ENDIF
 235       ELSE
 236         MNUM=-1-J
 237         IRGI=1
 238         IRGS=1
 239       ENDIF
 240 C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 241 C  READ AND SEARCH NEXT INDEX BUFFER
 242       JR=0
 243       DOWHILE(IRGI.EQ.1.AND.IRGS.EQ.1)
 244         IF(LUGI.GT.0) THEN
 245           CALL GETGI(LUGI,MNUM,MBUF,CBUF,NLEN,NNUM,IRGI)
 246         ELSE
 247           CALL GETGIR(LUGB,MSK1,MSK2,MNUM,MBUF,CBUF,NLEN,NNUM,IRGI)
 248         ENDIF
 249         IF(IRGI.LE.1) THEN
 250           CALL GETGB1S(CBUF,NLEN,NNUM,JR,JPDS,JGDS,JENS,
 251      &                 KR,KPDS,KGDS,KENS,LSKIP,LGRIB,IRGS)
 252           IF(IRGS.EQ.0) K=KR+MNUM
 253           IF(IRGI.EQ.1.AND.IRGS.EQ.0) MNUM=-1-MNUM
 254           IF(IRGI.EQ.1.AND.IRGS.GT.0) MNUM=MNUM+NNUM
 255         ENDIF
 256       ENDDO
 257 C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 258 C  READ AND UNPACK GRIB RECORD
 259       IF(IRGI.GT.1) THEN
 260         IRET=96
 261       ELSEIF(IRGS.NE.0) THEN
 262         IRET=99
 263       ELSEIF(LENGDS(KGDS).GT.JF) THEN
 264         IRET=98
 265       ELSE
 266         CALL GETGB1R(LUGB,LSKIP,LGRIB,KF,KPDS,KGDS,KENS,LB,F,NBITSS
 267      + ,IRET)
 268       ENDIF
 269 C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 270       RETURN
 271       END