external/fftpack/fftpack5/cosq1b.F

   1 subroutine cosq1b ( n, inc, x, lenx, wsave, lensav, work, lenwrk, ier )
   2
   3 !*****************************************************************************80
   4 !
   5 !! COSQ1B: real single precision backward cosine quarter wave transform, 1D.
   6 !
   7 !  Discussion:
   8 !
   9 !    COSQ1B computes the one-dimensional Fourier transform of a sequence
  10 !    which is a cosine series with odd wave numbers.  This transform is
  11 !    referred to as the backward transform or Fourier synthesis, transforming
  12 !    the sequence from spectral to physical space.
  13 !
  14 !    This transform is normalized since a call to COSQ1B followed
  15 !    by a call to COSQ1F (or vice-versa) reproduces the original
  16 !    array  within roundoff error.
  17 !
  18 !
  19 !    Copyright (C) 1995-2004, Scientific Computing Division,
  20 !    University Corporation for Atmospheric Research
  21 !
  22 !  Modified:
  23 !
  24 !    31 March 2005
  25 !
  26 !  Author:
  27 !
  28 !    Paul Swarztrauber
  29 !    Richard Valent
  30 !
  31 !  Reference:
  32 !
  33 !    Paul Swarztrauber,
  34 !    Vectorizing the Fast Fourier Transforms,
  35 !    in Parallel Computations,
  36 !    edited by G. Rodrigue,
  37 !    Academic Press, 1982.
  38 !
  39 !    Paul Swarztrauber,
  40 !    Fast Fourier Transform Algorithms for Vector Computers,
  41 !    Parallel Computing, pages 45-63, 1984.
  42 !
  43 !  Parameters:
  44 !
  45 !    Input, integer ( kind = 4 ) N, the number of elements to be transformed
  46 !    in the sequence.  The transform is most efficient when N is a
  47 !    product of small primes.
  48 !
  49 !    Input, integer ( kind = 4 ) INC, the increment between the locations,
  50 !    in array R, of two consecutive elements within the sequence.
  51 !
  52 !    Input/output, real ( kind = 4 ) R(LENR); on input, containing the sequence
  53 !    to be transformed, and on output, containing the transformed sequence.
  54 !
  55 !    Input, integer ( kind = 4 ) LENR, the dimension of the R array.
  56 !    LENR must be at least INC*(N-1)+ 1.
  57 !
  58 !    Input, real ( kind = 4 ) WSAVE(LENSAV).  WSAVE's contents must be
  59 !    initialized with a call to COSQ1I before the first call to routine COSQ1F
  60 !    or COSQ1B for a given transform length N.  WSAVE's contents may be
  61 !    re-used for subsequent calls to COSQ1F and COSQ1B with the same N.
  62 !
  63 !    Input, integer ( kind = 4 ) LENSAV, the dimension of the WSAVE array.
  64 !    LENSAV must be at least 2*N + INT(LOG(REAL(N))) + 4.
  65 !
  66 !    Workspace, real ( kind = 4 ) WORK(LENWRK).
  67 !
  68 !    Input, integer ( kind = 4 ) LENWRK, the dimension of the WORK array.
  69 !    LENWRK must be at least N.
  70 !
  71 !    Output, integer ( kind = 4 ) IER, error flag.
  72 !    0, successful exit;
  73 !    1, input parameter LENR   not big enough;
  74 !    2, input parameter LENSAV not big enough;
  75 !    3, input parameter LENWRK not big enough;
  76 !    20, input error returned by lower level routine.
  77 !
  78   implicit none
  79
  80   integer ( kind = 4 ) inc
  81   integer ( kind = 4 ) lensav
  82   integer ( kind = 4 ) lenwrk
  83
  84   integer ( kind = 4 ) ier
  85   integer ( kind = 4 ) ier1
  86   integer ( kind = 4 ) lenx
  87   integer ( kind = 4 ) n
  88   real ( kind = 4 ) ssqrt2
  89   real ( kind = 4 ) work(lenwrk)
  90   real ( kind = 4 ) wsave(lensav)
  91   real ( kind = 4 ) x(inc,*)
  92   real ( kind = 4 ) x1
  93
  94   ier = 0
  95
  96   if ( lenx < inc * ( n - 1 ) + 1 ) then
  97     ier = 1
  98     call xerfft ( 'COSQ1B', 6 )
  99     return
 100   end if
 101
 102   if ( lensav < 2 * n + int ( log ( real ( n, kind = 4 ) ) ) + 4 ) then
 103     ier = 2
 104     call xerfft ( 'COSQ1B', 8 )
 105     return
 106   end if
 107
 108   if ( lenwrk < n ) then
 109     ier = 3
 110     call xerfft ( 'COSQ1B', 10 )
 111     return
 112   end if
 113
 114   if ( n < 2 ) then
 115     return
 116   end if
 117
 118   if ( n == 2 ) then
 119     ssqrt2 = 1.0E+00 / sqrt ( 2.0E+00 )
 120     x1 = x(1,1) + x(1,2)
 121     x(1,2) = ssqrt2 * ( x(1,1) - x(1,2) )
 122     x(1,1) = x1
 123     return
 124   end if
 125
 126   call cosqb1 ( n, inc, x, wsave, work, ier1 )
 127
 128   if ( ier1 /= 0 ) then
 129     ier = 20
 130     call xerfft ( 'COSQ1B', -5 )
 131     return
 132   end if
 133
 134   return
 135 end