configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2011 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  30
  31 AC_PREREQ(2.62)
  32
  33 # autoconf 2.70 introduced some incompatibilities that will make the build fail
  34 # As a "workaround" reject 2.70 and above for now.
  35 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1],, [m4_fatal([autoconf ]m4_defn([AC_AUTOCONF_VERSION])[ is known to not work with aMule. Please use 2.69 instead.])])
  36
  37 AC_CONFIG_SRCDIR([src/amule.cpp])
  38 AC_CONFIG_HEADERS([config.h])
  39 AC_CONFIG_MACRO_DIR([m4])
  40 AM_MAINTAINER_MODE
  41
  42 dnl Check host system.
  43 MULE_CHECK_SYSTEM
  44
  45 dnl Checks for programs.
  46 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  47 MULE_BACKUP([CFLAGS])
  48 MULE_BACKUP([CXXFLAGS])
  49 MULE_BACKUP([BUILD_CFLAGS])
  50 AC_PROG_CXX
  51 AC_PROG_CXXCPP
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  55 MULE_RESTORE([CFLAGS])
  56 MULE_RESTORE([CXXFLAGS])
  57 MULE_RESTORE([BUILD_CFLAGS])
  58 AC_PROG_AWK
  59 AC_PROG_EGREP
  60 AC_PROG_MAKE_SET
  61 AC_PROG_INSTALL
  62 AC_PROG_RANLIB
  63 AC_PROG_SED
  64
  65 dnl Find the right ranlib, even when cross-compiling
  66 dnl And for some other tools for cross compilation
  67 AC_CHECK_TOOL(RANLIB, ranlib)
  68 AC_CHECK_TOOL(STRIP, strip)
  69 AC_CHECK_TOOL(AR, ar)
  70 AC_CHECK_TOOL(LD, ld)
  71
  72 dnl Selectable components
  73 MULE_ARG_ENABLE([monolithic],   [yes],  [disable building of the monolithic aMule app], [MONOLITHIC])
  74 MULE_ARG_ENABLE([amule-daemon], [no],   [compile aMule daemon version], [AMULE_DAEMON])
  75 MULE_ARG_ENABLE([amulecmd],     [no],   [compile aMule command line client], [COMPILE_CMD])
  76 MULE_ARG_ENABLE([webserver],    [no],   [compile aMule WebServer], [WEB])
  77 MULE_ARG_ENABLE([amule-gui],    [no],   [compile aMule remote GUI], [AMULE_GUI])
  78 MULE_ARG_ENABLE([cas],          [no],   [compile C aMule Statistics], [CAS])
  79 MULE_ARG_ENABLE([wxcas],        [no],   [compile aMule GUI Statistics], [WXCAS])
  80 MULE_ARG_ENABLE([ed2k],         [yes],  [don't compile aMule ed2k links handler], [ED2K])
  81 MULE_ARG_ENABLE([alc],          [no],   [compile aMuleLinkCreator GUI version], [ALC])
  82 MULE_ARG_ENABLE([alcc],         [no],   [compile aMuleLinkCreator for console], [ALCC])
  83 MULE_ARG_ENABLE([xas],          [no],   [install xas XChat2 plugin], [XAS])
  84 MULE_ARG_ENABLE([fileview],     [no],   [compile aMule file viewer for console], [FILEVIEW])
  85 MULE_ARG_ENABLE([plasmamule],   [no],   [compile aMule plasma applet and engine])
  86
  87 # Run all the tests with static linkage if we want a statically linked binary
  88 MULE_ARG_ENABLE([static], [no], [produce a statically linked executable])
  89 MULE_IF_ENABLED([static], [MULE_APPEND([LDFLAGS], [-static])])
  90
  91 KDE_CONFIG_OPTIONS
  92 QT_CONFIG_OPTIONS
  93
  94 # Default is yes, because they're most likely compatible.
  95 # However, this is only used when cross-compiling.
  96 AC_ARG_WITH(
  97         [gnu-malloc],
  98         [AS_HELP_STRING([--without-gnu-malloc],
  99                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
 100         [gnumalloc=$withval], [gnumalloc=yes])
 101
 102
 103 # Checking for libs before all other stuff to break
 104 # configure as soon as possible in case of a missing one
 105 # to avoid losing too much time
 106
 107 # Check for gd
 108 MULE_IF_ENABLED([cas], [
 109         MULE_CHECK_GDLIB([2.0.0], [
 110                 CAS_DEFS="-D__GD__"
 111                 GDLIB_LIBS="-lgd"
 112         ], [CAS_DEFS=])
 113         AS_IF([test -z "$CAS_DEFS"],
 114                 [MULE_WARNING(
 115                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 116                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 117                         Or this might also be that your gdlib-config has other name.
 118                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 119                         If you use compiled packages check if you have devel pack installed.
 120                         To download the latest version check http://www.boutell.com/gd for sources.])])
 121 ])
 122 AC_SUBST([CAS_DEFS])dnl
 123
 124 dnl Tests explicitly requiring C. They test features of the C compiler.
 125 AC_HEADER_STDBOOL
 126 AC_C_CONST
 127 AC_C_INLINE
 128 AC_C_VOLATILE
 129
 130 dnl Use C++ for all other tests, since we use C++ to actually compile the
 131 dnl sources.  There might be differences between the compilers, thus if
 132 dnl something works in C it doesn't automatically mean it also works in C++.
 133 dnl
 134 dnl The only exception is cas which is written in pure C.
 135 AC_LANG_PUSH([C++])
 136
 137
 138 # Check for zlib
 139 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 140         [MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])])
 141
 142
 143 # Check for libpng
 144 MULE_IF_ENABLED([webserver],
 145         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 146                 MULE_WARNING(
 147                         [libpng >= 1.2.0 not found.
 148                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 149                 ])
 150         ])
 151 AC_SUBST([AMULEWEB_DEFS])dnl
 152
 153
 154 # Check for GeoIP (required for IP2Country capability)
 155 MULE_IF_ENABLED_ANY([monolithic, amule-gui], [MULE_CHECK_GEOIP])
 156
 157
 158 # Check for wx
 159 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview],
 160         [WX_CONFIG_OPTIONS
 161         WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 162         # Force using a static wxWidgets library if the executable is to be linked statically.
 163         MULE_IF_ENABLED([static], [WX_SHARED=0])
 164         # Force using a unicode build of the library
 165         MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, fileview], [WX_UNICODE=1])
 166         DEBUG=$WX_DEBUG
 167         WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 168         WX_CONFIG_CHECK([2.8.12], [wxWin=1],,, [$WXCONFIG_FLAGS])
 169         AS_IF([test "$wxWin" != 1],
 170                 [AC_MSG_ERROR([
 171                 wxWidgets must be installed on your system but wx-config
 172                 script couldn't be found. Please check that wx-config is
 173                 in path or specified by --with-wx-config=path flag, the
 174                 directory where wxWidgets libraries are installed (returned
 175                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 176                 equivalent variable and wxWidgets version is 2.8.12 or above.
 177                 ])]
 178         )
 179         AS_IF([test "${WX_VERSION_FULL}" = "2.9.0"], [AC_MSG_ERROR([
 180                 This version of wxWidgets is known to not work with aMule.
 181                 Please upgrade to a newer version.]
 182                 )]
 183         )
 184         WX_DETECT_STANDARD_OPTION_VALUES
 185
 186         # We also need wxBase
 187         WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 188         WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 189         WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 190
 191         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 192 ])
 193 AC_SUBST([WXBASE_LIBS])dnl
 194 AC_SUBST([WXBASE_CPPFLAGS])dnl
 195
 196 MULE_IF_ENABLED_ANY([monolithic, amule-gui, wxcas, alc],
 197 [AS_IF([test "${WX_PORT}" = base],
 198         [AC_MSG_ERROR([
 199                 The selected components need a wxWidgets library with GUI,
 200                 but your installation is base-only.  Please install a GUI
 201                 enabled version of wxWidgets and then retry.
 202         ])]
 203 )])
 204
 205
 206 dnl Resource compiler for W32
 207 AC_ARG_VAR([RC], [Resource Compiler])dnl
 208 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 209 AS_IF([test ${SYS:-unknown} = win32], [AC_CHECK_TOOL([RC], [windres], [:])])
 210
 211
 212 # Check for libupnp
 213 MULE_ARG_ENABLE([upnp], [yes], [do not compile UPnP code])
 214 MULE_IF_ENABLED_ANY([monolithic, amule-daemon],, [MULE_ENABLEVAR([upnp])=no])
 215 MULE_IF_ENABLED([upnp], [
 216         LIBUPNP_CHECK(
 217                 [1.6.6],
 218                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 219                 [MULE_ENABLEVAR([upnp])=disabled
 220                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 221         )
 222 ])dnl
 223
 224
 225 # Check for Crypto++ (requires C++)
 226 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 227 # Check for CryptoPP >= 5.5
 228 [MULE_CHECK_CRYPTOPP([5.5], [
 229         MULE_APPEND([CRYPTOPP_CPPFLAGS])
 230 ], [
 231         AC_MSG_ERROR([
 232         Could not find crypto++ installation or sources.
 233         Please try again with --with-crypto-prefix=/my_crypto_prefix
 234         (replace /my_crypto_prefix with a valid path to your crypto++
 235         installation or source directory).])
 236 ])])
 237
 238
 239 MULE_COMPILATION_FLAGS
 240
 241
 242 dnl Checks explicitly requiring C++
 243 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, ed2k, alc, alcc, wxcas, fileview],
 244 [
 245 dnl MULE_CHECK_GLIBCXX
 246 MULE_CHECK_STRICT_ALIASING
 247 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, alc, alcc], [MULE_CHECK_WX_SUPPORTS_LARGEFILE])
 248
 249 # Check if the compiler is broken, wrt. exceptions.
 250 MULE_CHECK_EXCEPTIONS
 251
 252 MULE_CHECK_CXXABI
 253
 254 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver], [MULE_CHECK_BOOST([1.47])])
 255 ])
 256
 257 # Ok, we have all needed libs, now checking for other stuff
 258
 259
 260 # Checks for header files.
 261 AC_FUNC_ALLOCA
 262 AC_HEADER_DIRENT
 263 AC_HEADER_STDC
 264 AC_CHECK_HEADERS([argz.h arpa/inet.h errno.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h nl_types.h signal.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h])
 265 AC_HEADER_SYS_WAIT
 266
 267
 268 # Checks for typedefs, structures, and compiler characteristics.
 269 AC_TYPE_MODE_T
 270 AC_TYPE_OFF_T
 271 AC_TYPE_SIZE_T
 272 AC_HEADER_TIME
 273 AC_STRUCT_TM
 274 AC_TYPE_UID_T
 275 AC_CHECK_TYPES([ptrdiff_t])
 276
 277
 278 # Checks for library functions.
 279 AC_FUNC_CLOSEDIR_VOID
 280 AC_PROG_GCC_TRADITIONAL
 281 AC_FUNC_FORK
 282 AS_IF([test x$SYS != xwin32], [
 283         AC_FUNC_GETMNTENT
 284         AC_FUNC_LSTAT
 285         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 286 ])
 287 AC_FUNC_MEMCMP
 288 AC_FUNC_SELECT_ARGTYPES
 289 AC_FUNC_SETVBUF_REVERSED
 290 AC_TYPE_SIGNAL
 291 AC_FUNC_STAT
 292 AC_FUNC_STRFTIME
 293 AC_FUNC_STRTOD
 294 AC_FUNC_VPRINTF
 295 dnl Some other functions that worth checking deeper:
 296 dnl AC_FUNC_CLOSEDIR_VOID
 297 dnl AC_FUNC_MEMCMP
 298 dnl AC_FUNC_MMAP
 299 dnl AC_FUNC_STAT
 300 dnl AC_FUNC_STRTOD
 301 dnl AC_FUNC_SETVBUF_REVERSED
 302 dnl Anyways, do we actually USE them?
 303 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 304         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 305         ac_cv_func_malloc_0_nonnull=yes
 306         ac_cv_func_realloc_0_nonnull=yes
 307 ])
 308 AC_FUNC_MALLOC
 309 AC_FUNC_REALLOC
 310 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getopt_long getpass getrlimit gettimeofday inet_ntoa localeconv memmove mempcpy memset mkdir nl_langinfo pow select setlocale setrlimit sigaction socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul])
 311
 312
 313 dnl This must be *before* MULE_CHECK_NLS
 314 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_MMAP])
 315
 316
 317 # Look for a way to preallocate disk space for files.
 318 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_FALLOCATE])
 319
 320
 321 dnl Use the C compiler for the gettext library checks
 322 AC_LANG_POP([C++])
 323 # Checking Native Language Support
 324 dnl Sets gettext version.
 325 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.ac!
 326 AM_GNU_GETTEXT_VERSION(0.11.5)
 327 MULE_CHECK_NLS
 328 AS_IF([test x$USE_INCLUDED_LIBINTL = xyes], [AC_CONFIG_COMMANDS([intl], [[
 329         test -d intl || mkdir intl
 330         test -f intl/plural.c || cp "$srcdir"/intl/plural.c intl/
 331         touch intl/plural.c
 332 ]])])
 333 AC_LANG_PUSH([C++])
 334
 335
 336 # Check for bfd.h (to have proper backtraces without using wxExecute)
 337 dnl This must be *after* MULE_CHECK_NLS
 338 MULE_CHECK_BFD
 339 MULE_CHECK_EXECINFO
 340
 341
 342 # aMule plasma widget
 343 MULE_IF_ENABLED([plasmamule], [PLASMAMULE_CHECKS])
 344
 345
 346 # Check for readline library
 347 MULE_IF_ENABLED_ANY([amulecmd, webserver], [VL_LIB_READLINE])
 348
 349
 350 dnl Tests that should be run in C mode. These tests either test features of the
 351 dnl C compiler or their results will be used in C sources only.
 352 AC_LANG_POP([C++])
 353
 354 # Check for strerror_r
 355 MULE_BACKUP([CPPFLAGS])
 356 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 357 AC_FUNC_STRERROR_R
 358 MULE_RESTORE([CPPFLAGS])
 359
 360
 361 # Other tests
 362
 363 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 364 AC_MSG_CHECKING([for docdir])
 365 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 366 AC_SUBST([docdir])dnl
 367 AC_MSG_RESULT([$docdir])
 368
 369
 370 # Try to set the SVN checkout-date
 371 AC_MSG_CHECKING([for SVNDATE])
 372 modified=
 373 MULE_IF(
 374 dnl SVNDATE for tarballs
 375 [test -f "$srcdir/.svn-revision"],
 376         [svndate="rev. `cat $srcdir/.svn-revision`"],
 377
 378 dnl SVNDATE for Subversion checkouts
 379 [test -d "$srcdir"/.svn],
 380         [svndate="rev. `svnversion "$srcdir" | ${SED} -e 'h;s/[[0-9]][[0-9]]*:\(.*\)/\1/;s/\([[0-9]][[0-9]]*\).*/\1/;x;/.*M.*/{x;s/$/+/;b;};x'`"],
 381
 382 dnl SVNDATE for git/git-svn clones
 383 [test -d "$srcdir"/.git],
 384 [
 385         git_revision=`git --git-dir="$srcdir"/.git log --max-count=1 --pretty='tformat:%h'`
 386         if test -n "`git --git-dir="$srcdir"/.git --work-tree="$srcdir" status --porcelain --untracked-files=no`" ; then
 387                 modified="+"
 388         fi
 389         if test -f $srcdir/.git/svn/.metadata ; then
 390                 git_sha=`git --git-dir="$srcdir"/.git log --max-count=1 --pretty='tformat:%H'`
 391                 svndate=`git --git-dir="$srcdir"/.git rev-list ${git_sha} | while read sha; do
 392                         svn_revision=\`git --git-dir="$srcdir"/.git svn find-rev \${sha}\`
 393                         if test -n "\${svn_revision}" ; then
 394                                 if test \${sha} = ${git_sha} ; then
 395                                         echo "rev. \${svn_revision}${modified}"
 396                                 else
 397                                         echo "rev. \${svn_revision}+g${git_revision}${modified}"
 398                                 fi
 399                                 break
 400                         fi
 401                 done`
 402         else
 403                 svndate="rev. g${git_revision}${modified}"
 404         fi
 405 ],
 406
 407 dnl SVNDATE for mercurial/hgsubversion clones
 408 [test -d "$srcdir"/.hg],
 409 [
 410         hg_revision=`hg --cwd "$srcdir" identify --id`
 411         hg_revid=${hg_revision%+}
 412         if test ${hg_revision} != ${hg_revid} ; then
 413                 modified="+"
 414         fi
 415         if test -f "$srcdir"/.hg/svn/uuid ; then
 416                 svndate=`hg --cwd "$srcdir" log --follow --template='r{svnrev} {node|short}\n' | while read svn_revision hg_sha; do
 417                         if test \${svn_revision} != r ; then
 418                                 if test \${hg_sha} = ${hg_revid} ; then
 419                                         echo "rev. \${svn_revision#r}${modified}"
 420                                 else
 421                                         echo "rev. \${svn_revision#r}+h${hg_revision}"
 422                                 fi
 423                                 break
 424                         fi
 425                 done`
 426         else
 427                 svndate="rev. h${hg_revision}"
 428         fi
 429 ])
 430
 431 AC_MSG_RESULT(${svndate:-None required})
 432 AS_IF([test -n "$svndate"], [
 433             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 434             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 435 ])
 436 AC_SUBST([SVNDATE], [$svndate])dnl
 437
 438
 439 dnl Set up the denoiser
 440 MULE_DENOISER
 441
 442
 443 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 444 MULE_CHECK_CCACHE
 445
 446
 447 dnl ---------------------------------------------------------------------------
 448 dnl End of checks, now write the results and report
 449 dnl ---------------------------------------------------------------------------
 450
 451 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 452 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":" -a x$WX_PORT = xmsw)
 453 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 454 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 455 AM_CONDITIONAL(INSTALL_SKINS, test MULE_IS_ENABLED_ANY([monolithic, amule-gui]))
 456 AM_CONDITIONAL(PLASMAMULE, test MULE_IS_ENABLED([plasmamule]))
 457
 458 AM_CONDITIONAL([COMPILE_LIB_COMMON],    [test MULE_IS_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui, fileview])])
 459 AM_CONDITIONAL([COMPILE_LIB_EC],        [test MULE_IS_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui])])
 460
 461 dnl Generate the Makefiles
 462 AC_CONFIG_FILES([Makefile
 463                  docs/Makefile
 464                  docs/man/Makefile
 465                  intl/Makefile
 466                  po/Makefile.in
 467                  src/Makefile
 468                  src/pixmaps/Makefile
 469                  src/pixmaps/flags_xpm/Makefile
 470                  src/libs/Makefile
 471                  src/libs/ec/Makefile
 472                  src/libs/ec/cpp/Makefile
 473                  src/libs/common/Makefile
 474                  src/utils/Makefile
 475                  src/utils/aLinkCreator/Makefile
 476                  src/utils/aLinkCreator/docs/Makefile
 477                  src/utils/aLinkCreator/src/Makefile
 478                  src/utils/cas/Makefile
 479                  src/utils/cas/docs/Makefile
 480                  src/utils/fileview/Makefile
 481                  src/utils/plasmamule/Makefile
 482                  src/utils/wxCas/Makefile
 483                  src/utils/wxCas/docs/Makefile
 484                  src/utils/wxCas/src/Makefile
 485                  src/utils/xas/Makefile
 486                  src/utils/xas/autostart-xas
 487                  src/utils/xas/docs/Makefile
 488                  src/skins/Makefile
 489                  src/webserver/Makefile
 490                  src/webserver/src/Makefile
 491                  src/webserver/default/Makefile
 492                  unittests/Makefile
 493                  unittests/muleunit/Makefile
 494                  unittests/tests/Makefile])
 495
 496 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 497 AC_OUTPUT
 498
 499 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 500
 501 echo
 502 echo
 503 echo "  Configure script has finished system check."
 504 echo
 505 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 506 echo
 507 echo "  aMule enabled options:"
 508 echo
 509 echo "  **** aMule Core ****"
 510 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 511 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 512 echo "  Should aMule be compiled in debug mode?                    MULE_STATUSOF([debug])"
 513 echo "  Should aMule be compiled with profiling?                   MULE_STATUSOF([profile])"
 514 echo "  Should aMule be compiled with optimizations?               MULE_STATUSOF([optimize])"
 515 echo "  Should aMule be compiled with UPnP support?                MULE_STATUSOF([upnp])"
 516 echo "  Should aMule be compiled with IP2country support?          MULE_STATUSOF([geoip])"
 517 echo "  Should aMule monolithic application be built?              MULE_STATUSOF([monolithic])"
 518 echo "  Should aMule daemon version be built?                      MULE_STATUSOF([amule-daemon])"
 519 echo "  Should aMule remote gui be built?                          MULE_STATUSOF([amule-gui])"
 520
 521 echo
 522 echo "  **** aMule TextClient ****"
 523 echo "  Should aMule Command Line Client be built?                 MULE_STATUSOF([amulecmd])"
 524 echo
 525 echo "  **** aMule WebServer ****"
 526 echo "  Should aMule WebServer be built?                           MULE_STATUSOF([webserver])"
 527 echo
 528 echo "  **** aMule ED2K Links Handler ****"
 529 echo "  Should aMule ED2K Links Handler be built?                  MULE_STATUSOF([ed2k])"
 530 echo
 531 echo "  **** aMuleLinkCreator ****"
 532 echo "  Should aMuleLinkCreator GUI version (alc) be built?        MULE_STATUSOF([alc])"
 533 echo "  Should aMuleLinkCreator for console (alcc) be built?       MULE_STATUSOF([alcc])"
 534 echo
 535 echo "  **** aMule Statistics ****"
 536 echo "  Should C aMule Statistics (CAS) be built?                  MULE_STATUSOF([cas])"
 537 echo "  Should aMule GUI Statistics (wxCas) be built?              MULE_STATUSOF([wxcas])"
 538 echo "  Should xas XChat2 plugin be installed?                     MULE_STATUSOF([xas])"
 539 echo "  Should plasmaMule plasma-applet be built?                  MULE_STATUSOF([plasmamule])"
 540
 541 echo
 542 echo "  **** General Libraries and Tools ****"
 543 echo "  Should ccache support be enabled?                          MULE_STATUSOF([ccache])"
 544 echo "  Should aMule file viewer for console be built?             MULE_STATUSOF([fileview])"
 545 echo "  Libraries aMule will use to build:"
 546 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview], [
 547         wxinfo="$WX_PORT"
 548         AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 549         AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 550         echo "                             wxWidgets             ${WX_VERSION} ($wxinfo)"
 551 ])
 552 AS_IF([test ${with_boost:-no} != no],
 553 [MULE_IF(
 554         [test ${with_boost:-no} = disabled],
 555                 [echo "                             boost                 Not detected"],
 556         [test ${boost_cv_inc_path:-yes} != yes],
 557                 [echo "                             boost                 `echo ${boost_cv_lib_version} | sed -e 's/_/./g'` (in ${boost_cv_inc_path})"],
 558                 [echo "                             boost                 `echo ${boost_cv_lib_version} | sed -e 's/_/./g'`"],
 559 )])
 560 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 561         [echo "                             crypto++              ${CRYPTOPP_VERSION_STRING} (in ${CRYPTOPP_PREFIX})"])
 562 MULE_IF_ENABLED([upnp], [
 563         AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 564         echo "                             libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"
 565 ])
 566 if test ${enable_nls:-yes} = yes; then
 567 AS_IF([test x$USE_NLS = xno],
 568         [libintl_found="Not detected"],
 569         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 570                 [libintl_found="included"],
 571                 [libintl_found="system"])])
 572 echo "                             libintl               $libintl_found"
 573 fi
 574 MULE_IF_ENABLED([geoip],
 575         [AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 576         MULE_IF_ENABLED_ANY([monolithic, amule-gui],
 577                 [echo "                             libGeoIP              ${geoip_style}"])])
 578 MULE_IF_ENABLED([webserver],
 579         [echo "                             libpng                ${LIBPNG_VERSION:-Not detected}"])
 580 MULE_IF_ENABLED([cas],
 581         [echo "                             libgd                 ${GDLIB_VERSION:-Not detected}"])
 582 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 583         [echo "                             zlib                  ${ZLIB_VERSION:-Not detected}"])
 584 MULE_IF_ENABLED([plasmamule],
 585 [echo "                             qt-moc                ${QT_MOC} ${QT_MOC_VERSION}"
 586 echo "                             qt-core-libs          ${QT_CORE_LIBS}"
 587 echo "                             qt-gui-libs           ${QT_GUI_LIBS}"
 588 echo "                             kde4-config           ${KDE4_CONFIG} (${KDE_CONF_VER})"
 589 echo "                             kde-headers           ${KDE_HEADER_DIR}"
 590 echo "                             kde-services-path     ${KDE_SERVICE_PATH}"
 591 echo "                             kde-module-path       ${KDE_MODULE_PATH}"
 592 echo "                             kde-icon-path         ${KDE_ICON_PATH}"
 593 echo "                             kde-mime-path         ${KDE_MIME_PATH}"
 594 echo "                             kde-applinks-path     ${KDE_APPLNK_PATH}"
 595 ])