| blob | 3294fca828f4708161569e10031b6ec6fc153f24 |
1 # -*- Autoconf -*-
2 # This file is part of the aMule Project.
3 #
4 # Copyright (c) 2003-2011 aMule Team ( admin@amule.org / http://www.amule.org )
5 #
6 # Any parts of this program derived from the xMule, lMule or eMule project,
7 # or contributed by third-party developers are copyrighted by their
8 # respective authors.
9 #
10 # This program is free software; you can redistribute it and/or modify
11 # it under the terms of the GNU General Public License as published by
12 # the Free Software Foundation; either version 2 of the License, or
13 # (at your option) any later version.
14 #
15 # This program is distributed in the hope that it will be useful,
16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 # GNU General Public License for more details.
19 #
20 # You should have received a copy of the GNU General Public License
21 # along with this program; if not, write to the Free Software
22 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
23 #
25 m4_pattern_forbid(MULE_)dnl Check for unexpanded *MULE_* macros
26 m4_pattern_allow(AMULE_)dnl Allow the *AMULE_* names
27 m4_pattern_forbid(__mule_)dnl Check for unexpanded internal macros
30 # -------------------- #
31 # Common useful macros #
32 # -------------------- #
34 dnl MULE_APPEND(VARNAME, VALUE)
35 AC_DEFUN([MULE_APPEND], [$1="$$1 $2"])
37 dnl MULE_PREPEND(VARNAME, VALUE)
38 AC_DEFUN([MULE_PREPEND], [$1="$2 $$1"])
40 dnl MULE_ADDFLAG(FLAGTYPE, VALUE)
41 AC_DEFUN([MULE_ADDFLAG], [MULE_APPEND([MULE[]$1[]FLAGS], [$2])])
43 dnl MULE_ADDCCXXFLAG(VALUE)
44 AC_DEFUN([MULE_ADDCCXXFLAG],
45 [
46 MULE_ADDFLAG([C], [$1])
47 MULE_ADDFLAG([CXX], [$1])
48 ])
50 dnl MULE_BACKUP(VAR)
51 AC_DEFUN([MULE_BACKUP], [mule_backup_$1="$$1"])
53 dnl MULE_RESTORE(VAR)
54 AC_DEFUN([MULE_RESTORE], [$1="$mule_backup_$1"])
57 # ------------------- #
58 # Issuing diagnostics #
59 # ------------------- #
61 # -----------------------------------------------------------------------------
62 # __mule_print_final_warning(section, condition, message)
63 # -----------------------------------------------------------------------------
64 m4_define([__mule_print_final_warning],
65 [m4_divert_push($1)dnl
66 if test [$2]; then
67 cat <<_MULEEOT
69 m4_pushdef([__mule_Prefix1], [* ])dnl
70 m4_pushdef([__mule_Prefix], [ ])dnl
71 m4_foreach([__mule_Line], m4_quote(m4_split([$3], [
72 ])), [m4_text_wrap(m4_defn([__mule_Line]), __mule_Prefix, __mule_Prefix1)
73 m4_define([__mule_Prefix1], __mule_Prefix)dnl
74 ])[]dnl
75 m4_popdef([__mule_Prefix])dnl
76 m4_popdef([__mule_Prefix1])dnl
77 _MULEEOT
78 fi
79 m4_divert_pop()])
81 dnl ---------------------------------------------------------------------------
82 dnl MULE_WARNING(MESSAGE)
83 dnl
84 dnl Works like AC_MSG_WARN(), but the warning will be reproduced at the end of
85 dnl the configure run. An empty line is prepended at the final output and a
86 dnl newline is appended for free.
87 dnl ---------------------------------------------------------------------------
88 m4_ifndef([_MULE_WARNINGS],[
89 m4_define([_m4_divert(_MULE_WARNINGS)], m4_incr(_m4_divert([BODY])))])
90 m4_define([_MULE_WARNCOUNT], [0])
92 m4_divert_push(_MULE_WARNINGS)dnl
93 if test ${_mule_has_warnings:-no} = yes; then
94 echo ""
95 echo ""
96 echo " *** Warnings during configuration ***"
97 fi
98 m4_divert_pop()dnl
100 m4_define([MULE_WARNING],
101 [AC_MSG_WARN(
102 m4_pushdef([__mule_Prefix], [ ])dnl
103 m4_foreach([__mule_Line], m4_quote(m4_split([$1], [
104 ])), [
105 m4_text_wrap(m4_defn([__mule_Line]), __mule_Prefix)])[]dnl
106 m4_popdef([__mule_Prefix])dnl
107 )
108 _mule_warning_[]_MULE_WARNCOUNT[]=yes
109 _mule_has_warnings=yes
110 __mule_print_final_warning([_MULE_WARNINGS], [${_mule_warning_]_MULE_WARNCOUNT[:-no} = yes], [$1])dnl
111 m4_define([_MULE_WARNCOUNT], incr(_MULE_WARNCOUNT))])
113 dnl ---------------------------------------------------------------------------
114 dnl MULE_DEPRECATED(OLDFLAG [, NEWFLAG])
115 dnl
116 dnl Marks OLDFLAG as deprecated and produces an appropriate warning. If NEWFLAG
117 dnl is specified and is unset the value of OLDFLAG is assigned to NEWFLAG (i.e.
118 dnl if the user specified both OLDFLAG and NEWFLAG, NEWFLAG takes precedence;
119 dnl if only OLDFLAG is specified it will be redirected to NEWFLAG).
120 dnl
121 dnl There should be no AC_ARG_* for the deprecated flag, and if the old flag is
122 dnl deprecated in favour of a new one, MULE_DEPRECATED *MUST* precede the
123 dnl AC_ARG_* definition of the new flag (otherwise redirection may not work).
124 dnl ---------------------------------------------------------------------------
125 m4_define([_MULE_DEPRECATIONWARNINGS], [incr(_MULE_WARNINGS)])
126 m4_define([__mule_display_option_name], [m4_if(m4_substr([$1], 0, 1), [-],, [--])m4_bpatsubst([$1], [_], [-])])
127 m4_define([__mule_ac_option_name], [m4_bpatsubst(m4_bpatsubst(m4_bpatsubst(m4_bpatsubst([$1], [^-+], []), [-], [_]), [^disable], [enable]), [^without], [with])])
129 m4_define([MULE_DEPRECATED],
130 [if test "${__mule_ac_option_name([$1])+set}" = "set"; then
131 _mule_has_warnings=yes
132 m4_ifvaln([$2], [ if test "${__mule_ac_option_name([$2]):-unset}" = "unset"; then
133 __mule_ac_option_name([$2])=$__mule_ac_option_name([$1])
134 fi])fi
135 __mule_print_final_warning([_MULE_DEPRECATIONWARNINGS], ["${]__mule_ac_option_name([$1])[+set}" = set], __mule_display_option_name([$1])[ is now deprecated and ]m4_ifval([$2], [might be removed in the future without further notice. Please use ]__mule_display_option_name([$2])[ instead.], [not supported anymore.]))])
138 # ----------------- #
139 # Argument handling #
140 # ----------------- #
141 m4_define([__mule_arg_default], [__mule_arg_[]m4_translit([$1], [-], [_])[]_default])
142 m4_define([__mule_arg_value], [${enable_[]m4_translit([$1], [-], [_])[]:-[]__mule_arg_default([$1])[]}])
144 dnl ---------------------------------------------------------------------------
145 dnl MULE_ARG_ENABLE(FEATURE, DEFAULT-VALUE, HELP-STRING [, AUTOMAKE-CONDITIONAL])
146 dnl
147 dnl Wrapper around AC_ARG_ENABLE() that supports automatically setting up a
148 dnl conditional variable for automake, remembering default value for
149 dnl conditionals and supplying the help string based on the default value (i.e.
150 dnl it produce "--enable-FEATURE HELP-STRING" if the default is no, and
151 dnl "--disable-FEATURE HELP-STRING" if the default is yes. The default value
152 dnl *MUST* be either `yes' or `no'.
153 dnl ---------------------------------------------------------------------------
154 m4_define([MULE_ARG_ENABLE],
155 [m4_if([$2], [yes],, [m4_if([$2], [no],, [m4_fatal([Default value must be either `yes' or `no'!])])])dnl
156 m4_define(__mule_arg_default([$1]), [$2])dnl
157 AC_ARG_ENABLE([$1], [AS_HELP_STRING(m4_if([$2], [yes], [--disable-$1], [--enable-$1]), [$3])])
158 m4_ifvaln([$4], [AM_CONDITIONAL([$4], [test ]__mule_arg_value([$1])[ = yes])])])
160 dnl ---------------------------------------------------------------------------
161 dnl MULE_IS_ENABLED(FEATURE)
162 dnl
163 dnl Used in shell conditionals, tests whether the named feature is enabled or
164 dnl not, considering also the default value. FEATURE *must* have been set up
165 dnl using MULE_ARG_ENABLE().
166 dnl ---------------------------------------------------------------------------
167 m4_define([MULE_IS_ENABLED],
168 [m4_ifdef(__mule_arg_default([$1]), __mule_arg_value([$1])[ = yes], [m4_fatal([Unknown feature `$1'!])])])
170 m4_define([MULE_IS_ENABLED_ANY], [__mule_if_multi([$1], [-o])])
171 m4_define([MULE_IS_ENABLED_ALL], [__mule_if_multi([$1], [-a])])
173 dnl ---------------------------------------------------------------------------
174 dnl MULE_ENABLEVAR(FEATURE)
175 dnl
176 dnl Expands to the name of the shell variable holding the enabled/disabled
177 dnl status of FEATURE. FEATRUE *must* have been set up using MULE_ARG_ENABLE().
178 dnl ---------------------------------------------------------------------------
179 m4_define([MULE_ENABLEVAR],
180 [m4_ifdef(__mule_arg_default([$1]), [enable_[]m4_translit([$1], [-], [_])], [m4_fatal([Unknown feature `$1'!])])])
182 dnl ---------------------------------------------------------------------------
183 dnl MULE_STATUSOF(FEATURE)
184 dnl
185 dnl Expands to the value of the shell variable holding the status of FEATURE,
186 dnl considering default values. FEATURE *must* have been set up using
187 dnl MULE_ARG_ENABLE().
188 dnl ---------------------------------------------------------------------------
189 m4_define([MULE_STATUSOF],
190 [m4_ifdef(__mule_arg_default([$1]), __mule_arg_value([$1]), [m4_fatal([Unknown feature `$1'!])])])
193 # ---------------------- #
194 # Conditional processing #
195 # ---------------------- #
196 m4_define([__mule_if_multi],
197 [m4_define([__mule_if_logic], [])dnl
198 m4_foreach([__mule_condition], [$1], [__mule_if_logic MULE_IS_ENABLED(__mule_condition) ][m4_define([__mule_if_logic], [$2])])dnl
199 m4_undefine([__mule_if_logic])])
201 dnl ---------------------------------------------------------------------------
202 dnl MULE_IF_ENABLED(FEATURE, [ACTION-IF-ENABLED], [ACTION-IF-DISABLED])
203 dnl
204 dnl Basically a wrapper around AS_IF(), the test being if FEATURE is enabled.
205 dnl FEATURE must have been set up by MULE_ARG_ENABLE().
206 dnl ---------------------------------------------------------------------------
207 m4_define([MULE_IF_ENABLED],
208 [AS_IF([test MULE_IS_ENABLED([$1])], [$2], [$3])])
210 m4_define([MULE_IF_ENABLED_ALL],
211 [AS_IF([test]__mule_if_multi([$1], [-a]), [$2], [$3])])
213 m4_define([MULE_IF_ENABLED_ANY],
214 [AS_IF([test]__mule_if_multi([$1], [-o]), [$2], [$3])])
216 dnl ---------------------------------------------------------------------------
217 dnl MULE_IF(CONDITION, [IF-TRUE] [, ELIF-CONDITION, [IF-TRUE]]... [, ELSE-BRANCH])
218 dnl
219 dnl Works like AS_IF(), but allows elif-branches too.
220 dnl ---------------------------------------------------------------------------
221 m4_define([__mule_if_helper],
222 [m4_if( [$#], 0,,
223 [$#], 1, [m4_ifvaln([$1], [m4_n([else]) $1])],
224 [m4_n([elif $1; then]) m4_ifvaln([$2], [$2], :)])dnl
225 m4_if(m4_eval([$# > 2]), 1, [$0(m4_shiftn(2, $@))])])
227 m4_define([MULE_IF],
228 [m4_if( [$#], 0,,
229 [$#], 1,,
230 [m4_n([if $1; then]) m4_ifval([$2],[$2], :)
231 m4_if(m4_eval([$# > 2]), 1, [__mule_if_helper(m4_shiftn(2, $@))])m4_n([fi])])])
234 # ----------------------- #
235 # Other high-level macros #
236 # ----------------------- #
238 dnl ---------------------------------------------------------------------------
239 dnl MULE_CHECK_SYSTEM
240 dnl
241 dnl Checks host system type, and sets system-specific flags accordingly.
242 dnl Sets $SYS to the name of the host os.
243 dnl ---------------------------------------------------------------------------
244 AC_DEFUN([MULE_CHECK_SYSTEM],
245 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
247 case "${host_os}" in
248 darwin*)
249 SYS=darwin
250 MULECPPFLAGS="-no-cpp-precomp -D_INTL_REDIRECT_MACROS -DNOPCH";
251 MULELDFLAGS="-bind_at_load"
252 touch src/Scanner.cpp
253 ;;
254 openbsd*)
255 SYS=openbsd
256 LIBS="$LIBS -L/usr/local/lib"
257 MULECPPFLAGS="-D__OPENBSD__"
258 ;;
259 *cygwin* | *mingw32*)
260 SYS=win32
261 MULECPPFLAGS="-DNOMINMAX"
262 ;;
263 solaris*)
264 SYS=solaris
265 RESOLV_LIB="-lresolv -lnsl"
266 LIBS="$LIBS -lrt"
267 ;;
268 *netbsd*)
269 SYS=netbsd
270 # Now this is against autoconf recommendation that configure should not modify CPPFLAGS and LDFLAGS
271 # However, these values in NetBSD are required even to run the tests, and this is the easiest way to do it.
272 # Still, we prepend them, instead of adding, so the user may override them.
273 MULE_PREPEND([CPPFLAGS], [-I/usr/pkg/include])
274 MULE_PREPEND([LDFLAGS], [-R/usr/pkg/lib -L/usr/pkg/lib])
275 ;;
276 *irix*)
277 SYS=irix
278 MULECPPFLAGS="-D__IRIX__"
279 ;;
280 *)
281 SYS=unknown
282 ;;
283 esac
285 # -lpthread is needed by Debian but FreeBSD < 5 doesn't support it
286 AS_IF([test ${SYS:-unknown} != win32],
287 [
288 AC_MSG_CHECKING([if this is a FreeBSD 4 or earlier system])
289 AS_IF([test x"`uname -s`" = xFreeBSD && test 0`uname -r | cut -c 1` -lt 5],
290 [
291 MULE_ADDFLAG([LD], [-pthread])
292 AC_MSG_RESULT(yes)
293 ], [
294 MULE_ADDFLAG([LD], [-lpthread])
295 AC_MSG_RESULT(no)
296 ])
297 ])
299 AC_SUBST([RESOLV_LIB])dnl
300 AC_SUBST([MULECPPFLAGS])dnl
301 AC_SUBST([MULECFLAGS])dnl
302 AC_SUBST([MULECXXFLAGS])dnl
303 AC_SUBST([MULELDFLAGS])dnl
304 AC_SUBST([MULERCFLAGS])dnl
305 ])
307 dnl ---------------------------------------------------------------------------
308 dnl MULE_COMPILATION_FLAGS
309 dnl
310 dnl Checks type of compilation requested by user, and sets various flags
311 dnl accordingly.
312 dnl ---------------------------------------------------------------------------
313 AC_DEFUN([MULE_COMPILATION_FLAGS],
314 [AC_REQUIRE([MULE_CHECK_GLIBCXX])dnl
316 MULE_ARG_ENABLE([debug], [yes], [disable additional debugging output])
317 MULE_ARG_ENABLE([profile], [no], [enable code profiling])
318 MULE_ARG_ENABLE([optimize], [no], [enable code optimization])
320 MULE_IF_ENABLED([debug],
321 [
322 MULE_ADDFLAG([CPP], [-D__DEBUG__])
323 MULE_ADDCCXXFLAG([-g])
324 AS_IF([test ${GCC:-no} = yes], [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef -ggdb -fno-inline -fmessage-length=0])])
325 AS_IF([test ${SYS:-unknown} = win32], [MULE_ADDFLAG([RC], [-D__DEBUG__])])
326 ], [
327 AS_IF([test ${GCC:-no} = yes], [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef])])
328 ])
330 MULE_IF_ENABLED([profile],
331 [
332 MULE_ADDCCXXFLAG([-pg])
333 MULE_ADDFLAG([LD], [-pg])
334 ])
336 MULE_IF_ENABLED([optimize], [MULE_ADDCCXXFLAG([-O2])])
338 MULE_ADDFLAG([CPP], [-DUSE_WX_EXTENSIONS])
339 ])
341 dnl ---------------------------------------------------------------------------
342 dnl MULE_CHECK_GLIBCXX
343 dnl
344 dnl Checks whether we use the GNU C++ Library.
345 dnl ---------------------------------------------------------------------------
346 AC_DEFUN([MULE_CHECK_GLIBCXX],
347 [dnl
348 AC_REQUIRE([AC_PROG_EGREP])dnl
349 AC_REQUIRE([AC_PROG_CXXCPP])dnl
350 AC_LANG_ASSERT([C++])dnl
352 AC_MSG_CHECKING([if we're using the GNU C++ library])
353 AC_PREPROC_IFELSE([
354 AC_LANG_SOURCE([[
355 #include <string>
356 #ifndef __GLIBCXX__
357 #error Non-GNU C++ library found.
358 #endif
359 ]])
360 ], [GLIBCXX=yes], [GLIBCXX=no])
361 AC_MSG_RESULT([$GLIBCXX])
362 ])
364 dnl ---------------------------------------------------------------------------
365 dnl MULE_CHECK_WX_SUPPORTS_LARGEFILE
366 dnl
367 dnl Test that wxWidgets is built with support for large-files. If not
368 dnl configure is terminated.
369 dnl ---------------------------------------------------------------------------
370 AC_DEFUN([MULE_CHECK_WX_SUPPORTS_LARGEFILE],
371 [AC_LANG_ASSERT([C++])dnl
373 dnl Backup current flags and setup flags for testing
374 MULE_BACKUP([CPPFLAGS])
375 MULE_APPEND([CPPFLAGS], [$WX_CPPFLAGS])
377 AC_MSG_CHECKING([that wxWidgets has support for large files])
378 AC_PREPROC_IFELSE([
379 AC_LANG_SOURCE([[
380 #include <wx/wx.h>
381 #include <wx/filefn.h>
382 #ifndef wxHAS_LARGE_FILES
383 #error No LargeFile support!
384 #endif
385 ]])
386 ], [
387 AC_MSG_RESULT([yes])
388 ], [
389 AC_MSG_RESULT([no])
390 AC_MSG_ERROR([
391 Support for large files in wxWidgets is required by aMule.
392 To continue you must recompile wxWidgets with support for
393 large files enabled.])
394 ])
396 dnl Restore backup'd flags
397 MULE_RESTORE([CPPFLAGS])
398 ])
401 dnl --------------------------------------------------------------------------
402 dnl MULE_CHECK_CCACHE
403 dnl
404 dnl Checks if ccache is requested and available, and makes use of it
405 dnl --------------------------------------------------------------------------
406 AC_DEFUN([MULE_CHECK_CCACHE],
407 [
408 MULE_ARG_ENABLE([ccache], [no], [enable ccache support for fast recompilation])
410 AC_ARG_WITH([ccache-prefix],
411 [AS_HELP_STRING([--with-ccache-prefix=PREFIX], [prefix where ccache is installed])])
413 AC_MSG_CHECKING([whether ccache support should be added])
414 AC_MSG_RESULT([MULE_STATUSOF([ccache])])
416 MULE_IF_ENABLED([ccache], [
417 AC_MSG_CHECKING([for ccache presence])
418 AS_IF([test -z "$with_ccache_prefix"], [
419 ccache_full=`which ccache`
420 with_ccache_prefix=`dirname ${ccache_full}`
421 ])
422 AS_IF([$with_ccache_prefix/ccache -V >/dev/null 2>&1], [
423 CC="$with_ccache_prefix/ccache $CC"
424 CXX="$with_ccache_prefix/ccache $CXX"
425 BUILD_CC="$with_ccache_prefix/ccache $BUILD_CC"
426 ], [MULE_ENABLEVAR([ccache])=no])
427 AC_MSG_RESULT([MULE_STATUSOF([ccache])])
428 ])
429 ])
432 dnl ----------------------------------------------------
433 dnl MULE_CHECK_BFD
434 dnl check if bfd.h is on the system and usable
435 dnl ----------------------------------------------------
436 AC_DEFUN([MULE_CHECK_BFD],
437 [AC_REQUIRE([MULE_CHECK_NLS])dnl
439 AC_MSG_CHECKING([for bfd])
440 result=no
441 for bfd_ldadd in "" "${LIBINTL}" "-ldl" "-ldl ${LIBINTL}"; do
442 MULE_BACKUP([LIBS])
443 MULE_BACKUP([LDFLAGS])
444 MULE_PREPEND([LIBS], [-lbfd -liberty ${bfd_ldadd} ${ZLIB_LIBS}])
445 MULE_APPEND([LDFLAGS], [${ZLIB_LDFLAGS}])
446 AC_LINK_IFELSE([
447 AC_LANG_PROGRAM([[
448 #include <ansidecl.h>
449 #include <bfd.h>
450 ]], [[
451 char *dummy = bfd_errmsg(bfd_get_error());
452 ]])
453 ], [
454 result=yes
455 BFD_CPPFLAGS="-DHAVE_BFD"
456 BFD_LIBS="-lbfd -liberty ${bfd_ldadd}"
457 MULE_RESTORE([LIBS])
458 MULE_RESTORE([LDFLAGS])
459 break
460 ])
461 MULE_RESTORE([LIBS])
462 MULE_RESTORE([LDFLAGS])
463 done
465 AC_MSG_RESULT([$result])
467 AS_IF([test $result = no],
468 [MULE_WARNING([bfd.h not found or unusable, please install binutils development package if you are a developer or want to help testing aMule])])
470 AC_SUBST([BFD_CPPFLAGS])dnl
471 AC_SUBST([BFD_LIBS])dnl
472 ])
475 dnl ----------------------------------------------------
476 dnl MULE_CHECK_FLEX_EXTENDED
477 dnl check if flex can produce header files
478 dnl ----------------------------------------------------
479 AC_DEFUN([MULE_CHECK_FLEX_EXTENDED],
480 [
481 AC_MSG_CHECKING([for extended flex capabilities])
483 extended_flex=`flex --help | grep header-file`
484 AS_IF([test -n "$extended_flex"], [HAVE_FLEX_EXTENDED=yes], [HAVE_FLEX_EXTENDED=no])
485 AC_MSG_RESULT($HAVE_FLEX_EXTENDED)
487 AS_IF([test $HAVE_FLEX_EXTENDED = no], [AC_MSG_NOTICE([Your flex version doesn't support --header-file flag. This is not critical, but an upgrade is recommended])])
488 ])
491 dnl ----------------------------------------------------
492 dnl MULE_CHECK_EXCEPTIONS
493 dnl Checks for broken exception-handling. This is needed
494 dnl because exception handling is broken for some archs/
495 dnl compilers.
496 dnl ----------------------------------------------------
497 AC_DEFUN([MULE_CHECK_EXCEPTIONS],
498 [AC_LANG_ASSERT([C++])dnl
500 AC_MSG_CHECKING([for exception-handling])
501 AC_RUN_IFELSE([
502 AC_LANG_PROGRAM(, [[
503 try {
504 throw 1;
505 } catch (int) {
506 return 0;
507 }
508 return 1;
509 ]])
510 ], [
511 AC_MSG_RESULT([yes])
512 ], [
513 AC_MSG_RESULT([no])
514 AC_MSG_ERROR([Exception handling does not work. Broken compiler?])
515 ], [
516 AC_MSG_RESULT([undeterminable])
517 MULE_WARNING(
518 [Cross-compilation detected, so exception handling cannot be tested.
519 Note that broken exception handling in your compiler may lead to unexpected crashes.])
520 ])
521 ])
524 dnl ---------------------------------------------------------------------------
525 dnl MULE_CHECK_CXXABI
526 dnl
527 dnl This function will test the header <cxxabi.h> and abi::__cxa_demangle()
528 dnl ---------------------------------------------------------------------------
529 AC_DEFUN([MULE_CHECK_CXXABI],
530 [AC_LANG_ASSERT([C++])dnl
532 AC_MSG_CHECKING([for <cxxabi.h> and __cxa_demangle()])
533 AC_LINK_IFELSE([
534 AC_LANG_PROGRAM([[
535 #include <cxxabi.h>
536 ]], [[
537 int status;
538 char * demangled = abi::__cxa_demangle("", 0, 0, &status);
539 std::type_info *ti = abi::__cxa_current_exception_type();
540 ]])
541 ], [
542 AH_TEMPLATE([HAVE_CXXABI], [Define to 1 if you have the <cxxabi.h> header which declares abi::__cxa_demangle()])
543 AC_DEFINE([HAVE_CXXABI])
544 AC_MSG_RESULT([yes])
545 ], [
546 AC_MSG_RESULT([no])
547 ])
548 ])
551 dnl ---------------------------------------------------------------------------
552 dnl MULE_CHECK_EXECINFO
553 dnl
554 dnl This function will test the header <execinfo.h> and backtrace()
555 dnl ---------------------------------------------------------------------------
556 AC_DEFUN([MULE_CHECK_EXECINFO],
557 [
558 AC_MSG_CHECKING([for <execinfo.h> and backtrace()])
559 AC_LINK_IFELSE([
560 AC_LANG_PROGRAM([[
561 #include <execinfo.h>
562 ]], [[
563 void *bt[1];
564 int n = backtrace(&bt, 1);
565 const char **bt_syms = backtrace_symbols(bt, n);
566 ]])
567 ], [
568 AH_TEMPLATE([HAVE_EXECINFO], [Define to 1 if you have the <execinfo.h> header which declares backtrace()])
569 AC_DEFINE([HAVE_EXECINFO])
570 AC_MSG_RESULT([yes])
571 ], [
572 AC_MSG_RESULT([no])
573 ])
574 ])
576 dnl ---------------------------------------------------------------------------
577 dnl MULE_CHECK_MMAP
578 dnl
579 dnl Checks for mmap() and makes use of it when found.
580 dnl ---------------------------------------------------------------------------
581 AC_DEFUN([MULE_CHECK_MMAP],
582 [
583 MULE_ARG_ENABLE([mmap], [no], [enable using mapped memory if supported])
585 MULE_IF_ENABLED([mmap], [
586 AC_CHECK_HEADERS([sys/mman.h])
587 AC_FUNC_MMAP
588 AC_CHECK_FUNCS([munmap sysconf])
589 AS_IF([test $ac_cv_func_sysconf = yes], [
590 AC_MSG_CHECKING([for pagesize constant for sysconf])
591 AC_LINK_IFELSE([
592 AC_LANG_PROGRAM([[
593 #include <unistd.h>
594 ]], [[
595 return sysconf(_SC_PAGESIZE);
596 ]])
597 ], [
598 AC_MSG_RESULT([_SC_PAGESIZE])
599 AC_DEFINE([HAVE__SC_PAGESIZE], [1], [Define to 1 if you have the _SC_PAGESIZE constant in <unistd.h>])
600 ], [
601 AC_LINK_IFELSE([
602 AC_LANG_PROGRAM([[
603 #include <unistd.h>
604 ]], [[
605 return sysconf(_SC_PAGE_SIZE);
606 ]])
607 ], [
608 AC_MSG_RESULT([_SC_PAGE_SIZE])
609 AC_DEFINE([HAVE__SC_PAGE_SIZE], [1], [Define to 1 if you have the _SC_PAGE_SIZE constant in <unistd.h>, but not _SC_PAGESIZE])
610 ], [
611 AC_MSG_RESULT([none])
612 ])
613 ])
614 ])
615 ], [
616 # fake the result of the test for munmap() for the gettext macros
617 ac_cv_func_munmap=no
618 ])
619 ])
622 dnl ---------------------------------------------------------------------------
623 dnl MULE_DENOISER
624 dnl
625 dnl Test for denoising level and add denoiser commands to config.status
626 dnl ---------------------------------------------------------------------------
627 AC_DEFUN([MULE_DENOISER],
628 [
629 AC_ARG_WITH([denoise-level],
630 [AS_HELP_STRING([--with-denoise-level=<level>], [Specifies denoising level (0-4):])
631 AS_HELP_STRING([], [0 - Do nothing])
632 AS_HELP_STRING([], [4 - Suppress all normal output])
633 AS_HELP_STRING([], [(for more information see src/utils/scripts/denoiser.rules)])
634 ])
636 AC_MSG_CHECKING([denoising level])
637 AS_IF([test ${with_denoise_level:-5} = yes], [with_denoise_level=5])
638 AS_IF([test ${with_denoise_level:-5} = no], [with_denoise_level=0])
639 AS_IF([test ${with_denoise_level:-5} -gt 4],
640 [AS_IF([test "${svndate:+set}" = "set"], [with_denoise_level=0], [with_denoise_level=4])])
641 AC_MSG_RESULT([$with_denoise_level])
643 AC_CONFIG_COMMANDS([denoiser], [[if test $denoiserlevel -gt 0; then
644 if test ! -d src/utils/scripts; then mkdir -p src/utils/scripts; fi
645 sed -e "1{x;s/.*/1/;x;};/^[ ]*\$/d;/^#if /{/level.*$denoiserlevel/{x;s/^/1/;x;b0;};x;s/^/0/;x;:0;d;};/^#else/{x;/^1/{s/1/0/;b1;};s/0/1/;:1;x;d;};/^#endif/{x;s/.//;x;d;};/^[ ]*#/d;x;/^1/{x;b;};x;d" \
646 $srcdir/src/utils/scripts/denoiser.rules > src/utils/scripts/denoiser.sed
647 for i in `find . -name 'Makefile' -print`; do
648 if test -n "`head -n 1 $i | grep '^#'`"; then
649 sed -f src/utils/scripts/denoiser.sed $i > $i.tmp && mv $i.tmp $i
650 fi
651 done
652 fi]], [denoiserlevel=$with_denoise_level])
653 ])