external/fftpack/fftpack5/d1f2kb.F

   1 subroutine d1f2kb ( ido, l1, cc, in1, ch, in2, wa1 )
   2
   3 !*****************************************************************************80
   4 !
   5 !! D1F2KB is an FFTPACK5 auxiliary routine.
   6 !
   7 !
   8 !
   9 !  Modified:
  10 !
  11 !    27 March 2009
  12 !
  13 !  Author:
  14 !
  15 !    Original real single precision by Paul Swarztrauber, Richard Valent.
  16 !    Real double precision version by John Burkardt.
  17 !
  18 !  Reference:
  19 !
  20 !    Paul Swarztrauber,
  21 !    Vectorizing the Fast Fourier Transforms,
  22 !    in Parallel Computations,
  23 !    edited by G. Rodrigue,
  24 !    Academic Press, 1982.
  25 !
  26 !    Paul Swarztrauber,
  27 !    Fast Fourier Transform Algorithms for Vector Computers,
  28 !    Parallel Computing, pages 45-63, 1984.
  29 !
  30 !  Parameters:
  31 !
  32   implicit none
  33
  34   integer ( kind = 4 ) ido
  35   integer ( kind = 4 ) in1
  36   integer ( kind = 4 ) in2
  37   integer ( kind = 4 ) l1
  38
  39   real ( kind = 8 ) cc(in1,ido,2,l1)
  40   real ( kind = 8 ) ch(in2,ido,l1,2)
  41   integer ( kind = 4 ) i
  42   integer ( kind = 4 ) ic
  43   integer ( kind = 4 ) idp2
  44   integer ( kind = 4 ) k
  45   real ( kind = 8 ) wa1(ido)
  46
  47   do k = 1, l1
  48     ch(1,1,k,1) = cc(1,1,1,k) + cc(1,ido,2,k)
  49     ch(1,1,k,2) = cc(1,1,1,k) - cc(1,ido,2,k)
  50   end do
  51
  52   if ( ido < 2 ) then
  53     return
  54   end if
  55
  56   if ( 2 < ido ) then
  57
  58     idp2 = ido + 2
  59     do k = 1, l1
  60       do i = 3, ido, 2
  61         ic = idp2 - i
  62
  63         ch(1,i-1,k,1) = cc(1,i-1,1,k) + cc(1,ic-1,2,k)
  64         ch(1,i,k,1)   = cc(1,i,1,k)   - cc(1,ic,2,k)
  65
  66         ch(1,i-1,k,2) = wa1(i-2) * ( cc(1,i-1,1,k) - cc(1,ic-1,2,k) ) &
  67                       - wa1(i-1) * ( cc(1,i,1,k)   + cc(1,ic,2,k) )
  68         ch(1,i,k,2)   = wa1(i-2) * ( cc(1,i,1,k)   + cc(1,ic,2,k) ) &
  69                       + wa1(i-1) * ( cc(1,i-1,1,k) - cc(1,ic-1,2,k) )
  70
  71       end do
  72     end do
  73
  74     if ( mod ( ido, 2 ) == 1 ) then
  75       return
  76     end if
  77
  78   end if
  79
  80   do k = 1, l1
  81     ch(1,ido,k,1) =     cc(1,ido,1,k) + cc(1,ido,1,k)
  82     ch(1,ido,k,2) = - ( cc(1,1,2,k)   + cc(1,1,2,k) )
  83   end do
  84
  85   return
  86 end