external/fftpack/fftpack5/z1f2kb.F

   1 subroutine z1f2kb ( ido, l1, na, cc, in1, ch, in2, wa )
   2
   3 !*****************************************************************************80
   4 !
   5 !! Z1F2KB is an FFTPACK5 auxiliary routine.
   6 !
   7 !
   8 !
   9 !  Modified:
  10 !
  11 !    26 Ausust 2009
  12 !
  13 !  Author:
  14 !
  15 !    Original complex single precision by Paul Swarztrauber, Richard Valent.
  16 !    Complex double precision version by John Burkardt.
  17 !
  18 !  Reference:
  19 !
  20 !    Paul Swarztrauber,
  21 !    Vectorizing the Fast Fourier Transforms,
  22 !    in Parallel Computations,
  23 !    edited by G. Rodrigue,
  24 !    Academic Press, 1982.
  25 !
  26 !    Paul Swarztrauber,
  27 !    Fast Fourier Transform Algorithms for Vector Computers,
  28 !    Parallel Computing, pages 45-63, 1984.
  29 !
  30 !  Parameters:
  31 !
  32   implicit none
  33
  34   integer ( kind = 4 ) ido
  35   integer ( kind = 4 ) in1
  36   integer ( kind = 4 ) in2
  37   integer ( kind = 4 ) l1
  38
  39   real ( kind = 8 ) cc(in1,l1,ido,2)
  40   real ( kind = 8 ) ch(in2,l1,2,ido)
  41   real ( kind = 8 ) chold1
  42   real ( kind = 8 ) chold2
  43   integer ( kind = 4 ) i
  44   integer ( kind = 4 ) k
  45   integer ( kind = 4 ) na
  46   real ( kind = 8 ) ti2
  47   real ( kind = 8 ) tr2
  48   real ( kind = 8 ) wa(ido,1,2)
  49
  50   if ( 1 < ido .or. na == 1 ) then
  51
  52     do k = 1, l1
  53       ch(1,k,1,1) = cc(1,k,1,1) + cc(1,k,1,2)
  54       ch(1,k,2,1) = cc(1,k,1,1) - cc(1,k,1,2)
  55       ch(2,k,1,1) = cc(2,k,1,1) + cc(2,k,1,2)
  56       ch(2,k,2,1) = cc(2,k,1,1) - cc(2,k,1,2)
  57     end do
  58
  59     do i = 2, ido
  60       do k = 1, l1
  61
  62         ch(1,k,1,i) = cc(1,k,i,1) + cc(1,k,i,2)
  63         tr2         = cc(1,k,i,1) - cc(1,k,i,2)
  64         ch(2,k,1,i) = cc(2,k,i,1) + cc(2,k,i,2)
  65         ti2         = cc(2,k,i,1) - cc(2,k,i,2)
  66
  67         ch(2,k,2,i) = wa(i,1,1) * ti2 + wa(i,1,2) * tr2
  68         ch(1,k,2,i) = wa(i,1,1) * tr2 - wa(i,1,2) * ti2
  69
  70       end do
  71     end do
  72
  73   else
  74
  75     do k = 1, l1
  76
  77       chold1      = cc(1,k,1,1) + cc(1,k,1,2)
  78       cc(1,k,1,2) = cc(1,k,1,1) - cc(1,k,1,2)
  79       cc(1,k,1,1) = chold1
  80
  81       chold2      = cc(2,k,1,1) + cc(2,k,1,2)
  82       cc(2,k,1,2) = cc(2,k,1,1) - cc(2,k,1,2)
  83       cc(2,k,1,1) = chold2
  84
  85     end do
  86
  87   end if
  88
  89   return
  90 end