external/fftpack/fftpack5/sintmf.F

   1 subroutine sintmf ( lot, jump, n, inc, x, lenx, wsave, lensav, &
   2   work, lenwrk, ier )
   3
   4 !*****************************************************************************80
   5 !
   6 !! SINTMF: real single precision forward sine transform, multiple vectors.
   7 !
   8 !  Discussion:
   9 !
  10 !    SINTMF computes the one-dimensional Fourier transform of multiple
  11 !    odd sequences within a real array.  This transform is referred to as
  12 !    the forward transform or Fourier analysis, transforming the sequences
  13 !    from physical to spectral space.
  14 !
  15 !    This transform is normalized since a call to SINTMF followed
  16 !    by a call to SINTMB (or vice-versa) reproduces the original
  17 !    array within roundoff error.
  18 !
  19 !
  20 !    Copyright (C) 1995-2004, Scientific Computing Division,
  21 !    University Corporation for Atmospheric Research
  22 !
  23 !  Modified:
  24 !
  25 !    02 April 2005
  26 !
  27 !  Author:
  28 !
  29 !    Paul Swarztrauber
  30 !    Richard Valent
  31 !
  32 !  Reference:
  33 !
  34 !    Paul Swarztrauber,
  35 !    Vectorizing the Fast Fourier Transforms,
  36 !    in Parallel Computations,
  37 !    edited by G. Rodrigue,
  38 !    Academic Press, 1982.
  39 !
  40 !    Paul Swarztrauber,
  41 !    Fast Fourier Transform Algorithms for Vector Computers,
  42 !    Parallel Computing, pages 45-63, 1984.
  43 !
  44 !  Parameters:
  45 !
  46 !    Input, integer ( kind = 4 ) LOT, the number of sequences to be
  47 !    transformed within.
  48 !
  49 !    Input, integer ( kind = 4 ) JUMP, the increment between the locations,
  50 !    in array R, of the first elements of two consecutive sequences.
  51 !
  52 !    Input, integer ( kind = 4 ) N, the length of each sequence to be
  53 !    transformed.  The transform is most efficient when N+1 is a product of
  54 !    small primes.
  55 !
  56 !    Input, integer ( kind = 4 ) INC, the increment between the locations, in
  57 !    array R, of two consecutive elements within the same sequence.
  58 !
  59 !    Input/output, real ( kind = 4 ) R(LENR), containing LOT sequences, each
  60 !    having length N.  R can have any number of dimensions, but the total
  61 !    number of locations must be at least LENR.  On input, R contains the data
  62 !    to be transformed, and on output, the transformed data.
  63 !
  64 !    Input, integer ( kind = 4 ) LENR, the dimension of the R array.
  65 !    LENR must be at least (LOT-1)*JUMP + INC*(N-1)+ 1.
  66 !
  67 !    Input, real ( kind = 4 ) WSAVE(LENSAV).  WSAVE's contents must be
  68 !    initialized with a call to SINTMI before the first call to routine SINTMF
  69 !    or SINTMB for a given transform length N.  WSAVE's contents may be re-used
  70 !    for subsequent calls to SINTMF and SINTMB with the same N.
  71 !
  72 !    Input, integer ( kind = 4 ) LENSAV, the dimension of the WSAVE array.
  73 !    LENSAV must be at least N/2 + N + INT(LOG(REAL(N))) + 4.
  74 !
  75 !    Workspace, real ( kind = 4 ) WORK(LENWRK).
  76 !
  77 !    Input, integer ( kind = 4 ) LENWRK, the dimension of the WORK array.
  78 !    LENWRK must be at least LOT*(2*N+4).
  79 !
  80 !    Output, integer ( kind = 4 ) IER, error flag.
  81 !    0, successful exit;
  82 !    1, input parameter LENR   not big enough;
  83 !    2, input parameter LENSAV not big enough;
  84 !    3, input parameter LENWRK not big enough;
  85 !    4, input parameters INC,JUMP,N,LOT are not consistent;
  86 !    20, input error returned by lower level routine.
  87 !
  88   implicit none
  89
  90   integer ( kind = 4 ) inc
  91   integer ( kind = 4 ) lensav
  92   integer ( kind = 4 ) lenwrk
  93
  94   integer ( kind = 4 ) ier
  95   integer ( kind = 4 ) ier1
  96   integer ( kind = 4 ) iw1
  97   integer ( kind = 4 ) iw2
  98   integer ( kind = 4 ) jump
  99   integer ( kind = 4 ) lenx
 100   integer ( kind = 4 ) lot
 101   integer ( kind = 4 ) n
 102   real ( kind = 4 ) work(lenwrk)
 103   real ( kind = 4 ) wsave(lensav)
 104   real ( kind = 4 ) x(inc,*)
 105   logical              xercon
 106
 107   ier = 0
 108
 109   if ( lenx < ( lot - 1 ) * jump + inc * ( n - 1 ) + 1 ) then
 110     ier = 1
 111     call xerfft ( 'sintmf', 6 )
 112     return
 113   end if
 114
 115   if ( lensav < n / 2 + n + int ( log ( real ( n, kind = 4 ) ) ) + 4 ) then
 116     ier = 2
 117     call xerfft ( 'sintmf', 8 )
 118     return
 119   end if
 120
 121   if ( lenwrk < lot * ( 2 * n + 4 ) ) then
 122     ier = 3
 123     call xerfft ( 'sintmf', 10 )
 124     return
 125   end if
 126
 127   if ( .not. xercon ( inc, jump, n, lot ) ) then
 128     ier = 4
 129     call xerfft ( 'sintmf', -1 )
 130     return
 131   end if
 132
 133   iw1 = lot + lot + 1
 134   iw2 = iw1 + lot * ( n + 1 )
 135
 136   call msntf1 ( lot, jump, n, inc, x, wsave, work,work(iw1), work(iw2), ier1 )
 137
 138   if ( ier1 /= 0 ) then
 139     ier = 20
 140     call xerfft ( 'sintmf', -5 )
 141     return
 142   end if
 143
 144   return
 145 end