configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29
  30 AC_CONFIG_SRCDIR([src/amule.cpp])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_MAINTAINER_MODE
  33
  34 dnl Check host system.
  35 MULE_CHECK_SYSTEM
  36
  37 dnl Checks for programs.
  38 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  39 MULE_BACKUP([CFLAGS])
  40 MULE_BACKUP([CXXFLAGS])
  41 MULE_BACKUP([BUILD_CFLAGS])
  42 AC_PROG_CXX
  43 AC_PROG_CXXCPP
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  47 MULE_RESTORE([CFLAGS])
  48 MULE_RESTORE([CXXFLAGS])
  49 MULE_RESTORE([BUILD_CFLAGS])
  50 AC_PROG_AWK
  51 AC_PROG_EGREP
  52 AC_PROG_MAKE_SET
  53 AC_PROG_LEX
  54 AC_PROG_INSTALL
  55 AC_PROG_RANLIB
  56 AC_PROG_YACC
  57
  58 dnl Find the right ranlib, even when cross-compiling
  59 dnl And for some other tools for cross compilation
  60 AC_CHECK_TOOL(RANLIB, ranlib)
  61 AC_CHECK_TOOL(STRIP, strip)
  62 AC_CHECK_TOOL(AR, ar)
  63 AC_CHECK_TOOL(LD, ld)
  64
  65 dnl
  66 dnl Add args to configure
  67 dnl
  68 AC_ARG_ENABLE(
  69         [monolithic],
  70         [AS_HELP_STRING(
  71                 [--disable-monolithic],
  72                 [disable building of the monolithic aMule app])],
  73         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
  74
  75 AC_ARG_ENABLE(
  76         [amule-daemon],
  77         [AS_HELP_STRING(
  78                 [--enable-amule-daemon],
  79                 [compile aMule daemon version])],
  80         [AMULE_DAEMON=$enableval], [AMULE_DAEMON=no])
  81
  82 AC_ARG_ENABLE(
  83         [amulecmd],
  84         [AS_HELP_STRING(
  85                 [--enable-amulecmd],
  86                 [compile aMule command line client])],
  87         [AMULECMD=$enableval], [AMULECMD=no])
  88
  89 AC_ARG_ENABLE(
  90         [webserver],
  91         [AS_HELP_STRING(
  92                 [--enable-webserver],
  93                 [compile aMule WebServer])],
  94         [WEB=$enableval], [WEB=no])
  95
  96 AC_ARG_ENABLE(
  97         [amule-gui],
  98         [AS_HELP_STRING(
  99                 [--enable-amule-gui],
 100                 [compile aMule remote GUI (EXPERIMENTAL)])],
 101         [AMULE_GUI=$enableval], [AMULE_GUI=no])
 102
 103 AC_ARG_ENABLE(
 104         [cas],
 105         [AS_HELP_STRING(
 106                 [--enable-cas],
 107                 [compile C aMule Statistics])],
 108         [CAS=$enableval], [CAS=no])
 109
 110 AC_ARG_ENABLE(
 111         [wxcas],
 112         [AS_HELP_STRING(
 113                 [--enable-wxcas],
 114                 [compile aMule GUI Statistics])],
 115         [WXCAS=$enableval], [WXCAS=no])
 116
 117 AC_ARG_ENABLE(
 118         [ed2k],
 119         [AS_HELP_STRING(
 120                 [--disable-ed2k],
 121                 [don't compile aMule ed2k links handler])],
 122         [ED2K=$enableval], [ED2K=yes])
 123
 124 AC_ARG_ENABLE(
 125         [alc],
 126         [AS_HELP_STRING(
 127                 [--enable-alc],
 128                 [compile aMuleLinkCreator GUI version])],
 129         [ALC=$enableval], [ALC=no])
 130
 131 AC_ARG_ENABLE(
 132         [alcc],
 133         [AS_HELP_STRING(
 134                 [--enable-alcc],
 135                 [compile aMuleLinkCreator for console])],
 136         [ALCC=$enableval], [ALCC=no])
 137
 138 AC_ARG_ENABLE(
 139         [monolithic],
 140         [AS_HELP_STRING(
 141                 [--disable-monolithic],
 142                 [disable building of the monolithic aMule app])],
 143         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
 144
 145 AC_ARG_ENABLE(
 146         [upnp],
 147         [AS_HELP_STRING(
 148                 [--disable-upnp],
 149                 [do not compile UPnP code])],
 150         [ENABLE_UPNP=$enableval], [ENABLE_UPNP=yes])
 151
 152 AC_ARG_ENABLE(
 153         [xas],
 154         [AS_HELP_STRING(
 155                 [--enable-xas],
 156                 [install xas XChat2 plugin])],
 157         [XAS=$enableval], [XAS=no])
 158
 159 # Default is yes, because they're most likely compatible.
 160 # However, this is only used when cross-compiling.
 161 AC_ARG_WITH(
 162         [gnu-malloc],
 163         [AS_HELP_STRING([--without-gnu-malloc],
 164                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
 165         [gnumalloc=$withval], [gnumalloc=yes])
 166
 167
 168 # Checking for libs before all other stuff to break
 169 # configure as soon as possible in case of a missing one
 170 # to avoid losing too much time
 171
 172 # Check for zlib
 173 MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])
 174
 175 AS_IF([test x$CAS = xyes], [
 176         # Check for gd
 177         MULE_CHECK_GDLIB([2.0.0], [
 178                 CAS_DEFS="-D__GD__"
 179                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 180         ], [CAS_DEFS=])
 181         AS_IF([test -z "$CAS_DEFS"],
 182                 [MULE_WARNING(
 183                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 184                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 185                         Or this might also be that your gdlib-config has other name.
 186                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 187                         If you use compiled packages check if you have devel pack installed.
 188                         To download the latest version check http://www.boutell.com/gd for sources.])])
 189 ], [GDLIB_VERSION="not_needed"])
 190 AC_SUBST([CAS_DEFS])dnl
 191
 192
 193 AS_IF([test x$WEB = xyes],
 194         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 195                 MULE_WARNING(
 196                         [libpng >= 1.2.0 not found.
 197                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 198                 ])
 199         ], [LIBPNG_VERSION="not_needed"])
 200 AC_SUBST([AMULEWEB_DEFS])dnl
 201
 202
 203 # Check for perl File::Copy
 204 AC_MSG_CHECKING([for File::Copy])
 205 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])], [AC_MSG_ERROR([File::Copy perl module is required])])
 206
 207
 208 # Check if we need the GUI
 209 AC_MSG_CHECKING([whether we need the GUI])
 210 AS_IF([test x$MONOLITHIC = xyes], [need_gui=yes])
 211 AS_IF([test x$WXCAS = xyes], [need_gui=yes])
 212 AS_IF([test x$ALC = xyes], [need_gui=yes])
 213 AS_IF([test x$AMULE_GUI = xyes], [need_gui=yes])
 214 AS_IF([test x${need_gui:+set} != xset], [need_gui=no])
 215 AC_MSG_RESULT($need_gui)
 216
 217 # Check if we need to install skins
 218 AS_IF([test x$MONOLITHIC = xyes], [INSTALL_SKINS=yes])
 219 AS_IF([test x$AMULE_GUI = xyes], [INSTALL_SKINS=yes])
 220 AS_IF([test x${INSTALL_SKINS:+set} != xset], [INSTALL_SKINS=no])
 221
 222 # Check for GeoIP (required for IP2Country capability)
 223 MULE_CHECK_GEOIP
 224
 225 # Check for wx
 226 WX_CONFIG_OPTIONS
 227 WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 228 # Force using a static wxWidgets library if the executable is to be linked statically.
 229 AS_IF([test ${enable_static:-no} = yes], [WX_SHARED=0])
 230 # Force using a unicode build of the library
 231 WX_UNICODE=1
 232 DEBUG=$WX_DEBUG
 233 WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 234 WX_CONFIG_CHECK([2.8.0], [wxWin=1],,, [$WXCONFIG_FLAGS])
 235 if test "$wxWin" != 1; then
 236         AC_MSG_ERROR([
 237                 wxWidgets must be installed on your system but wx-config
 238                 script couldn't be found. Please check that wx-config is
 239                 in path or specified by --with-wx-config=path flag, the
 240                 directory where wxWidgets libraries are installed (returned
 241                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 242                 equivalent variable and wxWidgets version is 2.8.0 or above.
 243         ])
 244 fi
 245 WX_DETECT_STANDARD_OPTION_VALUES
 246
 247 # We also need wxBase
 248 WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 249 WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 250 WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 251 AC_SUBST([WXBASE_LIBS])
 252 AC_SUBST([WXBASE_CPPFLAGS])
 253
 254 dnl Get flags for windres
 255 AC_ARG_VAR([RC], [Resource Compiler])dnl
 256 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 257 AS_IF([test ${SYS:-unknown} = win32],
 258 [
 259         AC_CHECK_TOOL([RC], [windres], [:])
 260         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 261 ])
 262
 263
 264 # Check for libupnp
 265 AS_IF([test "${ENABLE_UPNP:-yes}" = yes], [
 266         LIBUPNP_CHECK(
 267                 [1.6.6],
 268                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 269                 [ENABLE_UPNP=disabled
 270                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 271         )
 272 ])dnl
 273
 274
 275 # Check for Crypto++
 276 MULE_CHECK_CRYPTOPP([5.1], [
 277         # Check for CryptoPP >= 5.5
 278         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 279 ], [
 280         AC_MSG_ERROR([
 281         Could not find crypto++ header file "$cryptopp_file_with_version".
 282         Please try again with --with-crypto-prefix=/my_crypto_prefix
 283         (replace /my_crypto_prefix with a valid path to your crypto++
 284         installation directory).])
 285 ])
 286
 287 dnl Checks requiring C++
 288 AC_LANG_PUSH([C++])
 289 MULE_CHECK_GLIBCXX
 290 MULE_CHECK_WX_SUPPORTS_LARGEFILE
 291
 292 # Check if the compiler is broken, wrt. exceptions.
 293 MULE_CHECK_EXCEPTIONS
 294
 295 MULE_CHECK_CXXABI
 296 AC_LANG_POP([C++])
 297
 298 # Ok, we have all needed libs, now checking for other stuff
 299 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 300
 301 # Flush standard test results for speeding cache
 302 AC_CACHE_SAVE
 303
 304 dnl -------------------------------------------------------------------------------
 305 dnl Start of autoscan stuff
 306 dnl -------------------------------------------------------------------------------
 307 # Checks for header files.
 308 AC_PATH_X
 309 AC_FUNC_ALLOCA
 310 AC_HEADER_DIRENT
 311 AC_HEADER_STDC
 312 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h  nl_types.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h errno.h signal.h])
 313 AC_HEADER_SYS_WAIT
 314
 315 # Checks for typedefs, structures, and compiler characteristics.
 316 AC_HEADER_STDBOOL
 317 AC_C_CONST
 318 AC_C_INLINE
 319 AC_TYPE_MODE_T
 320 AC_TYPE_OFF_T
 321 AC_TYPE_SIZE_T
 322 AC_HEADER_TIME
 323 AC_STRUCT_TM
 324 AC_TYPE_UID_T
 325 AC_C_VOLATILE
 326 AC_CHECK_TYPES([ptrdiff_t])
 327
 328 # Checks for library functions.
 329 AC_FUNC_CLOSEDIR_VOID
 330 AC_PROG_GCC_TRADITIONAL
 331 AC_FUNC_FORK
 332 AS_IF([test x$SYS != xwin32], [
 333         AC_FUNC_GETMNTENT
 334         AC_FUNC_LSTAT
 335         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 336 ])
 337 AC_FUNC_MEMCMP
 338 AC_FUNC_SELECT_ARGTYPES
 339 AC_FUNC_SETVBUF_REVERSED
 340 AC_TYPE_SIGNAL
 341 AC_FUNC_STAT
 342 AC_FUNC_STRFTIME
 343 AC_FUNC_STRTOD
 344 AC_FUNC_VPRINTF
 345 dnl Some other functions that worth checking deeper:
 346 dnl AC_FUNC_CLOSEDIR_VOID
 347 dnl AC_FUNC_MEMCMP
 348 dnl AC_FUNC_MMAP
 349 dnl AC_FUNC_STAT
 350 dnl AC_FUNC_STRTOD
 351 dnl AC_FUNC_SETVBUF_REVERSED
 352 dnl Anyways, do we actually USE them?
 353 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 354         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 355         ac_cv_func_malloc_0_nonnull=yes
 356         ac_cv_func_realloc_0_nonnull=yes
 357 ])
 358 AC_FUNC_MALLOC
 359 AC_FUNC_REALLOC
 360 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getpass gettimeofday inet_ntoa localeconv memmove mempcpy memset nl_langinfo pow select setlocale socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul sigaction])
 361 #-------------------------------------------------------------------------------
 362 # End of autoscan stuff
 363 #-------------------------------------------------------------------------------
 364
 365 dnl
 366 dnl autoscan has missed these ones.
 367 dnl
 368 AC_CHECK_FUNCS([mkdir getrlimit setrlimit getopt_long])
 369
 370 dnl This must be *before* MULE_CHECK_NLS
 371 AC_ARG_ENABLE([mmap],
 372         [AS_HELP_STRING([--enable-mmap], [enable using mapped memory if supported])])
 373
 374 AS_IF([test ${enable_mmap:-no} = yes], [
 375         AC_CHECK_HEADERS([sys/mman.h])
 376         AC_FUNC_MMAP
 377         AC_CHECK_FUNCS([munmap])
 378 ], [
 379         # fake the result of the test for munmap() for the gettext macros
 380         ac_cv_func_munmap=no
 381 ])
 382
 383
 384 MULE_BACKUP([CPPFLAGS])
 385 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 386 AC_FUNC_STRERROR_R
 387 MULE_RESTORE([CPPFLAGS])
 388
 389 # Look for a way to preallocate disk space for files.
 390 MULE_CHECK_FALLOCATE
 391
 392 # Checking Native Language Support
 393 dnl Sets gettext version.
 394 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 395 AM_GNU_GETTEXT_VERSION(0.11.5)
 396 MULE_CHECK_NLS
 397
 398 # Check for bfd.h (to have proper backtraces without using wxExecute)
 399 MULE_CHECK_BFD
 400 MULE_CHECK_EXECINFO
 401
 402 # Flush standard test results for speeding cache
 403 AC_CACHE_SAVE
 404
 405 # Other tests
 406 # aMule options
 407 MULE_COMPILATION_FLAGS
 408
 409 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 410 AC_MSG_CHECKING([for docdir])
 411 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 412 AC_SUBST([docdir])dnl
 413 AC_MSG_RESULT([$docdir])
 414
 415 # Try to set the SVN checkout-date
 416 AC_MSG_CHECKING([for SVNDATE])
 417 if test -f "$srcdir/.svn-revision" # SVNDATE for tarballs
 418 then
 419         svndate="rev. `cat $srcdir/.svn-revision`"
 420 elif test -d $srcdir/.svn # SVNDATE for svn
 421 then
 422         svndate="rev. `svnversion $srcdir | sed -e 's/[[0-9]][[0-9]]*:\(.*\)/\1/' -e 's/\([[0-9]][[0-9]]*\).*/\1/'`"
 423 fi
 424 AC_MSG_RESULT(${svndate:-None required})
 425 AS_IF([test -n "$svndate"], [
 426             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 427             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 428 ])
 429 AC_SUBST([SVNDATE], [$svndate])dnl
 430
 431 dnl Set up the denoiser
 432 MULE_DENOISER
 433
 434 AM_CONDITIONAL(WEB, test x$WEB = xyes)
 435 AM_CONDITIONAL(ED2K, test x$ED2K = xyes)
 436 AM_CONDITIONAL(CAS, test x$CAS = xyes)
 437 AM_CONDITIONAL(WXCAS, test x$WXCAS = xyes)
 438 AM_CONDITIONAL(ALC, test x$ALC = xyes)
 439 AM_CONDITIONAL(ALCC, test x$ALCC = xyes)
 440 AM_CONDITIONAL(AMULE_GUI, test x$AMULE_GUI = xyes)
 441 AM_CONDITIONAL(AMULE_DAEMON, test x$AMULE_DAEMON = xyes)
 442 AM_CONDITIONAL(COMPILE_CMD, test x$AMULECMD = xyes)
 443 AM_CONDITIONAL(MONOLITHIC, test x$MONOLITHIC = xyes)
 444 AM_CONDITIONAL(XAS, test x$XAS = xyes)
 445 AM_CONDITIONAL(ENABLE_UPNP, test x$ENABLE_UPNP = xyes)
 446 AM_CONDITIONAL(ENABLE_IP2COUNTRY, test x$ENABLE_IP2COUNTRY = xyes)
 447 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 448 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 449 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 450 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 451 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 452 AM_CONDITIONAL(INSTALL_SKINS, test x$INSTALL_SKINS = xyes)
 453
 454 # Check for readline library
 455 if test x$AMULECMD = xyes -o x$WEB = xyes; then
 456         VL_LIB_READLINE
 457 fi
 458
 459 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 460
 461 MULE_CHECK_CCACHE
 462
 463 dnl
 464 dnl Generate the Makefiles
 465 dnl
 466 AC_CONFIG_FILES([Makefile
 467                  docs/Makefile
 468                  docs/man/Makefile
 469                  intl/Makefile
 470                  src/Makefile
 471                  src/pixmaps/Makefile
 472                  src/pixmaps/flags_xpm/Makefile
 473                  src/libs/Makefile
 474                  src/libs/ec/Makefile
 475                  src/libs/ec/cpp/Makefile
 476                  src/libs/common/Makefile
 477                  src/utils/Makefile
 478                  src/utils/aLinkCreator/Makefile
 479                  src/utils/aLinkCreator/docs/Makefile
 480                  src/utils/aLinkCreator/src/Makefile
 481                  src/utils/cas/Makefile
 482                  src/utils/cas/docs/Makefile
 483                  src/utils/fileview/Makefile
 484                  src/utils/wxCas/Makefile
 485                  src/utils/wxCas/docs/Makefile
 486                  src/utils/wxCas/src/Makefile
 487                  src/utils/xas/Makefile
 488                  src/utils/xas/autostart-xas
 489                  src/utils/xas/docs/Makefile
 490                  src/skins/Makefile
 491                  src/webserver/Makefile
 492                  src/webserver/src/Makefile
 493                  src/webserver/default/Makefile
 494                  unittests/Makefile
 495                  unittests/muleunit/Makefile
 496                  unittests/tests/Makefile])
 497 dnl
 498 dnl autoscan has missed these, i wonder why...
 499 dnl
 500 AC_CONFIG_FILES([po/Makefile.in
 501                  Compilation.flags])
 502 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 503 AC_OUTPUT
 504
 505 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 506
 507 echo
 508 echo
 509 echo "  Configure script has finished system check."
 510 echo
 511 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 512 echo
 513 echo "  aMule enabled options:"
 514 echo
 515 echo "  **** aMule Core ****"
 516 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 517 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 518 echo "  Should aMule be compiled in debug mode?                    ${USE_DEBUG:-no}"
 519 echo "  Should aMule be compiled with profiling?                   ${USE_PROFILE:-no}"
 520 echo "  Should aMule be compiled with optimizations?               ${USE_OPTIMIZE:-no}"
 521 echo "  Should aMule be compiled with UPnP support?                ${ENABLE_UPNP:-yes}"
 522 echo "  Should aMule be compiled with IP2country support?          ${ENABLE_IP2COUNTRY:-no}"
 523 echo "  Should aMule monolithic application be built?              ${MONOLITHIC:-yes}"
 524 echo "  Should aMule daemon version be built?                      ${AMULE_DAEMON:-no}"
 525 echo "  Should aMule remote gui be built? (EXPERIMENTAL)           ${AMULE_GUI:-no}"
 526 echo "  Crypto++ library/headers style?                            ${CRYPTOPP_STYLE:-not found}"
 527
 528 echo
 529 echo "  **** aMule TextClient ****"
 530 echo "  Should aMule Command Line Client be built?                 ${AMULECMD:-no}"
 531 echo
 532 echo "  **** aMule WebServer ****"
 533 echo "  Should aMule WebServer be built?                           ${WEB:-no}"
 534 echo
 535 echo "  **** aMule ED2K Links Handler ****"
 536 echo "  Should aMule ED2K Links Handler be built?                  ${ED2K:-yes}"
 537 echo
 538 echo "  **** aMuleLinkCreator ****"
 539 echo "  Should aMuleLinkCreator GUI version (alc) be built?        ${ALC:-no}"
 540 echo "  Should aMuleLinkCreator for console (alcc) be built?       ${ALCC:-no}"
 541 echo
 542 echo "  **** aMule Statistics ****"
 543 echo "  Should C aMule Statistics (CAS) be built?                  ${CAS:-no}"
 544 echo "  Should aMule GUI Statistics (wxCas) be built?              ${WXCAS:-no}"
 545 echo "  Should xas XChat2 plugin be installed?                     ${XAS:-yes}"
 546
 547 echo
 548 echo "  **** General Libraries and Tools ****"
 549 echo "  Should ccache support be enabled?                          ${enable_ccache:-no}"
 550 echo "  Libraries aMule will use to build:"
 551 wxinfo="$WX_PORT"
 552 AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 553 AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 554 echo "                                       wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 555 echo "                                       crypto++              ${CRYPTOPP_VERSION_STRING} (${CRYPTOPP_STYLE}, in ${CRYPTOPP_PREFIX})"
 556 AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 557 AS_IF([test x${ENABLE_UPNP} = xyes], [echo "                                       libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"])
 558 if test ${enable_nls:-yes} = yes; then
 559 AS_IF([test x$USE_NLS = xno],
 560         [libintl_found="Not detected"],
 561         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 562                 [libintl_found="included"],
 563                 [libintl_found="system"])])
 564 echo "                                       libintl               $libintl_found"
 565 fi
 566 AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 567 AS_IF([test ${ENABLE_IP2COUNTRY:-no} = yes], [echo "                                       libGeoIP              ${geoip_style}"])
 568 if test x$LIBPNG_VERSION != xnot_needed; then
 569 echo "                                       libpng                ${LIBPNG_VERSION:-Not detected}"
 570 fi
 571 if test x$GDLIB_VERSION != xnot_needed; then
 572 echo "                                       libgd                 ${GDLIB_VERSION:-Not detected}"
 573 fi
 574 echo "                                       zlib                  ${ZLIB_VERSION:-Not detected}"