external/fftpack/fftpack5/sint1i.F

   1 subroutine sint1i ( n, wsave, lensav, ier )
   2
   3 !*****************************************************************************80
   4 !
   5 !! SINT1I: initialization for SINT1B and SINT1F.
   6 !
   7 !  Discussion:
   8 !
   9 !    SINT1I initializes array WSAVE for use in its companion routines
  10 !    SINT1F and SINT1B.  The prime factorization of N together with a
  11 !    tabulation of the trigonometric functions are computed and stored
  12 !    in array WSAVE.  Separate WSAVE arrays are required for different
  13 !    values of N.
  14 !
  15 !
  16 !    Copyright (C) 1995-2004, Scientific Computing Division,
  17 !    University Corporation for Atmospheric Research
  18 !
  19 !  Modified:
  20 !
  21 !    30 March 2005
  22 !
  23 !  Author:
  24 !
  25 !    Paul Swarztrauber
  26 !    Richard Valent
  27 !
  28 !  Reference:
  29 !
  30 !    Paul Swarztrauber,
  31 !    Vectorizing the Fast Fourier Transforms,
  32 !    in Parallel Computations,
  33 !    edited by G. Rodrigue,
  34 !    Academic Press, 1982.
  35 !
  36 !    Paul Swarztrauber,
  37 !    Fast Fourier Transform Algorithms for Vector Computers,
  38 !    Parallel Computing, pages 45-63, 1984.
  39 !
  40 !  Parameters:
  41 !
  42 !    Input, integer ( kind = 4 ) N, the length of the sequence to be
  43 !    transformed.  The transform is most efficient when N+1 is a product
  44 !    of small primes.
  45 !
  46 !    Input, integer ( kind = 4 ) LENSAV, the dimension of the WSAVE array.
  47 !    LENSAV must be at least N/2 + N + INT(LOG(REAL(N))) + 4.
  48 !
  49 !    Output, real ( kind = 4 ) WSAVE(LENSAV), containing the prime factors
  50 !    of N and also containing certain trigonometric values which will be used
  51 !    in routines SINT1B or SINT1F.
  52 !
  53 !    Output, integer ( kind = 4 ) IER, error flag.
  54 !    0, successful exit;
  55 !    2, input parameter LENSAV not big enough;
  56 !    20, input error returned by lower level routine.
  57 !
  58   implicit none
  59
  60   integer ( kind = 4 ) lensav
  61
  62   real ( kind = 4 ) dt
  63   integer ( kind = 4 ) ier
  64   integer ( kind = 4 ) ier1
  65   integer ( kind = 4 ) k
  66   integer ( kind = 4 ) lnsv
  67   integer ( kind = 4 ) n
  68   integer ( kind = 4 ) np1
  69   integer ( kind = 4 ) ns2
  70   real ( kind = 4 ) pi
  71   real ( kind = 4 ) wsave(lensav)
  72
  73   ier = 0
  74
  75   if ( lensav < n / 2 + n + int ( log ( real ( n, kind = 4 ) ) ) + 4 ) then
  76     ier = 2
  77     call xerfft ( 'SINT1I', 3 )
  78     return
  79   end if
  80
  81   pi = 4.0E+00 * atan ( 1.0E+00 )
  82
  83   if ( n <= 1 ) then
  84     return
  85   end if
  86
  87   ns2 = n / 2
  88   np1 = n + 1
  89   dt = pi / real ( np1, kind = 4 )
  90
  91   do k = 1, ns2
  92     wsave(k) = 2.0E+00 * sin ( real ( k, kind = 4 ) * dt )
  93   end do
  94
  95   lnsv = np1 + int ( log ( real ( np1, kind = 4 ) ) ) + 4
  96
  97   call rfft1i ( np1, wsave(ns2+1), lnsv, ier1 )
  98
  99   if ( ier1 /= 0 ) then
 100     ier = 20
 101     call xerfft ( 'SINT1I', -5 )
 102     return
 103   end if
 104
 105   return
 106 end