var/external/lapack/dorg2l.inc

   1       SUBROUTINE DORG2L( M, N, K, A, LDA, TAU, WORK, INFO )
   2 !
   3 !  -- LAPACK routine (version 3.1) --
   4 !     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
   5 !     November 2006
   6 !
   7 !     .. Scalar Arguments ..
   8       INTEGER            INFO, K, LDA, M, N
   9 !     ..
  10 !     .. Array Arguments ..
  11       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
  12 !     ..
  13 !
  14 !  Purpose
  15 !  =======
  16 !
  17 !  DORG2L generates an m by n real matrix Q with orthonormal columns,
  18 !  which is defined as the last n columns of a product of k elementary
  19 !  reflectors of order m
  20 !
  21 !        Q  =  H(k) . . . H(2) H(1)
  22 !
  23 !  as returned by DGEQLF.
  24 !
  25 !  Arguments
  26 !  =========
  27 !
  28 !  M       (input) INTEGER
  29 !          The number of rows of the matrix Q. M >= 0.
  30 !
  31 !  N       (input) INTEGER
  32 !          The number of columns of the matrix Q. M >= N >= 0.
  33 !
  34 !  K       (input) INTEGER
  35 !          The number of elementary reflectors whose product defines the
  36 !          matrix Q. N >= K >= 0.
  37 !
  38 !  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
  39 !          On entry, the (n-k+i)-th column must contain the vector which
  40 !          defines the elementary reflector H(i), for i = 1,2,...,k, as
  41 !          returned by DGEQLF in the last k columns of its array
  42 !          argument A.
  43 !          On exit, the m by n matrix Q.
  44 !
  45 !  LDA     (input) INTEGER
  46 !          The first dimension of the array A. LDA >= max(1,M).
  47 !
  48 !  TAU     (input) DOUBLE PRECISION array, dimension (K)
  49 !          TAU(i) must contain the scalar factor of the elementary
  50 !          reflector H(i), as returned by DGEQLF.
  51 !
  52 !  WORK    (workspace) DOUBLE PRECISION array, dimension (N)
  53 !
  54 !  INFO    (output) INTEGER
  55 !          = 0: successful exit
  56 !          < 0: if INFO = -i, the i-th argument has an illegal value
  57 !
  58 !  =====================================================================
  59 !
  60 !     .. Parameters ..
  61       DOUBLE PRECISION   ONE, ZERO
  62       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
  63 !     ..
  64 !     .. Local Scalars ..
  65       INTEGER            I, II, J, L
  66 !     ..
  67 !     .. External Subroutines ..
  68 !     EXTERNAL           DLARF, DSCAL, XERBLA
  69 !     ..
  70 !     .. Intrinsic Functions ..
  71       INTRINSIC          MAX
  72 !     ..
  73 !     .. Executable Statements ..
  74 !
  75 !     Test the input arguments
  76 !
  77       INFO = 0
  78       IF( M.LT.0 ) THEN
  79          INFO = -1
  80       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
  81          INFO = -2
  82       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
  83          INFO = -3
  84       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  85          INFO = -5
  86       END IF
  87       IF( INFO.NE.0 ) THEN
  88          CALL XERBLA( 'DORG2L', -INFO )
  89          RETURN
  90       END IF
  91 !
  92 !     Quick return if possible
  93 !
  94       IF( N.LE.0 ) &
  95          RETURN
  96 !
  97 !     Initialise columns 1:n-k to columns of the unit matrix
  98 !
  99       DO 20 J = 1, N - K
 100          DO 10 L = 1, M
 101             A( L, J ) = ZERO
 102    10    CONTINUE
 103          A( M-N+J, J ) = ONE
 104    20 CONTINUE
 105 !
 106       DO 40 I = 1, K
 107          II = N - K + I
 108 !
 109 !        Apply H(i) to A(1:m-k+i,1:n-k+i) from the left
 110 !
 111          A( M-N+II, II ) = ONE
 112          CALL DLARF( 'Left', M-N+II, II-1, A( 1, II ), 1, TAU( I ), A, &
 113                      LDA, WORK )
 114          CALL DSCAL( M-N+II-1, -TAU( I ), A( 1, II ), 1 )
 115          A( M-N+II, II ) = ONE - TAU( I )
 116 !
 117 !        Set A(m-k+i+1:m,n-k+i) to zero
 118 !
 119          DO 30 L = M - N + II + 1, M
 120             A( L, II ) = ZERO
 121    30    CONTINUE
 122    40 CONTINUE
 123       RETURN
 124 !
 125 !     End of DORG2L
 126 !
 127       END SUBROUTINE DORG2L