var/da/da_gpseph/da_jo_and_grady_gpseph.inc

   1 subroutine da_jo_and_grady_gpseph( iv, re, jo, jo_grad_y)
   2
   3    !-----------------------------------------------------------------------
   4    ! Purpose: calculate Jo and Grad_y(Jo) for gpseph obs
   5    !-----------------------------------------------------------------------
   6
   7    !----------------------------------------------------------------------
   8    ! Called by da_minimisation/da_jo_and_grady.inc
   9    !----------------------------------------------------------------------
  10
  11    implicit none
  12
  13    type(iv_type), intent(in)    :: iv          ! Innovation vector.
  14    type(y_type),  intent(in)    :: re          ! Residual vector.
  15    type(y_type),  intent(inout) :: jo_grad_y   ! Grad_y(Jo)
  16    type(jo_type), intent(inout) :: jo          ! Obs cost function.
  17
  18    integer :: n, k
  19
  20    if (trace_use_dull) call da_trace_entry("da_jo_and_grady_gpseph")
  21
  22    jo % gpseph_eph = 0.0
  23
  24    do n=1, iv%info(gpseph)%nlocal
  25
  26       do k=1, iv%info(gpseph)%levels(n)
  27          if ( iv%gpseph(n)%eph(k)%qc >= obs_qc_pointer ) then
  28             jo_grad_y%gpseph(n)%eph(k) = -re%gpseph(n)%eph(k) / &
  29                ( iv%gpseph(n)%eph(k)%error * iv%gpseph(n)%eph(k)%error)
  30          endif
  31       end do
  32
  33       if (iv%info(gpseph)%proc_domain(1,n)) then
  34          do k=1, iv%info(gpseph)%levels(n)
  35             if ( iv%gpseph(n)%eph(k)%qc >= obs_qc_pointer ) then
  36                jo % gpseph_eph = jo % gpseph_eph - &
  37                    re%gpseph(n)%eph(k) * jo_grad_y%gpseph(n)%eph(k)
  38             endif
  39          end do
  40       end if
  41
  42    end do
  43
  44    jo % gpseph_eph = 0.5 * jo % gpseph_eph
  45
  46    if (trace_use_dull) call da_trace_exit("da_jo_and_grady_gpseph")
  47
  48 end subroutine da_jo_and_grady_gpseph