CMakeLists.txt

   1 cmake_minimum_required( VERSION 3.20 )
   2 cmake_policy( SET CMP0118 NEW )
   3
   4 enable_language( C )
   5 enable_language( CXX )
   6 enable_language( Fortran )
   7
   8 project( WPS )
   9 set( EXPORT_NAME          ${PROJECT_NAME} )
  10 set( INTERNAL_GRIB2_PATH  ${CMAKE_INSTALL_PREFIX}/grib2 )
  11
  12 if ( NOT DEFINED WRF_DIR )
  13   message( STATUS "No WRF_DIR provided, skipping targets that rely on WRF" )
  14 endif()
  15
  16 list( APPEND CMAKE_MODULE_PATH
  17       ${PROJECT_SOURCE_DIR}/cmake/
  18       ${PROJECT_SOURCE_DIR}/cmake/modules
  19       )
  20
  21 # I'd love to be able to do something like this, but this would place a depedency
  22 # on WRF which would be bad since who would expect the *WRF Preprocessing System*
  23 # to have a strict dependency on WRF. Silly me
  24 # if ( DEFINED WRF_DIR )
  25 #   list( APPEND CMAKE_MODULE_PATH
  26 #       ${WRF_DIR}/share
  27 #       )
  28 # endif()
  29
  30 # Use link paths as rpaths
  31 set( CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE )
  32 set( CMAKE_Fortran_PREPROCESS          ON )
  33
  34 include( CMakePackageConfigHelpers )
  35 # include( confcheck   )
  36 # include( gitinfo     )
  37 include( wrf_get_version )
  38
  39 # Grab version info
  40 wrf_get_version( ${PROJECT_SOURCE_DIR}/README )
  41
  42 ################################################################################
  43 ##
  44 ## MPI & OpenMP
  45 ##
  46 ################################################################################
  47 if ( ${USE_MPI} )
  48   # Through ***MUCH*** debugging, if utilizing MPI_<LANG>_COMPILER
  49   # https://cmake.org/cmake/help/latest/module/FindMPI.html#variables-for-locating-mpi
  50   # the find logic makes a mess of things by utilizing <mpi> -show[me]
  51   # Which may or may not get polluted by the environment
  52   # It still technically finds MPI but the output is nonintuitive
  53   # saying things like hdf5 or pthread
  54   find_package( MPI REQUIRED COMPONENTS Fortran C )
  55   add_compile_definitions(
  56                           USE_MPI=1
  57                           DM_PARALLEL
  58                           )
  59
  60   if ( DEFINED WRF_MPI_Fortran_FLAGS AND NOT "${WRF_MPI_Fortran_FLAGS}" STREQUAL "" )
  61     add_compile_options(
  62                         $<$<COMPILE_LANGUAGE:Fortran>,${WRF_MPI_Fortran_FLAGS}>
  63                         )
  64   endif()
  65
  66   if ( DEFINED WRF_MPI_C_FLAGS AND NOT "${WRF_MPI_C_FLAGS}" STREQUAL "" )
  67     add_compile_options(
  68                         $<$<COMPILE_LANGUAGE:C>,${WRF_MPI_C_FLAGS}>
  69                         )
  70   endif()
  71 endif()
  72
  73 if ( ${USE_OPENMP} )
  74   find_package( OpenMP REQUIRED COMPONENTS Fortran C )
  75   add_compile_definitions( USE_OPENMP=1 SM_PARALLEL )
  76 endif()
  77
  78
  79 # First do externals
  80 if ( BUILD_EXTERNALS )
  81   add_subdirectory( external )
  82   # If we got here everything built, we are safe to add find paths for libs
  83   set( ZLIB_ROOT   ${INTERNAL_GRIB2_PATH} ) # This may get overridden by HDF5 if zlib is packaged with that
  84   set( PNG_ROOT    ${INTERNAL_GRIB2_PATH} )
  85   set( Jasper_ROOT ${INTERNAL_GRIB2_PATH} )
  86 endif()
  87
  88
  89 # Now find required libraries, which may have been affected by externals
  90 if ( DEFINED WRF_DIR )
  91   find_package( WRF COMPONENTS WRF_Core io_netcdf io_grib1 io_int HINTS ${WRF_DIR}/lib )
  92 endif()
  93
  94 # Find externals now -- this is a little different than normal since we want WRF to
  95 # take precedence if it is present on which libraries to use to avoid library splicing
  96 # rather than finding our external thirdparty libraries first
  97 find_package( ZLIB   REQUIRED )
  98 find_package( PNG    REQUIRED )
  99 find_package( Jasper REQUIRED )
 100
 101 # Add config definitions
 102 message( STATUS "Adding configuration specific definitions : ${WPS_DEFINITIONS}" )
 103 # In CMake 2.26 this will not be necessary
 104 string( REPLACE " " ";" WPS_DEFINITIONS_LIST ${WPS_DEFINITIONS} )
 105 list( TRANSFORM WPS_DEFINITIONS_LIST REPLACE "^-D(.*)" "\\1" )
 106 add_compile_definitions(
 107                         ${WPS_DEFINITIONS_LIST}
 108                         $<$<COMPILE_LANGUAGE:Fortran>:USE_JPEG2000>
 109                         $<$<COMPILE_LANGUAGE:Fortran>:USE_PNG>
 110                         )
 111 # Whole project flags
 112 add_compile_options(
 113                     $<$<COMPILE_LANG_AND_ID:Fortran,GNU>:-fallow-argument-mismatch>
 114                     )
 115
 116
 117 # Always build whatever we can
 118 add_subdirectory( ungrib )
 119
 120 if ( DEFINED WRF_DIR )
 121   # WRF Specific things
 122   add_subdirectory( metgrid )
 123   add_subdirectory( geogrid )
 124 endif()
 125
 126 add_subdirectory( util )
 127
 128
 129 ################################################################################
 130 ##
 131 ## Install and export
 132 ##
 133 ################################################################################
 134
 135 # Install to namespace
 136 install(
 137         EXPORT      ${EXPORT_NAME}Targets
 138         DESTINATION lib/cmake/
 139         FILE        ${EXPORT_NAME}Targets.cmake
 140         NAMESPACE   ${EXPORT_NAME}::
 141         )
 142
 143 configure_package_config_file(
 144                               ${PROJECT_SOURCE_DIR}/cmake/template/${EXPORT_NAME}Config.cmake.in
 145                               ${CMAKE_BINARY_DIR}/${EXPORT_NAME}Config.cmake
 146                               INSTALL_DESTINATION lib/cmake
 147                               )
 148
 149 write_basic_package_version_file(
 150                                   ${CMAKE_BINARY_DIR}/${EXPORT_NAME}ConfigVersion.cmake
 151                                   VERSION ${PROJECT_VERSION}
 152                                   #!TODO Check if this is the type of versioning support we want to use
 153                                   COMPATIBILITY SameMinorVersion
 154                                   )
 155
 156 install(
 157         FILES
 158           ${CMAKE_BINARY_DIR}/${EXPORT_NAME}Config.cmake
 159           ${CMAKE_BINARY_DIR}/${EXPORT_NAME}ConfigVersion.cmake
 160         DESTINATION lib/cmake
 161         )
 162
 163 # Install some helper files for anyone using this build as part of their code
 164 install(
 165         DIRECTORY
 166           # Trailing / is important
 167           ${PROJECT_SOURCE_DIR}/cmake/modules/
 168         COMPONENT       helpers
 169         DESTINATION     share
 170         FILES_MATCHING
 171           PATTERN       "*.cmake"
 172         )
 173 # install(
 174 #         FILES
 175 #           ${PROJECT_SOURCE_DIR}/cmake/confcheck.cmake
 176 #           ${PROJECT_SOURCE_DIR}/cmake/gitinfo.cmake
 177 #           ${PROJECT_SOURCE_DIR}/cmake/printOption.cmake
 178 #           ${PROJECT_SOURCE_DIR}/cmake/wrf_get_version.cmake
 179 #         COMPONENT     helpers
 180 #         DESTINATION   share
 181 #         )