external/fftpack/fftpack5/cosqmf.F

   1 subroutine cosqmf ( lot, jump, n, inc, x, lenx, wsave, lensav, work, &
   2   lenwrk, ier )
   3
   4 !*****************************************************************************80
   5 !
   6 !! COSQMF: real single precision forward cosine quarter wave, multiple vectors.
   7 !
   8 !  Discussion:
   9 !
  10 !    COSQMF computes the one-dimensional Fourier transform of multiple
  11 !    sequences within a real array, where each of the sequences is a
  12 !    cosine series with odd wave numbers.  This transform is referred to
  13 !    as the forward transform or Fourier synthesis, transforming the
  14 !    sequences from spectral to physical space.
  15 !
  16 !    This transform is normalized since a call to COSQMF followed
  17 !    by a call to COSQMB (or vice-versa) reproduces the original
  18 !    array within roundoff error.
  19 !
  20 !
  21 !    Copyright (C) 1995-2004, Scientific Computing Division,
  22 !    University Corporation for Atmospheric Research
  23 !
  24 !  Modified:
  25 !
  26 !    01 April 2005
  27 !
  28 !  Author:
  29 !
  30 !    Paul Swarztrauber
  31 !    Richard Valent
  32 !
  33 !  Reference:
  34 !
  35 !    Paul Swarztrauber,
  36 !    Vectorizing the Fast Fourier Transforms,
  37 !    in Parallel Computations,
  38 !    edited by G. Rodrigue,
  39 !    Academic Press, 1982.
  40 !
  41 !    Paul Swarztrauber,
  42 !    Fast Fourier Transform Algorithms for Vector Computers,
  43 !    Parallel Computing, pages 45-63, 1984.
  44 !
  45 !  Parameters:
  46 !
  47 !    Input, integer ( kind = 4 ) LOT, the number of sequences to be transformed
  48 !    within array R.
  49 !
  50 !    Input, integer ( kind = 4 ) JUMP, the increment between the locations, in
  51 !    array R, of the first elements of two consecutive sequences to be
  52 !    transformed.
  53 !
  54 !    Input, integer ( kind = 4 ) N, the length of each sequence to be
  55 !    transformed.  The transform is most efficient when N is a product of
  56 !    small primes.
  57 !
  58 !    Input, integer ( kind = 4 ) INC, the increment between the locations,
  59 !    in array R, of two consecutive elements within the same sequence.
  60 !
  61 !    Input/output, real ( kind = 4 ) R(LENR), array containing LOT sequences,
  62 !    each having length N.  R can have any number of dimensions, but the total
  63 !    number of locations must be at least LENR.  On input, R contains the data
  64 !    to be transformed, and on output, the transformed data.
  65 !
  66 !    Input, integer ( kind = 4 ) LENR, the dimension of the R array.
  67 !    LENR must be at least (LOT-1)*JUMP + INC*(N-1)+ 1.
  68 !
  69 !    Input, real ( kind = 4 ) WSAVE(LENSAV).  WSAVE's contents must be
  70 !    initialized with a call to COSQMI before the first call to routine COSQMF
  71 !    or COSQMB for a given transform length N.  WSAVE's contents may be re-used
  72 !    for subsequent calls to COSQMF and COSQMB with the same N.
  73 !
  74 !    Input, integer ( kind = 4 ) LENSAV, the dimension of the WSAVE array.
  75 !    LENSAV must be at least 2*N + INT(LOG(REAL(N))) + 4.
  76 !
  77 !    Workspace, real ( kind = 4 ) WORK(LENWRK).
  78 !
  79 !    Input, integer ( kind = 4 ) LENWRK, the dimension of the WORK array.
  80 !    LENWRK must be at least LOT*N.
  81 !
  82 !    Output, integer ( kind = 4 ) IER, error flag.
  83 !    0, successful exit;
  84 !    1, input parameter LENR   not big enough;
  85 !    2, input parameter LENSAV not big enough;
  86 !    3, input parameter LENWRK not big enough;
  87 !    4, input parameters INC,JUMP,N,LOT are not consistent;
  88 !    20, input error returned by lower level routine.
  89 !
  90   implicit none
  91
  92   integer ( kind = 4 ) inc
  93   integer ( kind = 4 ) lensav
  94   integer ( kind = 4 ) lenwrk
  95
  96   integer ( kind = 4 ) ier
  97   integer ( kind = 4 ) ier1
  98   integer ( kind = 4 ) jump
  99   integer ( kind = 4 ) lenx
 100   integer ( kind = 4 ) lj
 101   integer ( kind = 4 ) lot
 102   integer ( kind = 4 ) m
 103   integer ( kind = 4 ) n
 104   real ( kind = 4 ) ssqrt2
 105   real ( kind = 4 ) tsqx
 106   real ( kind = 4 ) work(lenwrk)
 107   real ( kind = 4 ) wsave(lensav)
 108   real ( kind = 4 ) x(inc,*)
 109   logical              xercon
 110
 111   ier = 0
 112
 113   if ( lenx < ( lot - 1 ) * jump + inc * ( n - 1 ) + 1 ) then
 114     ier = 1
 115     call xerfft ( 'cosqmf', 6 )
 116     return
 117   end if
 118
 119   if ( lensav < 2 * n + int ( log ( real ( n, kind = 4 ) ) ) + 4 ) then
 120     ier = 2
 121     call xerfft ( 'cosqmf', 8 )
 122     return
 123   end if
 124
 125   if ( lenwrk < lot * n ) then
 126     ier = 3
 127     call xerfft ( 'cosqmf', 10 )
 128     return
 129   end if
 130
 131   if ( .not. xercon ( inc, jump, n, lot ) ) then
 132     ier = 4
 133     call xerfft ( 'cosqmf', -1 )
 134     return
 135   end if
 136
 137   lj = ( lot - 1 ) * jump + 1
 138
 139   if ( n < 2 ) then
 140     return
 141   end if
 142
 143   if ( n == 2 ) then
 144
 145     ssqrt2 = 1.0E+00 / sqrt ( 2.0E+00 )
 146
 147     do m = 1, lj, jump
 148       tsqx = ssqrt2 * x(m,2)
 149       x(m,2) = 0.5E+00 * x(m,1) - tsqx
 150       x(m,1) = 0.5E+00 * x(m,1) + tsqx
 151     end do
 152
 153     return
 154   end if
 155
 156   call mcsqf1 ( lot, jump, n, inc, x, wsave, work, ier1 )
 157
 158   if ( ier1 /= 0 ) then
 159     ier = 20
 160     call xerfft ( 'cosqmf', -5 )
 161     return
 162   end if
 163
 164   return
 165 end