external/fftpack/fftpack5/cosqmi.F

   1 subroutine cosqmi ( n, wsave, lensav, ier )
   2
   3 !*****************************************************************************80
   4 !
   5 !! COSQMI: initialization for COSQMB and COSQMF.
   6 !
   7 !  Discussion:
   8 !
   9 !    COSQMI initializes array WSAVE for use in its companion routines
  10 !    COSQMF and COSQMB.  The prime factorization of N together with a
  11 !    tabulation of the trigonometric functions are computed and stored
  12 !    in array WSAVE.  Separate WSAVE arrays are required for different
  13 !    values of N.
  14 !
  15 !
  16 !    Copyright (C) 1995-2004, Scientific Computing Division,
  17 !    University Corporation for Atmospheric Research
  18 !
  19 !  Modified:
  20 !
  21 !    01 April 2005
  22 !
  23 !  Author:
  24 !
  25 !    Paul Swarztrauber
  26 !    Richard Valent
  27 !
  28 !  Reference:
  29 !
  30 !    Paul Swarztrauber,
  31 !    Vectorizing the Fast Fourier Transforms,
  32 !    in Parallel Computations,
  33 !    edited by G. Rodrigue,
  34 !    Academic Press, 1982.
  35 !
  36 !    Paul Swarztrauber,
  37 !    Fast Fourier Transform Algorithms for Vector Computers,
  38 !    Parallel Computing, pages 45-63, 1984.
  39 !
  40 !  Parameters:
  41 !
  42 !    Input, integer ( kind = 4 ) N, the length of each sequence to be
  43 !    transformed.  The transform is most efficient when N is a product of
  44 !    small primes.
  45 !
  46 !    Input, integer ( kind = 4 ) LENSAV, the dimension of the WSAVE array.
  47 !    LENSAV must be at least 2*N + INT(LOG(REAL(N))) + 4.
  48 !
  49 !    Output, real ( kind = 4 ) WSAVE(LENSAV), containing the prime factors of
  50 !    N and also containing certain trigonometric values which will be used
  51 !    in routines COSQMB or COSQMF.
  52 !
  53 !    Input, integer ( kind = 4 ) IER, error flag.
  54 !    0, successful exit;
  55 !    2, input parameter LENSAV not big enough;
  56 !    20, input error returned by lower level routine.
  57 !
  58   implicit none
  59
  60   integer ( kind = 4 ) lensav
  61
  62   real ( kind = 4 ) dt
  63   real ( kind = 4 ) fk
  64   integer ( kind = 4 ) ier
  65   integer ( kind = 4 ) ier1
  66   integer ( kind = 4 ) k
  67   integer ( kind = 4 ) lnsv
  68   integer ( kind = 4 ) n
  69   real ( kind = 4 ) pih
  70   real ( kind = 4 ) wsave(lensav)
  71
  72   ier = 0
  73
  74   if ( lensav < 2 * n + int ( log ( real ( n, kind = 4 ) ) ) + 4 ) then
  75     ier = 2
  76     call xerfft ( 'cosqmi', 3 )
  77     return
  78   end if
  79
  80   pih = 2.0E+00 * atan ( 1.0E+00 )
  81
  82   dt = pih / real ( n, kind = 4 )
  83
  84   fk = 0.0E+00
  85   do k = 1, n
  86     fk = fk + 1.0E+00
  87     wsave(k) = cos ( fk * dt )
  88   end do
  89
  90   lnsv = n + int ( log ( real ( n, kind = 4 ) ) ) + 4
  91
  92   call rfftmi ( n, wsave(n+1), lnsv, ier1 )
  93
  94   if ( ier1 /= 0 ) then
  95     ier = 20
  96     call xerfft ( 'cosqmi', -5 )
  97     return
  98   end if
  99
 100   return
 101 end