external/fftpack/fftpack5/dcosq1i.F

   1 subroutine dcosq1i ( n, wsave, lensav, ier )
   2
   3 !*****************************************************************************80
   4 !
   5 !! DCOSQ1I: initialization for DCOSQ1B and DCOSQ1F.
   6 !
   7 !  Discussion:
   8 !
   9 !    DCOSQ1I initializes array WSAVE for use in its companion routines
  10 !    DCOSQ1F and DCOSQ1B.  The prime factorization of N together with a
  11 !    tabulation of the trigonometric functions are computed and stored
  12 !    in array WSAVE.  Separate WSAVE arrays are required for different
  13 !    values of N.
  14 !
  15 !
  16 !
  17 !  Modified:
  18 !
  19 !    17 November 2007
  20 !
  21 !  Author:
  22 !
  23 !    Original real single precision by Paul Swarztrauber, Richard Valent.
  24 !    Real double precision version by John Burkardt.
  25 !
  26 !  Reference:
  27 !
  28 !    Paul Swarztrauber,
  29 !    Vectorizing the Fast Fourier Transforms,
  30 !    in Parallel Computations,
  31 !    edited by G. Rodrigue,
  32 !    Academic Press, 1982.
  33 !
  34 !    Paul Swarztrauber,
  35 !    Fast Fourier Transform Algorithms for Vector Computers,
  36 !    Parallel Computing, pages 45-63, 1984.
  37 !
  38 !  Parameters:
  39 !
  40 !    Input, integer ( kind = 4 ) N, the length of the sequence to be
  41 !    transformed.  The transform is most efficient when N is a product of small
  42 !    primes.
  43 !
  44 !    Input, integer ( kind = 4 ) LENSAV, the dimension of the WSAVE array.
  45 !    LENSAV must be at least 2*N + INT(LOG(REAL(N))) + 4.
  46 !
  47 !    Output, real ( kind = 8 ) WSAVE(LENSAV), containing the prime factors of
  48 !    N and also containing certain trigonometric values which will be used
  49 !    in routines DCOSQ1B or DCOSQ1F.
  50 !
  51 !    Output, integer ( kind = 4 ) IER, error flag.
  52 !    0, successful exit;
  53 !    2, input parameter LENSAV not big enough;
  54 !    20, input error returned by lower level routine.
  55 !
  56   implicit none
  57
  58   integer ( kind = 4 ) lensav
  59
  60   real ( kind = 8 ) dt
  61   real ( kind = 8 ) fk
  62   integer ( kind = 4 ) ier
  63   integer ( kind = 4 ) ier1
  64   integer ( kind = 4 ) k
  65   integer ( kind = 4 ) lnsv
  66   integer ( kind = 4 ) n
  67   real ( kind = 8 ) pih
  68   real ( kind = 8 ) wsave(lensav)
  69
  70   ier = 0
  71
  72   if ( lensav < 2 * n + int ( log ( real ( n, kind = 8 ) ) ) + 4 ) then
  73     ier = 2
  74     call xerfft ( 'dcosq1i', 3 )
  75     return
  76   end if
  77
  78   pih = 2.0D+00 * atan ( 1.0D+00 )
  79   dt = pih / real ( n, kind = 8 )
  80   fk = 0.0D+00
  81
  82   do k = 1, n
  83     fk = fk + 1.0D+00
  84     wsave(k) = cos ( fk * dt )
  85   end do
  86
  87   lnsv = n + int ( log ( real ( n, kind = 8 ) ) ) + 4
  88
  89   call dfft1i ( n, wsave(n+1), lnsv, ier1 )
  90
  91   if ( ier1 /= 0 ) then
  92     ier = 20
  93     call xerfft ( 'dcosq1i', -5 )
  94     return
  95   end if
  96
  97   return
  98 end