phys/module_sf_sfclay.F

   1 !WRF:MODEL_LAYER:PHYSICS
   2 !
   3 MODULE module_sf_sfclay
   4
   5  REAL    , PARAMETER ::  VCONVC=1.
   6  REAL    , PARAMETER ::  CZO=0.0185
   7  REAL    , PARAMETER ::  OZO=1.59E-5
   8
   9  REAL,   DIMENSION(0:1000 ),SAVE          :: PSIMTB,PSIHTB
  10
  11 CONTAINS
  12
  13 !-------------------------------------------------------------------
  14    SUBROUTINE SFCLAY(U3D,V3D,T3D,QV3D,P3D,dz8w,                    &
  15                      CP,G,ROVCP,R,XLV,PSFC,CHS,CHS2,CQS2,CPM,      &
  16                      ZNT,UST,PBLH,MAVAIL,ZOL,MOL,REGIME,PSIM,PSIH, &
  17                      FM,FH,                                        &
  18                      XLAND,HFX,QFX,LH,TSK,FLHC,FLQC,QGH,QSFC,RMOL, &
  19                      U10,V10,TH2,T2,Q2,                            &
  20                      GZ1OZ0,WSPD,BR,ISFFLX,DX,                     &
  21                      SVP1,SVP2,SVP3,SVPT0,EP1,EP2,                 &
  22                      KARMAN,EOMEG,STBOLT,                          &
  23                      P1000mb,                                      &
  24                      ids,ide, jds,jde, kds,kde,                    &
  25                      ims,ime, jms,jme, kms,kme,                    &
  26                      its,ite, jts,jte, kts,kte,                    &
  27                      ustm,ck,cka,cd,cda,                           &
  28                      isftcflx,iz0tlnd,scm_force_flux)
  29 !-------------------------------------------------------------------
  30       IMPLICIT NONE
  31 !-------------------------------------------------------------------
  32 !   Changes in V3.7 over water surfaces:
  33 !          1. for ZNT/Cd, replacing constant OZO with 0.11*1.5E-5/UST(I)
  34 !             the COARE 3.5 (Edson et al. 2013) formulation is also available
  35 !          2. for VCONV, reducing magnitude by half
  36 !          3. for Ck, replacing Carlson-Boland with COARE 3
  37 !-------------------------------------------------------------------
  38 !-- U3D         3D u-velocity interpolated to theta points (m/s)
  39 !-- V3D         3D v-velocity interpolated to theta points (m/s)
  40 !-- T3D         temperature (K)
  41 !-- QV3D        3D water vapor mixing ratio (Kg/Kg)
  42 !-- P3D         3D pressure (Pa)
  43 !-- dz8w        dz between full levels (m)
  44 !-- CP          heat capacity at constant pressure for dry air (J/kg/K)
  45 !-- G           acceleration due to gravity (m/s^2)
  46 !-- ROVCP       R/CP
  47 !-- R           gas constant for dry air (J/kg/K)
  48 !-- XLV         latent heat of vaporization for water (J/kg)
  49 !-- PSFC        surface pressure (Pa)
  50 !-- ZNT         roughness length (m)
  51 !-- UST         u* in similarity theory (m/s)
  52 !-- USTM        u* in similarity theory (m/s) without vconv correction
  53 !               used to couple with TKE scheme
  54 !-- PBLH        PBL height from previous time (m)
  55 !-- MAVAIL      surface moisture availability (between 0 and 1)
  56 !-- ZOL         z/L height over Monin-Obukhov length
  57 !-- MOL         T* (similarity theory) (K)
  58 !-- REGIME      flag indicating PBL regime (stable, unstable, etc.)
  59 !-- PSIM        similarity stability function for momentum
  60 !-- PSIH        similarity stability function for heat
  61 !-- FM          integrated stability function for momentum
  62 !-- FH          integrated stability function for heat
  63 !-- XLAND       land mask (1 for land, 2 for water)
  64 !-- HFX         upward heat flux at the surface (W/m^2)
  65 !-- QFX         upward moisture flux at the surface (kg/m^2/s)
  66 !-- LH          net upward latent heat flux at surface (W/m^2)
  67 !-- TSK         surface temperature (K)
  68 !-- FLHC        exchange coefficient for heat (W/m^2/K)
  69 !-- FLQC        exchange coefficient for moisture (kg/m^2/s)
  70 !-- CHS         heat/moisture exchange coefficient for LSM (m/s)
  71 !-- QGH         lowest-level saturated mixing ratio
  72 !-- QSFC        ground saturated mixing ratio
  73 !-- U10         diagnostic 10m u wind
  74 !-- V10         diagnostic 10m v wind
  75 !-- TH2         diagnostic 2m theta (K)
  76 !-- T2          diagnostic 2m temperature (K)
  77 !-- Q2          diagnostic 2m mixing ratio (kg/kg)
  78 !-- GZ1OZ0      log(z/z0) where z0 is roughness length
  79 !-- WSPD        wind speed at lowest model level (m/s)
  80 !-- BR          bulk Richardson number in surface layer
  81 !-- ISFFLX      isfflx=1 for surface heat and moisture fluxes
  82 !-- DX          horizontal grid size (m)
  83 !-- SVP1        constant for saturation vapor pressure (kPa)
  84 !-- SVP2        constant for saturation vapor pressure (dimensionless)
  85 !-- SVP3        constant for saturation vapor pressure (K)
  86 !-- SVPT0       constant for saturation vapor pressure (K)
  87 !-- EP1         constant for virtual temperature (R_v/R_d - 1) (dimensionless)
  88 !-- EP2         constant for specific humidity calculation
  89 !               (R_d/R_v) (dimensionless)
  90 !-- KARMAN      Von Karman constant
  91 !-- EOMEG       angular velocity of earth's rotation (rad/s)
  92 !-- STBOLT      Stefan-Boltzmann constant (W/m^2/K^4)
  93 !-- ck          enthalpy exchange coeff at 10 meters
  94 !-- cd          momentum exchange coeff at 10 meters
  95 !-- cka         enthalpy exchange coeff at the lowest model level
  96 !-- cda         momentum exchange coeff at the lowest model level
  97 !-- isftcflx    =0, (Charnock and Carlson-Boland); =1, AHW Ck, Cd, =2 Garratt
  98 !-- iz0tlnd     =0 Carlson-Boland, =1 Czil_new
  99 !-- ids         start index for i in domain
 100 !-- ide         end index for i in domain
 101 !-- jds         start index for j in domain
 102 !-- jde         end index for j in domain
 103 !-- kds         start index for k in domain
 104 !-- kde         end index for k in domain
 105 !-- ims         start index for i in memory
 106 !-- ime         end index for i in memory
 107 !-- jms         start index for j in memory
 108 !-- jme         end index for j in memory
 109 !-- kms         start index for k in memory
 110 !-- kme         end index for k in memory
 111 !-- its         start index for i in tile
 112 !-- ite         end index for i in tile
 113 !-- jts         start index for j in tile
 114 !-- jte         end index for j in tile
 115 !-- kts         start index for k in tile
 116 !-- kte         end index for k in tile
 117 !-------------------------------------------------------------------
 118       INTEGER,  INTENT(IN )   ::        ids,ide, jds,jde, kds,kde, &
 119                                         ims,ime, jms,jme, kms,kme, &
 120                                         its,ite, jts,jte, kts,kte
 121 !
 122       INTEGER,  INTENT(IN )   ::        ISFFLX
 123       REAL,     INTENT(IN )   ::        SVP1,SVP2,SVP3,SVPT0
 124       REAL,     INTENT(IN )   ::        EP1,EP2,KARMAN,EOMEG,STBOLT
 125       REAL,     INTENT(IN )   ::        P1000mb
 126 !
 127       REAL,     DIMENSION( ims:ime, kms:kme, jms:jme )           , &
 128                 INTENT(IN   )   ::                           dz8w
 129
 130       REAL,     DIMENSION( ims:ime, kms:kme, jms:jme )           , &
 131                 INTENT(IN   )   ::                           QV3D, &
 132                                                               P3D, &
 133                                                               T3D
 134
 135       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 136                 INTENT(IN   )               ::             MAVAIL, &
 137                                                              PBLH, &
 138                                                             XLAND, &
 139                                                               TSK
 140
 141 !
 142       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 143                 INTENT(INOUT)               ::             REGIME, &
 144                                                               HFX, &
 145                                                               QFX, &
 146                                                                LH, &
 147                                                           MOL,RMOL
 148 !m the following 5 are change to memory size
 149 !
 150       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 151                 INTENT(INOUT)   ::                 GZ1OZ0,WSPD,BR, &
 152                                                   PSIM,PSIH,FM,FH
 153
 154       REAL,     DIMENSION( ims:ime, kms:kme, jms:jme )           , &
 155                 INTENT(IN   )   ::                            U3D, &
 156                                                               V3D
 157
 158       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 159                 INTENT(IN   )               ::               PSFC
 160
 161       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 162                 INTENT(INOUT)   ::                            ZNT, &
 163                                                               ZOL, &
 164                                                               UST, &
 165                                                               CPM, &
 166                                                              CHS2, &
 167                                                              CQS2, &
 168                                                               CHS
 169
 170       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 171                 INTENT(INOUT)   ::                      FLHC,FLQC
 172
 173       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 174                 INTENT(INOUT)   ::                                 &
 175                                                               QGH
 176       REAL,     INTENT(IN   )               ::   CP,G,ROVCP,R,XLV
 177
 178       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 179                 INTENT(IN   )               ::                 DX
 180
 181       REAL, OPTIONAL, DIMENSION( ims:ime, jms:jme )              , &
 182                 INTENT(OUT)     ::                  ck,cka,cd,cda
 183
 184       REAL, OPTIONAL, DIMENSION( ims:ime, jms:jme )              , &
 185                 INTENT(INOUT)   ::                           USTM
 186
 187       INTEGER,  OPTIONAL,  INTENT(IN )   ::     ISFTCFLX, IZ0TLND
 188       INTEGER,  OPTIONAL,  INTENT(IN )   ::     SCM_FORCE_FLUX
 189
 190       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 191                 INTENT(INOUT  )             ::               QSFC
 192
 193       REAL,     DIMENSION( ims:ime, jms:jme )                    , &
 194                 INTENT(OUT  )               ::                U10, &
 195                                                               V10, &
 196                                                               TH2, &
 197                                                                T2, &
 198                                                                Q2
 199
 200 ! LOCAL VARS
 201
 202       REAL,     DIMENSION( its:ite ) ::                       U1D, &
 203                                                               V1D, &
 204                                                              QV1D, &
 205                                                               P1D, &
 206                                                               T1D
 207
 208       REAL,     DIMENSION( its:ite ) ::                    dz8w1d
 209
 210       REAL,     DIMENSION( its:ite ) ::                      DX2D
 211
 212       INTEGER ::  I,J
 213
 214       DO J=jts,jte
 215
 216         DO i=its,ite
 217            DX2D(i)=DX(i,j)
 218         ENDDO
 219
 220         DO i=its,ite
 221           dz8w1d(I) = dz8w(i,1,j)
 222         ENDDO
 223
 224         DO i=its,ite
 225            U1D(i) =U3D(i,1,j)
 226            V1D(i) =V3D(i,1,j)
 227            QV1D(i)=QV3D(i,1,j)
 228            P1D(i) =P3D(i,1,j)
 229            T1D(i) =T3D(i,1,j)
 230         ENDDO
 231
 232         !  Sending array starting locations of optional variables may cause
 233         !  troubles, so we explicitly change the call.
 234
 235         CALL SFCLAY1D(J,U1D,V1D,T1D,QV1D,P1D,dz8w1d,               &
 236                 CP,G,ROVCP,R,XLV,PSFC(ims,j),CHS(ims,j),CHS2(ims,j),&
 237                 CQS2(ims,j),CPM(ims,j),PBLH(ims,j), RMOL(ims,j),   &
 238                 ZNT(ims,j),UST(ims,j),MAVAIL(ims,j),ZOL(ims,j),    &
 239                 MOL(ims,j),REGIME(ims,j),PSIM(ims,j),PSIH(ims,j),  &
 240                 FM(ims,j),FH(ims,j),                               &
 241                 XLAND(ims,j),HFX(ims,j),QFX(ims,j),TSK(ims,j),     &
 242                 U10(ims,j),V10(ims,j),TH2(ims,j),T2(ims,j),        &
 243                 Q2(ims,j),FLHC(ims,j),FLQC(ims,j),QGH(ims,j),      &
 244                 QSFC(ims,j),LH(ims,j),                             &
 245                 GZ1OZ0(ims,j),WSPD(ims,j),BR(ims,j),ISFFLX,DX2D,   &
 246                 SVP1,SVP2,SVP3,SVPT0,EP1,EP2,KARMAN,EOMEG,STBOLT,  &
 247                 P1000mb,                                           &
 248                 ids,ide, jds,jde, kds,kde,                         &
 249                 ims,ime, jms,jme, kms,kme,                         &
 250                 its,ite, jts,jte, kts,kte                          &
 251 #if ( ( EM_CORE == 1 ) || ( defined(mpas) ) )
 252                 ,isftcflx,iz0tlnd,scm_force_flux,                  &
 253                 USTM(ims,j),CK(ims,j),CKA(ims,j),                  &
 254                 CD(ims,j),CDA(ims,j)                               &
 255 #endif
 256                                                                    )
 257       ENDDO
 258
 259
 260    END SUBROUTINE SFCLAY
 261
 262
 263 !-------------------------------------------------------------------
 264    SUBROUTINE SFCLAY1D(J,UX,VX,T1D,QV1D,P1D,dz8w1d,                &
 265                      CP,G,ROVCP,R,XLV,PSFCPA,CHS,CHS2,CQS2,CPM,PBLH,RMOL, &
 266                      ZNT,UST,MAVAIL,ZOL,MOL,REGIME,PSIM,PSIH,FM,FH,&
 267                      XLAND,HFX,QFX,TSK,                            &
 268                      U10,V10,TH2,T2,Q2,FLHC,FLQC,QGH,              &
 269                      QSFC,LH,GZ1OZ0,WSPD,BR,ISFFLX,DX,             &
 270                      SVP1,SVP2,SVP3,SVPT0,EP1,EP2,                 &
 271                      KARMAN,EOMEG,STBOLT,                          &
 272                      P1000mb,                                      &
 273                      ids,ide, jds,jde, kds,kde,                    &
 274                      ims,ime, jms,jme, kms,kme,                    &
 275                      its,ite, jts,jte, kts,kte,                    &
 276                      isftcflx, iz0tlnd, scm_force_flux,            &
 277                      ustm,ck,cka,cd,cda                            )
 278 !-------------------------------------------------------------------
 279       IMPLICIT NONE
 280 !-------------------------------------------------------------------
 281       REAL,     PARAMETER     ::        XKA=2.4E-5
 282       REAL,     PARAMETER     ::        PRT=1.
 283
 284       INTEGER,  INTENT(IN )   ::        ids,ide, jds,jde, kds,kde, &
 285                                         ims,ime, jms,jme, kms,kme, &
 286                                         its,ite, jts,jte, kts,kte, &
 287                                         J
 288 !
 289       INTEGER,  INTENT(IN )   ::        ISFFLX
 290       REAL,     INTENT(IN )   ::        SVP1,SVP2,SVP3,SVPT0
 291       REAL,     INTENT(IN )   ::        EP1,EP2,KARMAN,EOMEG,STBOLT
 292       REAL,     INTENT(IN )   ::        P1000mb
 293
 294 !
 295       REAL,     DIMENSION( ims:ime )                             , &
 296                 INTENT(IN   )               ::             MAVAIL, &
 297                                                              PBLH, &
 298                                                             XLAND, &
 299                                                               TSK
 300 !
 301       REAL,     DIMENSION( ims:ime )                             , &
 302                 INTENT(IN   )               ::             PSFCPA
 303
 304       REAL,     DIMENSION( ims:ime )                             , &
 305                 INTENT(INOUT)               ::             REGIME, &
 306                                                               HFX, &
 307                                                               QFX, &
 308                                                          MOL,RMOL
 309 !m the following 5 are changed to memory size---
 310 !
 311       REAL,     DIMENSION( ims:ime )                             , &
 312                 INTENT(INOUT)   ::                 GZ1OZ0,WSPD,BR, &
 313                                                   PSIM,PSIH,FM,FH
 314
 315       REAL,     DIMENSION( ims:ime )                             , &
 316                 INTENT(INOUT)   ::                            ZNT, &
 317                                                               ZOL, &
 318                                                               UST, &
 319                                                               CPM, &
 320                                                              CHS2, &
 321                                                              CQS2, &
 322                                                               CHS
 323
 324       REAL,     DIMENSION( ims:ime )                             , &
 325                 INTENT(INOUT)   ::                      FLHC,FLQC
 326
 327       REAL,     DIMENSION( ims:ime )                             , &
 328                 INTENT(INOUT)   ::                                 &
 329                                                               QGH
 330
 331       REAL,     DIMENSION( ims:ime )                             , &
 332                 INTENT(OUT)     ::                        U10,V10, &
 333                                                 TH2,T2,Q2,QSFC,LH
 334
 335
 336       REAL,     INTENT(IN   )               ::   CP,G,ROVCP,R,XLV
 337
 338       REAL,     DIMENSION( its:ite ),  INTENT(IN   )   ::      DX
 339
 340 ! MODULE-LOCAL VARIABLES, DEFINED IN SUBROUTINE SFCLAY
 341       REAL,     DIMENSION( its:ite ),  INTENT(IN   )   ::  dz8w1d
 342
 343       REAL,     DIMENSION( its:ite ),  INTENT(IN   )   ::      UX, &
 344                                                                VX, &
 345                                                              QV1D, &
 346                                                               P1D, &
 347                                                               T1D
 348
 349       REAL, OPTIONAL, DIMENSION( ims:ime )                       , &
 350                 INTENT(OUT)     ::                  ck,cka,cd,cda
 351       REAL, OPTIONAL, DIMENSION( ims:ime )                       , &
 352                 INTENT(INOUT)   ::                           USTM
 353
 354       INTEGER,  OPTIONAL,  INTENT(IN )   ::     ISFTCFLX, IZ0TLND
 355       INTEGER,  OPTIONAL,  INTENT(IN )   ::     SCM_FORCE_FLUX
 356
 357 ! LOCAL VARS
 358
 359       REAL,     DIMENSION( its:ite )        ::                 ZA, &
 360                                                         THVX,ZQKL, &
 361                                                            ZQKLP1, &
 362                                                            THX,QX, &
 363                                                             PSIH2, &
 364                                                             PSIM2, &
 365                                                            PSIH10, &
 366                                                            PSIM10, &
 367                                                            DENOMQ, &
 368                                                           DENOMQ2, &
 369                                                           DENOMT2, &
 370                                                             WSPDI, &
 371                                                            GZ2OZ0, &
 372                                                            GZ10OZ0
 373 !
 374       REAL,     DIMENSION( its:ite )        ::                     &
 375                                                       RHOX,GOVRTH, &
 376                                                             TGDSA
 377 !
 378       REAL,     DIMENSION( its:ite)         ::          SCR3,SCR4
 379       REAL,     DIMENSION( its:ite )        ::         THGB, PSFC
 380 !
 381       INTEGER                               ::                 KL
 382
 383       INTEGER ::  N,I,K,KK,L,NZOL,NK,NZOL2,NZOL10
 384
 385       REAL    ::  PL,THCON,TVCON,E1
 386       REAL    ::  ZL,TSKV,DTHVDZ,DTHVM,VCONV,RZOL,RZOL2,RZOL10,ZOL2,ZOL10
 387       REAL    ::  DTG,PSIX,DTTHX,PSIX10,PSIT,PSIT2,PSIQ,PSIQ2,PSIQ10
 388       REAL    ::  FLUXC,VSGD,Z0Q,VISC,RESTAR,CZIL,GZ0OZQ,GZ0OZT
 389       REAL    ::  ZW, ZN1, ZN2
 390       REAL    ::  Z0T, CZC
 391 !-------------------------------------------------------------------
 392       KL=kte
 393
 394       DO i=its,ite
 395 ! PSFC cb
 396          PSFC(I)=PSFCPA(I)/1000.
 397       ENDDO
 398 !
 399 !----CONVERT GROUND TEMPERATURE TO POTENTIAL TEMPERATURE:
 400 !
 401       DO 5 I=its,ite
 402         TGDSA(I)=TSK(I)
 403 ! PSFC cb
 404 !        THGB(I)=TSK(I)*(100./PSFC(I))**ROVCP
 405         THGB(I)=TSK(I)*(P1000mb/PSFCPA(I))**ROVCP
 406     5 CONTINUE
 407 !
 408 !-----DECOUPLE FLUX-FORM VARIABLES TO GIVE U,V,T,THETA,THETA-VIR.,
 409 !     T-VIR., QV, AND QC AT CROSS POINTS AND AT KTAU-1.
 410 !
 411 !     *** NOTE ***
 412 !         THE BOUNDARY WINDS MAY NOT BE ADEQUATELY AFFECTED BY FRICTION,
 413 !         SO USE ONLY INTERIOR VALUES OF UX AND VX TO CALCULATE
 414 !         TENDENCIES.
 415 !
 416    10 CONTINUE
 417
 418 !     DO 24 I=its,ite
 419 !        UX(I)=U1D(I)
 420 !        VX(I)=V1D(I)
 421 !  24 CONTINUE
 422
 423    26 CONTINUE
 424
 425 !.....SCR3(I,K) STORE TEMPERATURE,
 426 !     SCR4(I,K) STORE VIRTUAL TEMPERATURE.
 427
 428       DO 30 I=its,ite
 429 ! PL cb
 430          PL=P1D(I)/1000.
 431          SCR3(I)=T1D(I)
 432 !         THCON=(100./PL)**ROVCP
 433          THCON=(P1000mb*0.001/PL)**ROVCP
 434          THX(I)=SCR3(I)*THCON
 435          SCR4(I)=SCR3(I)
 436          THVX(I)=THX(I)
 437          QX(I)=0.
 438    30 CONTINUE
 439 !
 440       DO I=its,ite
 441          QGH(I)=0.
 442          FLHC(I)=0.
 443          FLQC(I)=0.
 444          CPM(I)=CP
 445       ENDDO
 446 !
 447 !     IF(IDRY.EQ.1)GOTO 80
 448       DO 50 I=its,ite
 449          QX(I)=QV1D(I)
 450          TVCON=(1.+EP1*QX(I))
 451          THVX(I)=THX(I)*TVCON
 452          SCR4(I)=SCR3(I)*TVCON
 453    50 CONTINUE
 454 !
 455       DO 60 I=its,ite
 456         E1=SVP1*EXP(SVP2*(TGDSA(I)-SVPT0)/(TGDSA(I)-SVP3))
 457 !  for land points QSFC can come from previous time step
 458         if(xland(i).gt.1.5.or.qsfc(i).le.0.0)QSFC(I)=EP2*E1/(PSFC(I)-E1)
 459 ! QGH CHANGED TO USE LOWEST-LEVEL AIR TEMP CONSISTENT WITH MYJSFC CHANGE
 460 ! Q2SAT = QGH IN LSM
 461         E1=SVP1*EXP(SVP2*(T1D(I)-SVPT0)/(T1D(I)-SVP3))
 462         PL=P1D(I)/1000.
 463         QGH(I)=EP2*E1/(PL-E1)
 464         CPM(I)=CP*(1.+0.8*QX(I))
 465    60 CONTINUE
 466    80 CONTINUE
 467
 468 !-----COMPUTE THE HEIGHT OF FULL- AND HALF-SIGMA LEVELS ABOVE GROUND
 469 !     LEVEL, AND THE LAYER THICKNESSES.
 470
 471       DO 90 I=its,ite
 472         ZQKLP1(I)=0.
 473         RHOX(I)=PSFC(I)*1000./(R*SCR4(I))
 474    90 CONTINUE
 475 !
 476       DO 110 I=its,ite
 477            ZQKL(I)=dz8w1d(I)+ZQKLP1(I)
 478   110 CONTINUE
 479 !
 480       DO 120 I=its,ite
 481          ZA(I)=0.5*(ZQKL(I)+ZQKLP1(I))
 482   120 CONTINUE
 483 !
 484       DO 160 I=its,ite
 485         GOVRTH(I)=G/THX(I)
 486   160 CONTINUE
 487
 488 !-----CALCULATE BULK RICHARDSON NO. OF SURFACE LAYER, ACCORDING TO
 489 !     AKB(1976), EQ(12).
 490
 491       DO 260 I=its,ite
 492         GZ1OZ0(I)=ALOG(ZA(I)/ZNT(I))
 493         GZ2OZ0(I)=ALOG(2./ZNT(I))
 494         GZ10OZ0(I)=ALOG(10./ZNT(I))
 495         IF((XLAND(I)-1.5).GE.0)THEN
 496           ZL=ZNT(I)
 497         ELSE
 498           ZL=0.01
 499         ENDIF
 500         WSPD(I)=SQRT(UX(I)*UX(I)+VX(I)*VX(I))
 501
 502         TSKV=THGB(I)*(1.+EP1*QSFC(I))
 503         DTHVDZ=(THVX(I)-TSKV)
 504 !  Convective velocity scale Vc and subgrid-scale velocity Vsg
 505 !  following Beljaars (1994, QJRMS) and Mahrt and Sun (1995, MWR)
 506 !                                ... HONG Aug. 2001
 507 !
 508 !       VCONV = 0.25*sqrt(g/tskv*pblh(i)*dthvm)
 509 !      Use Beljaars over land, old MM5 (Wyngaard) formula over water
 510         if (xland(i).lt.1.5) then
 511         fluxc = max(hfx(i)/rhox(i)/cp                    &
 512               + ep1*tskv*qfx(i)/rhox(i),0.)
 513         VCONV = vconvc*(g/tgdsa(i)*pblh(i)*fluxc)**.33
 514         else
 515         IF(-DTHVDZ.GE.0)THEN
 516           DTHVM=-DTHVDZ
 517         ELSE
 518           DTHVM=0.
 519         ENDIF
 520 !       VCONV = 2.*SQRT(DTHVM)
 521 ! V3.7: reducing contribution in calm conditions
 522         VCONV = SQRT(DTHVM)
 523         endif
 524 ! Mahrt and Sun low-res correction
 525         VSGD = 0.32 * (max(dx(i)/5000.-1.,0.))**.33
 526         WSPD(I)=SQRT(WSPD(I)*WSPD(I)+VCONV*VCONV+vsgd*vsgd)
 527         WSPD(I)=AMAX1(WSPD(I),0.1)
 528         BR(I)=GOVRTH(I)*ZA(I)*DTHVDZ/(WSPD(I)*WSPD(I))
 529 !  IF PREVIOUSLY UNSTABLE, DO NOT LET INTO REGIMES 1 AND 2
 530         IF(MOL(I).LT.0.)BR(I)=AMIN1(BR(I),0.0)
 531 !jdf
 532         RMOL(I)=-GOVRTH(I)*DTHVDZ*ZA(I)*KARMAN
 533 !jdf
 534
 535   260 CONTINUE
 536
 537 !
 538 !-----DIAGNOSE BASIC PARAMETERS FOR THE APPROPRIATED STABILITY CLASS:
 539 !
 540 !
 541 !     THE STABILITY CLASSES ARE DETERMINED BY BR (BULK RICHARDSON NO.)
 542 !     AND HOL (HEIGHT OF PBL/MONIN-OBUKHOV LENGTH).
 543 !
 544 !     CRITERIA FOR THE CLASSES ARE AS FOLLOWS:
 545 !
 546 !        1. BR .GE. 0.2;
 547 !               REPRESENTS NIGHTTIME STABLE CONDITIONS (REGIME=1),
 548 !
 549 !        2. BR .LT. 0.2 .AND. BR .GT. 0.0;
 550 !               REPRESENTS DAMPED MECHANICAL TURBULENT CONDITIONS
 551 !               (REGIME=2),
 552 !
 553 !        3. BR .EQ. 0.0
 554 !               REPRESENTS FORCED CONVECTION CONDITIONS (REGIME=3),
 555 !
 556 !        4. BR .LT. 0.0
 557 !               REPRESENTS FREE CONVECTION CONDITIONS (REGIME=4).
 558 !
 559 !CCCCC
 560
 561       DO 320 I=its,ite
 562 !CCCCC
 563 !CC     REMOVE REGIME 3 DEPENDENCE ON PBL HEIGHT
 564 !CC          IF(BR(I).LT.0..AND.HOL(I,J).GT.1.5)GOTO 310
 565         IF(BR(I).LT.0.)GOTO 310
 566 !
 567 !-----CLASS 1; STABLE (NIGHTTIME) CONDITIONS:
 568 !
 569         IF(BR(I).LT.0.2)GOTO 270
 570         REGIME(I)=1.
 571         PSIM(I)=-10.*GZ1OZ0(I)
 572 !    LOWER LIMIT ON PSI IN STABLE CONDITIONS
 573         PSIM(I)=AMAX1(PSIM(I),-10.)
 574         PSIH(I)=PSIM(I)
 575         PSIM10(I)=10./ZA(I)*PSIM(I)
 576         PSIM10(I)=AMAX1(PSIM10(I),-10.)
 577         PSIH10(I)=PSIM10(I)
 578         PSIM2(I)=2./ZA(I)*PSIM(I)
 579         PSIM2(I)=AMAX1(PSIM2(I),-10.)
 580         PSIH2(I)=PSIM2(I)
 581
 582 !       1.0 over Monin-Obukhov length
 583         IF(UST(I).LT.0.01)THEN
 584            RMOL(I)=BR(I)*GZ1OZ0(I) !ZA/L
 585         ELSE
 586            RMOL(I)=KARMAN*GOVRTH(I)*ZA(I)*MOL(I)/(UST(I)*UST(I)) !ZA/L
 587         ENDIF
 588         RMOL(I)=AMIN1(RMOL(I),9.999) ! ZA/L
 589         RMOL(I) = RMOL(I)/ZA(I) !1.0/L
 590
 591         GOTO 320
 592 !
 593 !-----CLASS 2; DAMPED MECHANICAL TURBULENCE:
 594 !
 595   270   IF(BR(I).EQ.0.0)GOTO 280
 596         REGIME(I)=2.
 597         PSIM(I)=-5.0*BR(I)*GZ1OZ0(I)/(1.1-5.0*BR(I))
 598 !    LOWER LIMIT ON PSI IN STABLE CONDITIONS
 599         PSIM(I)=AMAX1(PSIM(I),-10.)
 600 !.....AKB(1976), EQ(16).
 601         PSIH(I)=PSIM(I)
 602         PSIM10(I)=10./ZA(I)*PSIM(I)
 603         PSIM10(I)=AMAX1(PSIM10(I),-10.)
 604         PSIH10(I)=PSIM10(I)
 605         PSIM2(I)=2./ZA(I)*PSIM(I)
 606         PSIM2(I)=AMAX1(PSIM2(I),-10.)
 607         PSIH2(I)=PSIM2(I)
 608
 609         ! Linear form: PSIM = -0.5*ZA/L; e.g, see eqn 16 of
 610         ! Blackadar, Modeling the nocturnal boundary layer, Preprints,
 611         ! Third Symposium on Atmospheric Turbulence Diffusion and Air Quality,
 612         ! Raleigh, NC, 1976
 613         ZOL(I) = BR(I)*GZ1OZ0(I)/(1.00001-5.0*BR(I))
 614
 615         if ( ZOL(I) .GT. 0.5 ) then ! linear form ok
 616            ! Holtslag and de Bruin, J. App. Meteor 27, 689-704, 1988;
 617            ! see also, Launiainen, Boundary-Layer Meteor 76,165-179, 1995
 618            ! Eqn (8) of Launiainen, 1995
 619            ZOL(I) = ( 1.89*GZ1OZ0(I) + 44.2 ) * BR(I)*BR(I)    &
 620                 + ( 1.18*GZ1OZ0(I) - 1.37 ) * BR(I)
 621            ZOL(I)=AMIN1(ZOL(I),9.999)
 622         end if
 623
 624         ! 1.0 over Monin-Obukhov length
 625         RMOL(I)= ZOL(I)/ZA(I)
 626
 627         GOTO 320
 628 !
 629 !-----CLASS 3; FORCED CONVECTION:
 630 !
 631   280   REGIME(I)=3.
 632         PSIM(I)=0.0
 633         PSIH(I)=PSIM(I)
 634         PSIM10(I)=0.
 635         PSIH10(I)=PSIM10(I)
 636         PSIM2(I)=0.
 637         PSIH2(I)=PSIM2(I)
 638
 639
 640         IF(UST(I).LT.0.01)THEN
 641           ZOL(I)=BR(I)*GZ1OZ0(I)
 642         ELSE
 643           ZOL(I)=KARMAN*GOVRTH(I)*ZA(I)*MOL(I)/(UST(I)*UST(I))
 644         ENDIF
 645
 646         RMOL(I) = ZOL(I)/ZA(I)
 647
 648         GOTO 320
 649 !
 650 !-----CLASS 4; FREE CONVECTION:
 651 !
 652   310   CONTINUE
 653         REGIME(I)=4.
 654         IF(UST(I).LT.0.01)THEN
 655           ZOL(I)=BR(I)*GZ1OZ0(I)
 656         ELSE
 657           ZOL(I)=KARMAN*GOVRTH(I)*ZA(I)*MOL(I)/(UST(I)*UST(I))
 658         ENDIF
 659         ZOL10=10./ZA(I)*ZOL(I)
 660         ZOL2=2./ZA(I)*ZOL(I)
 661         ZOL(I)=AMIN1(ZOL(I),0.)
 662         ZOL(I)=AMAX1(ZOL(I),-9.9999)
 663         ZOL10=AMIN1(ZOL10,0.)
 664         ZOL10=AMAX1(ZOL10,-9.9999)
 665         ZOL2=AMIN1(ZOL2,0.)
 666         ZOL2=AMAX1(ZOL2,-9.9999)
 667         NZOL=INT(-ZOL(I)*100.)
 668         RZOL=-ZOL(I)*100.-NZOL
 669         NZOL10=INT(-ZOL10*100.)
 670         RZOL10=-ZOL10*100.-NZOL10
 671         NZOL2=INT(-ZOL2*100.)
 672         RZOL2=-ZOL2*100.-NZOL2
 673         PSIM(I)=PSIMTB(NZOL)+RZOL*(PSIMTB(NZOL+1)-PSIMTB(NZOL))
 674         PSIH(I)=PSIHTB(NZOL)+RZOL*(PSIHTB(NZOL+1)-PSIHTB(NZOL))
 675         PSIM10(I)=PSIMTB(NZOL10)+RZOL10*(PSIMTB(NZOL10+1)-PSIMTB(NZOL10))
 676         PSIH10(I)=PSIHTB(NZOL10)+RZOL10*(PSIHTB(NZOL10+1)-PSIHTB(NZOL10))
 677         PSIM2(I)=PSIMTB(NZOL2)+RZOL2*(PSIMTB(NZOL2+1)-PSIMTB(NZOL2))
 678         PSIH2(I)=PSIHTB(NZOL2)+RZOL2*(PSIHTB(NZOL2+1)-PSIHTB(NZOL2))
 679
 680 !---LIMIT PSIH AND PSIM IN THE CASE OF THIN LAYERS AND HIGH ROUGHNESS
 681 !---  THIS PREVENTS DENOMINATOR IN FLUXES FROM GETTING TOO SMALL
 682 !       PSIH(I)=AMIN1(PSIH(I),0.9*GZ1OZ0(I))
 683 !       PSIM(I)=AMIN1(PSIM(I),0.9*GZ1OZ0(I))
 684         PSIH(I)=AMIN1(PSIH(I),0.9*GZ1OZ0(I))
 685         PSIM(I)=AMIN1(PSIM(I),0.9*GZ1OZ0(I))
 686         PSIH2(I)=AMIN1(PSIH2(I),0.9*GZ2OZ0(I))
 687         PSIM10(I)=AMIN1(PSIM10(I),0.9*GZ10OZ0(I))
 688 ! AHW: mods to compute ck, cd
 689         PSIH10(I)=AMIN1(PSIH10(I),0.9*GZ10OZ0(I))
 690
 691         RMOL(I) = ZOL(I)/ZA(I)
 692
 693   320 CONTINUE
 694 !
 695 !-----COMPUTE THE FRICTIONAL VELOCITY:
 696 !     ZA(1982) EQS(2.60),(2.61).
 697 !
 698       DO 330 I=its,ite
 699         DTG=THX(I)-THGB(I)
 700         PSIX=GZ1OZ0(I)-PSIM(I)
 701         PSIX10=GZ10OZ0(I)-PSIM10(I)
 702 !     LOWER LIMIT ADDED TO PREVENT LARGE FLHC IN SOIL MODEL
 703 !     ACTIVATES IN UNSTABLE CONDITIONS WITH THIN LAYERS OR HIGH Z0
 704         PSIT=AMAX1(GZ1OZ0(I)-PSIH(I),2.)
 705
 706         IF((XLAND(I)-1.5).GE.0)THEN
 707           ZL=ZNT(I)
 708         ELSE
 709           ZL=0.01
 710         ENDIF
 711         PSIQ=ALOG(KARMAN*UST(I)*ZA(I)/XKA+ZA(I)/ZL)-PSIH(I)
 712         PSIT2=GZ2OZ0(I)-PSIH2(I)
 713         PSIQ2=ALOG(KARMAN*UST(I)*2./XKA+2./ZL)-PSIH2(I)
 714 ! AHW: mods to compute ck, cd
 715         PSIQ10=ALOG(KARMAN*UST(I)*10./XKA+10./ZL)-PSIH10(I)
 716
 717 ! V3.7: using Fairall 2003 to compute z0q and z0t over water:
 718 !       adapted from module_sf_mynn.F
 719         IF ( (XLAND(I)-1.5).GE.0. ) THEN
 720               VISC=(1.32+0.009*(SCR3(I)-273.15))*1.E-5
 721 !             VISC=1.326e-5*(1. + 6.542e-3*SCR3(I) + 8.301e-6*SCR3(I)*SCR3(I) &
 722 !                 - 4.84e-9*SCR3(I)*SCR3(I)*SCR3(I))
 723               RESTAR=UST(I)*ZNT(I)/VISC
 724               Z0T = (5.5e-5)*(RESTAR**(-0.60))
 725               Z0T = MIN(Z0T,1.0e-4)
 726               Z0T = MAX(Z0T,2.0e-9)
 727               Z0Q = Z0T
 728
 729               PSIQ=max(ALOG((ZA(I)+Z0Q)/Z0Q)-PSIH(I), 2.)
 730               PSIT=max(ALOG((ZA(I)+Z0T)/Z0T)-PSIH(I), 2.)
 731               PSIQ2=max(ALOG((2.+Z0Q)/Z0Q)-PSIH2(I), 2.)
 732               PSIT2=max(ALOG((2.+Z0T)/Z0T)-PSIH2(I), 2.)
 733               PSIQ10=max(ALOG((10.+Z0Q)/Z0Q)-PSIH10(I), 2.)
 734         ENDIF
 735
 736         IF ( PRESENT(ISFTCFLX) ) THEN
 737            IF ( ISFTCFLX.EQ.1 .AND. (XLAND(I)-1.5).GE.0. ) THEN
 738 ! v3.1
 739 !             Z0Q = 1.e-4 + 1.e-3*(MAX(0.,UST(I)-1.))**2
 740 ! hfip1
 741 !             Z0Q = 0.62*2.0E-5/UST(I) + 1.E-3*(MAX(0.,UST(I)-1.5))**2
 742 ! v3.2
 743               Z0Q = 1.e-4
 744               PSIQ=ALOG(ZA(I)/Z0Q)-PSIH(I)
 745               PSIT=PSIQ
 746               PSIQ2=ALOG(2./Z0Q)-PSIH2(I)
 747               PSIQ10=ALOG(10./Z0Q)-PSIH10(I)
 748               PSIT2=PSIQ2
 749            ENDIF
 750            IF ( ISFTCFLX.EQ.2 .AND. (XLAND(I)-1.5).GE.0. ) THEN
 751 ! AHW: Garratt formula: Calculate roughness Reynolds number
 752 !        Kinematic viscosity of air (linear approc to
 753 !                 temp dependence at sea level)
 754 ! GZ0OZT and GZ0OZQ are based off formulas from Brutsaert (1975), which
 755 ! Garratt (1992) used with values of k = 0.40, Pr = 0.71, and Sc = 0.60
 756               VISC=(1.32+0.009*(SCR3(I)-273.15))*1.E-5
 757 !!            VISC=1.5E-5
 758               RESTAR=UST(I)*ZNT(I)/VISC
 759               GZ0OZT=0.40*(7.3*SQRT(SQRT(RESTAR))*SQRT(0.71)-5.)
 760               GZ0OZQ=0.40*(7.3*SQRT(SQRT(RESTAR))*SQRT(0.60)-5.)
 761               PSIT=GZ1OZ0(I)-PSIH(I)+GZ0OZT
 762               PSIQ=GZ1OZ0(I)-PSIH(I)+GZ0OZQ
 763               PSIT2=GZ2OZ0(I)-PSIH2(I)+GZ0OZT
 764               PSIQ2=GZ2OZ0(I)-PSIH2(I)+GZ0OZQ
 765               PSIQ10=GZ10OZ0(I)-PSIH(I)+GZ0OZQ
 766            ENDIF
 767         ENDIF
 768         IF(PRESENT(ck) .and. PRESENT(cd) .and. PRESENT(cka) .and. PRESENT(cda)) THEN
 769            Ck(I)=(karman/psix10)*(karman/psiq10)
 770            Cd(I)=(karman/psix10)*(karman/psix10)
 771            Cka(I)=(karman/psix)*(karman/psiq)
 772            Cda(I)=(karman/psix)*(karman/psix)
 773         ENDIF
 774         IF ( PRESENT(IZ0TLND) ) THEN
 775            IF ( IZ0TLND.GE.1 .AND. (XLAND(I)-1.5).LE.0. ) THEN
 776               ZL=ZNT(I)
 777 !             CZIL RELATED CHANGES FOR LAND
 778               VISC=(1.32+0.009*(SCR3(I)-273.15))*1.E-5
 779               RESTAR=UST(I)*ZL/VISC
 780 !             Modify CZIL according to Chen & Zhang, 2009 if iz0tlnd = 1
 781 !             If iz0tlnd = 2, use traditional value
 782
 783               IF ( IZ0TLND.EQ.1 ) THEN
 784                  CZIL = 10.0 ** ( -0.40 * ( ZL / 0.07 ) )
 785               ELSE IF ( IZ0TLND.EQ.2 ) THEN
 786                  CZIL = 0.1
 787               END IF
 788
 789               PSIT=GZ1OZ0(I)-PSIH(I)+CZIL*KARMAN*SQRT(RESTAR)
 790               PSIQ=GZ1OZ0(I)-PSIH(I)+CZIL*KARMAN*SQRT(RESTAR)
 791               PSIT2=GZ2OZ0(I)-PSIH2(I)+CZIL*KARMAN*SQRT(RESTAR)
 792               PSIQ2=GZ2OZ0(I)-PSIH2(I)+CZIL*KARMAN*SQRT(RESTAR)
 793
 794            ENDIF
 795         ENDIF
 796 ! TO PREVENT OSCILLATIONS AVERAGE WITH OLD VALUE
 797         UST(I)=0.5*UST(I)+0.5*KARMAN*WSPD(I)/PSIX
 798 ! TKE coupling: compute ust without vconv for use in tke scheme
 799         WSPDI(I)=SQRT(UX(I)*UX(I)+VX(I)*VX(I))
 800         IF ( PRESENT(USTM) ) THEN
 801         USTM(I)=0.5*USTM(I)+0.5*KARMAN*WSPDI(I)/PSIX
 802         ENDIF
 803         U10(I)=UX(I)*PSIX10/PSIX
 804         V10(I)=VX(I)*PSIX10/PSIX
 805         TH2(I)=THGB(I)+DTG*PSIT2/PSIT
 806         Q2(I)=QSFC(I)+(QX(I)-QSFC(I))*PSIQ2/PSIQ
 807 !        T2(I) = TH2(I)*(PSFC(I)/100.)**ROVCP
 808         T2(I) = TH2(I)*(PSFCPA(I)/P1000mb)**ROVCP
 809 !       LATER Q2 WILL BE OVERWRITTEN FOR LAND POINTS IN SURFCE
 810 !       QA2(I,J) = Q2(I)
 811 !       UA10(I,J) = U10(I)
 812 !       VA10(I,J) = V10(I)
 813 !       write(*,1002)UST(I),KARMAN*WSPD(I),PSIX,KARMAN*WSPD(I)/PSIX
 814 !
 815         IF((XLAND(I)-1.5).LT.0.)THEN
 816           UST(I)=AMAX1(UST(I),0.1)
 817         ENDIF
 818         MOL(I)=KARMAN*DTG/PSIT/PRT
 819         DENOMQ(I)=PSIQ
 820         DENOMQ2(I)=PSIQ2
 821         DENOMT2(I)=PSIT2
 822         FM(I)=PSIX
 823         FH(I)=PSIT
 824   330 CONTINUE
 825 !
 826   335 CONTINUE
 827
 828 !-----COMPUTE THE SURFACE SENSIBLE AND LATENT HEAT FLUXES:
 829       IF ( PRESENT(SCM_FORCE_FLUX) ) THEN
 830          IF (SCM_FORCE_FLUX.EQ.1) GOTO 350
 831       ENDIF
 832       DO i=its,ite
 833         QFX(i)=0.
 834         HFX(i)=0.
 835       ENDDO
 836   350 CONTINUE
 837
 838       IF (ISFFLX.EQ.0) GOTO 410
 839
 840 !-----OVER WATER, ALTER ROUGHNESS LENGTH (ZNT) ACCORDING TO WIND (UST).
 841
 842       DO 360 I=its,ite
 843         IF((XLAND(I)-1.5).GE.0)THEN
 844 !         ZNT(I)=CZO*UST(I)*UST(I)/G+OZO
 845 ! Since V3.7 (ref: EC Physics document for Cy36r1)
 846           ZNT(I)=CZO*UST(I)*UST(I)/G+0.11*1.5E-5/UST(I)
 847 ! V3.9: Add limit as in isftcflx = 1,2
 848           ZNT(I)=MIN(ZNT(I),2.85e-3)
 849 ! COARE 3.5 (Edson et al. 2013)
 850 !         CZC = 0.0017*WSPD(I)-0.005
 851 !         CZC = min(CZC,0.028)
 852 !         ZNT(I)=CZC*UST(I)*UST(I)/G+0.11*1.5E-5/UST(I)
 853 ! AHW: change roughness length, and hence the drag coefficients Ck and Cd
 854           IF ( PRESENT(ISFTCFLX) ) THEN
 855              IF ( ISFTCFLX.NE.0 ) THEN
 856 !               ZNT(I)=10.*exp(-9.*UST(I)**(-.3333))
 857 !               ZNT(I)=10.*exp(-9.5*UST(I)**(-.3333))
 858 !               ZNT(I)=ZNT(I) + 0.11*1.5E-5/AMAX1(UST(I),0.01)
 859 !               ZNT(I)=0.011*UST(I)*UST(I)/G+OZO
 860 !               ZNT(I)=MAX(ZNT(I),3.50e-5)
 861 ! AHW 2012:
 862                 ZW  = MIN((UST(I)/1.06)**(0.3),1.0)
 863                 ZN1 = 0.011*UST(I)*UST(I)/G + OZO
 864                 ZN2 = 10.*exp(-9.5*UST(I)**(-.3333)) + &
 865                        0.11*1.5E-5/AMAX1(UST(I),0.01)
 866                 ZNT(I)=(1.0-ZW) * ZN1 + ZW * ZN2
 867                 ZNT(I)=MIN(ZNT(I),2.85e-3)
 868                 ZNT(I)=MAX(ZNT(I),1.27e-7)
 869              ENDIF
 870           ENDIF
 871           ZL = ZNT(I)
 872         ELSE
 873           ZL = 0.01
 874         ENDIF
 875         FLQC(I)=RHOX(I)*MAVAIL(I)*UST(I)*KARMAN/DENOMQ(I)
 876 !       FLQC(I)=RHOX(I)*MAVAIL(I)*UST(I)*KARMAN/(   &
 877 !               ALOG(KARMAN*UST(I)*ZA(I)/XKA+ZA(I)/ZL)-PSIH(I))
 878         DTTHX=ABS(THX(I)-THGB(I))
 879         IF(DTTHX.GT.1.E-5)THEN
 880           FLHC(I)=CPM(I)*RHOX(I)*UST(I)*MOL(I)/(THX(I)-THGB(I))
 881 !         write(*,1001)FLHC(I),CPM(I),RHOX(I),UST(I),MOL(I),THX(I),THGB(I),I
 882  1001   format(f8.5,2x,f12.7,2x,f12.10,2x,f12.10,2x,f13.10,2x,f12.8,f12.8,2x,i3)
 883         ELSE
 884           FLHC(I)=0.
 885         ENDIF
 886   360 CONTINUE
 887
 888 !
 889 !-----COMPUTE SURFACE MOIST FLUX:
 890 !
 891 !     IF(IDRY.EQ.1)GOTO 390
 892      IF ( PRESENT(SCM_FORCE_FLUX) ) THEN
 893         IF (SCM_FORCE_FLUX.EQ.1) GOTO 405
 894      ENDIF
 895 !
 896       DO 370 I=its,ite
 897         QFX(I)=FLQC(I)*(QSFC(I)-QX(I))
 898         QFX(I)=AMAX1(QFX(I),0.)
 899         LH(I)=XLV*QFX(I)
 900   370 CONTINUE
 901
 902 !-----COMPUTE SURFACE HEAT FLUX:
 903 !
 904   390 CONTINUE
 905       DO 400 I=its,ite
 906         IF(XLAND(I)-1.5.GT.0.)THEN
 907           HFX(I)=FLHC(I)*(THGB(I)-THX(I))
 908 !         IF ( PRESENT(ISFTCFLX) ) THEN
 909 !            IF ( ISFTCFLX.NE.0 ) THEN
 910 ! AHW: add dissipative heating term (commented out in 3.6.1)
 911 !               HFX(I)=HFX(I)+RHOX(I)*USTM(I)*USTM(I)*WSPDI(I)
 912 !            ENDIF
 913 !         ENDIF
 914         ELSEIF(XLAND(I)-1.5.LT.0.)THEN
 915           HFX(I)=FLHC(I)*(THGB(I)-THX(I))
 916           HFX(I)=AMAX1(HFX(I),-250.)
 917         ENDIF
 918   400 CONTINUE
 919
 920   405 CONTINUE
 921
 922       DO I=its,ite
 923          IF((XLAND(I)-1.5).GE.0)THEN
 924            ZL=ZNT(I)
 925          ELSE
 926            ZL=0.01
 927          ENDIF
 928          CHS(I)=UST(I)*KARMAN/DENOMQ(I)
 929 !        GZ2OZ0(I)=ALOG(2./ZNT(I))
 930 !        PSIM2(I)=-10.*GZ2OZ0(I)
 931 !        PSIM2(I)=AMAX1(PSIM2(I),-10.)
 932 !        PSIH2(I)=PSIM2(I)
 933          CQS2(I)=UST(I)*KARMAN/DENOMQ2(I)
 934          CHS2(I)=UST(I)*KARMAN/DENOMT2(I)
 935       ENDDO
 936
 937   410 CONTINUE
 938 !jdf
 939 !     DO I=its,ite
 940 !       IF(UST(I).GE.0.1) THEN
 941 !         RMOL(I)=RMOL(I)*(-FLHC(I))/(UST(I)*UST(I)*UST(I))
 942 !       ELSE
 943 !         RMOL(I)=RMOL(I)*(-FLHC(I))/(0.1*0.1*0.1)
 944 !       ENDIF
 945 !     ENDDO
 946 !jdf
 947
 948 !
 949    END SUBROUTINE SFCLAY1D
 950
 951 !====================================================================
 952    SUBROUTINE sfclayinit( allowed_to_read )
 953
 954    LOGICAL , INTENT(IN)      ::      allowed_to_read
 955    INTEGER                   ::      N
 956    REAL                      ::      ZOLN,X,Y
 957
 958    DO N=0,1000
 959       ZOLN=-FLOAT(N)*0.01
 960       X=(1-16.*ZOLN)**0.25
 961       PSIMTB(N)=2*ALOG(0.5*(1+X))+ALOG(0.5*(1+X*X))- &
 962                 2.*ATAN(X)+2.*ATAN(1.)
 963       Y=(1-16*ZOLN)**0.5
 964       PSIHTB(N)=2*ALOG(0.5*(1+Y))
 965    ENDDO
 966
 967    END SUBROUTINE sfclayinit
 968
 969 !-------------------------------------------------------------------
 970
 971 END MODULE module_sf_sfclay