external/fftpack/fftpack5/mradf4.F

   1 subroutine mradf4 ( m, ido, l1, cc, im1, in1, ch, im2, in2, wa1, wa2, wa3 )
   2
   3 !*****************************************************************************80
   4 !
   5 !! MRADF4 is an FFTPACK5 auxiliary routine.
   6 !
   7 !
   8 !    Copyright (C) 1995-2004, Scientific Computing Division,
   9 !    University Corporation for Atmospheric Research
  10 !
  11 !  Modified:
  12 !
  13 !    27 March 2009
  14 !
  15 !  Author:
  16 !
  17 !    Paul Swarztrauber
  18 !    Richard Valent
  19 !
  20 !  Reference:
  21 !
  22 !    Paul Swarztrauber,
  23 !    Vectorizing the Fast Fourier Transforms,
  24 !    in Parallel Computations,
  25 !    edited by G. Rodrigue,
  26 !    Academic Press, 1982.
  27 !
  28 !    Paul Swarztrauber,
  29 !    Fast Fourier Transform Algorithms for Vector Computers,
  30 !    Parallel Computing, pages 45-63, 1984.
  31 !
  32 !  Parameters:
  33 !
  34   implicit none
  35
  36   integer ( kind = 4 ) ido
  37   integer ( kind = 4 ) in1
  38   integer ( kind = 4 ) in2
  39   integer ( kind = 4 ) l1
  40
  41   real ( kind = 4 ) cc(in1,ido,l1,4)
  42   real ( kind = 4 ) ch(in2,ido,4,l1)
  43   real ( kind = 4 ) hsqt2
  44   integer ( kind = 4 ) i
  45   integer ( kind = 4 ) ic
  46   integer ( kind = 4 ) idp2
  47   integer ( kind = 4 ) im1
  48   integer ( kind = 4 ) im2
  49   integer ( kind = 4 ) k
  50   integer ( kind = 4 ) m
  51   integer ( kind = 4 ) m1
  52   integer ( kind = 4 ) m1d
  53   integer ( kind = 4 ) m2
  54   integer ( kind = 4 ) m2s
  55   real ( kind = 4 ) wa1(ido)
  56   real ( kind = 4 ) wa2(ido)
  57   real ( kind = 4 ) wa3(ido)
  58
  59   hsqt2 = sqrt ( 2.0E+00 ) / 2.0E+00
  60   m1d = ( m - 1 ) * im1 + 1
  61   m2s = 1 - im2
  62
  63   do k = 1, l1
  64     m2 = m2s
  65     do m1 = 1, m1d, im1
  66       m2 = m2 + im2
  67       ch(m2,1,1,k) =   ( cc(m1,1,k,2) + cc(m1,1,k,4) ) &
  68                      + ( cc(m1,1,k,1) + cc(m1,1,k,3) )
  69       ch(m2,ido,4,k) = ( cc(m1,1,k,1) + cc(m1,1,k,3) ) &
  70                       -( cc(m1,1,k,2) + cc(m1,1,k,4) )
  71       ch(m2,ido,2,k) =   cc(m1,1,k,1) - cc(m1,1,k,3)
  72       ch(m2,1,3,k) =     cc(m1,1,k,4) - cc(m1,1,k,2)
  73     end do
  74   end do
  75
  76   if ( ido < 2 ) then
  77     return
  78   end if
  79
  80   if ( 2 < ido ) then
  81
  82     idp2 = ido + 2
  83
  84     do k = 1, l1
  85       do i = 3, ido, 2
  86         ic = idp2 - i
  87         m2 = m2s
  88         do m1 = 1, m1d, im1
  89           m2 = m2 + im2
  90           ch(m2,i-1,1,k) = ((wa1(i-2)*cc(m1,i-1,k,2) + wa1(i-1)* &
  91             cc(m1,i,k,2))+(wa3(i-2)*cc(m1,i-1,k,4) + wa3(i-1)* &
  92             cc(m1,i,k,4)))+(cc(m1,i-1,k,1)+(wa2(i-2)*cc(m1,i-1,k,3)+ &
  93             wa2(i-1)*cc(m1,i,k,3)))
  94           ch(m2,ic-1,4,k) = (cc(m1,i-1,k,1)+(wa2(i-2)*cc(m1,i-1,k,3)+ &
  95             wa2(i-1)*cc(m1,i,k,3)))-((wa1(i-2)*cc(m1,i-1,k,2)+ &
  96             wa1(i-1)*cc(m1,i,k,2))+(wa3(i-2)*cc(m1,i-1,k,4)+ &
  97             wa3(i-1)*cc(m1,i,k,4)))
  98           ch(m2,i,1,k) = ((wa1(i-2)*cc(m1,i,k,2)-wa1(i-1)* &
  99             cc(m1,i-1,k,2))+(wa3(i-2)*cc(m1,i,k,4)-wa3(i-1)* &
 100             cc(m1,i-1,k,4)))+(cc(m1,i,k,1)+(wa2(i-2)*cc(m1,i,k,3)- &
 101             wa2(i-1)*cc(m1,i-1,k,3)))
 102           ch(m2,ic,4,k) = ((wa1(i-2)*cc(m1,i,k,2)-wa1(i-1)* &
 103             cc(m1,i-1,k,2))+(wa3(i-2)*cc(m1,i,k,4)-wa3(i-1)* &
 104             cc(m1,i-1,k,4)))-(cc(m1,i,k,1)+(wa2(i-2)*cc(m1,i,k,3)- &
 105             wa2(i-1)*cc(m1,i-1,k,3)))
 106           ch(m2,i-1,3,k) = ((wa1(i-2)*cc(m1,i,k,2)-wa1(i-1)* &
 107             cc(m1,i-1,k,2))-(wa3(i-2)*cc(m1,i,k,4)-wa3(i-1)* &
 108             cc(m1,i-1,k,4)))+(cc(m1,i-1,k,1)-(wa2(i-2)*cc(m1,i-1,k,3)+ &
 109             wa2(i-1)*cc(m1,i,k,3)))
 110           ch(m2,ic-1,2,k) = (cc(m1,i-1,k,1)-(wa2(i-2)*cc(m1,i-1,k,3)+ &
 111             wa2(i-1)*cc(m1,i,k,3)))-((wa1(i-2)*cc(m1,i,k,2)-wa1(i-1)* &
 112             cc(m1,i-1,k,2))-(wa3(i-2)*cc(m1,i,k,4)-wa3(i-1)* &
 113             cc(m1,i-1,k,4)))
 114           ch(m2,i,3,k) = ((wa3(i-2)*cc(m1,i-1,k,4) + wa3(i-1)* &
 115             cc(m1,i,k,4))-(wa1(i-2)*cc(m1,i-1,k,2) + wa1(i-1)* &
 116             cc(m1,i,k,2)))+(cc(m1,i,k,1)-(wa2(i-2)*cc(m1,i,k,3)- &
 117             wa2(i-1)*cc(m1,i-1,k,3)))
 118           ch(m2,ic,2,k) = ((wa3(i-2)*cc(m1,i-1,k,4) + wa3(i-1)* &
 119             cc(m1,i,k,4))-(wa1(i-2)*cc(m1,i-1,k,2) + wa1(i-1)* &
 120             cc(m1,i,k,2)))-(cc(m1,i,k,1)-(wa2(i-2)*cc(m1,i,k,3)- &
 121             wa2(i-1)*cc(m1,i-1,k,3)))
 122         end do
 123       end do
 124     end do
 125
 126     if ( mod ( ido, 2 ) == 1 ) then
 127       return
 128     end if
 129
 130   end if
 131
 132   do k = 1, l1
 133     m2 = m2s
 134     do m1 = 1, m1d, im1
 135       m2 = m2 + im2
 136       ch(m2,ido,1,k) = cc(m1,ido,k,1) &
 137         + (  hsqt2 * ( cc(m1,ido,k,2) - cc(m1,ido,k,4) ) )
 138       ch(m2,ido,3,k) = cc(m1,ido,k,1) &
 139         - (  hsqt2 * ( cc(m1,ido,k,2) - cc(m1,ido,k,4) ) )
 140       ch(m2,1,2,k) =  -cc(m1,ido,k,3) &
 141         + ( -hsqt2 * ( cc(m1,ido,k,2) + cc(m1,ido,k,4) ) )
 142       ch(m2,1,4,k) =   cc(m1,ido,k,3) &
 143         + ( -hsqt2 * ( cc(m1,ido,k,2) + cc(m1,ido,k,4) ) )
 144     end do
 145   end do
 146
 147   return
 148 end