external/fftpack/fftpack5/cost1i.F

   1 subroutine cost1i ( n, wsave, lensav, ier )
   2
   3 !*****************************************************************************80
   4 !
   5 !! COST1I: initialization for COST1B and COST1F.
   6 !
   7 !  Discussion:
   8 !
   9 !    COST1I initializes array WSAVE for use in its companion routines
  10 !    COST1F and COST1B.  The prime factorization of N together with a
  11 !    tabulation of the trigonometric functions are computed and stored
  12 !    in array WSAVE.  Separate WSAVE arrays are required for different
  13 !    values of N.
  14 !
  15 !
  16 !    Copyright (C) 1995-2004, Scientific Computing Division,
  17 !    University Corporation for Atmospheric Research
  18 !
  19 !  Modified:
  20 !
  21 !    28 March 2005
  22 !
  23 !  Author:
  24 !
  25 !    Paul Swarztrauber
  26 !    Richard Valent
  27 !
  28 !  Reference:
  29 !
  30 !    Paul Swarztrauber,
  31 !    Vectorizing the Fast Fourier Transforms,
  32 !    in Parallel Computations,
  33 !    edited by G. Rodrigue,
  34 !    Academic Press, 1982.
  35 !
  36 !    Paul Swarztrauber,
  37 !    Fast Fourier Transform Algorithms for Vector Computers,
  38 !    Parallel Computing, pages 45-63, 1984.
  39 !
  40 !  Parameters:
  41 !
  42 !    Input, integer ( kind = 4 ) N, the length of the sequence to be
  43 !    transformed.  The transform is most efficient when N-1 is a product
  44 !    of small primes.
  45 !
  46 !    Input, integer ( kind = 4 ) LENSAV, dimension of WSAVE array.
  47 !    LENSAV must be at least 2*N + INT(LOG(REAL(N))) + 4.
  48 !
  49 !    Output, real ( kind = 4 ) WSAVE(LENSAV), containing the prime factors of
  50 !    N and also containing certain trigonometric values which will be used in
  51 !    routines COST1B or COST1F.
  52 !
  53 !    Output, integer ( kind = 4 ) IER, error flag.
  54 !    0, successful exit;
  55 !    2, input parameter LENSAV not big enough;
  56 !    20, input error returned by lower level routine.
  57 !
  58   implicit none
  59
  60   integer ( kind = 4 ) lensav
  61
  62   real ( kind = 4 ) dt
  63   real ( kind = 4 ) fk
  64   integer ( kind = 4 ) ier
  65   integer ( kind = 4 ) ier1
  66   integer ( kind = 4 ) k
  67   integer ( kind = 4 ) kc
  68   integer ( kind = 4 ) lnsv
  69   integer ( kind = 4 ) n
  70   integer ( kind = 4 ) nm1
  71   integer ( kind = 4 ) np1
  72   integer ( kind = 4 ) ns2
  73   real ( kind = 4 ) pi
  74   real ( kind = 4 ) wsave(lensav)
  75
  76   ier = 0
  77
  78   if ( lensav < 2 * n + int ( log ( real ( n, kind = 4 ) ) ) + 4 ) then
  79     ier = 2
  80     call xerfft ( 'COST1I', 3 )
  81     return
  82   end if
  83
  84   if ( n <= 3 ) then
  85     return
  86   end if
  87
  88   nm1 = n - 1
  89   np1 = n + 1
  90   ns2 = n / 2
  91   pi = 4.0E+00 * atan ( 1.0E+00 )
  92   dt = pi / real ( nm1, kind = 4 )
  93   fk = 0.0E+00
  94   do k = 2, ns2
  95     kc = np1 - k
  96     fk = fk + 1.0E+00
  97     wsave(k) = 2.0E+00 * sin ( fk * dt )
  98     wsave(kc) = 2.0E+00 * cos ( fk * dt )
  99   end do
 100
 101   lnsv = nm1 + int ( log ( real ( nm1, kind = 4 ) ) ) + 4
 102
 103   call rfft1i ( nm1, wsave(n+1), lnsv, ier1 )
 104
 105   if ( ier1 /= 0 ) then
 106     ier = 20
 107     call xerfft ( 'COST1I', -5 )
 108     return
 109   end if
 110
 111   return
 112 end