| blob | f0a147a832e8de424625c2cd11915d8580523407 |
1 # -*- Autoconf -*-
2 # This file is part of the aMule Project.
3 #
4 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
5 #
6 # Any parts of this program derived from the xMule, lMule or eMule project,
7 # or contributed by third-party developers are copyrighted by their
8 # respective authors.
9 #
10 # This program is free software; you can redistribute it and/or modify
11 # it under the terms of the GNU General Public License as published by
12 # the Free Software Foundation; either version 2 of the License, or
13 # (at your option) any later version.
14 #
15 # This program is distributed in the hope that it will be useful,
16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 # GNU General Public License for more details.
19 #
20 # You should have received a copy of the GNU General Public License
21 # along with this program; if not, write to the Free Software
22 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
23 #
25 dnl ---------------------------------------------------------------------------
26 dnl Helper functions
27 dnl ---------------------------------------------------------------------------
28 m4_pattern_forbid(MULE_)dnl Check for unexpanded *MULE_* macros
29 m4_pattern_allow(AMULE_)dnl Allow the *AMULE_* names
31 dnl MULE_APPEND(VARNAME, VALUE)
32 AC_DEFUN([MULE_APPEND], [$1="$$1 $2"])
34 dnl MULE_PREPEND(VARNAME, VALUE)
35 AC_DEFUN([MULE_PREPEND], [$1="$2 $$1"])
37 dnl MULE_ADDFLAG(FLAGTYPE, VALUE)
38 AC_DEFUN([MULE_ADDFLAG], [MULE_APPEND([MULE[]$1[]FLAGS], [$2])])
40 dnl MULE_ADDCCXXFLAG(VALUE)
41 AC_DEFUN([MULE_ADDCCXXFLAG],
42 [
43 MULE_ADDFLAG([C], [$1])
44 MULE_ADDFLAG([CXX], [$1])
45 ])
47 dnl MULE_BACKUP(VAR)
48 AC_DEFUN([MULE_BACKUP], [mule_backup_$1="$$1"])
50 dnl MULE_RESTORE(VAR)
51 AC_DEFUN([MULE_RESTORE], [$1="$mule_backup_$1"])
53 dnl ---------------------------------------------------------------------------
54 dnl MULE_IF(CONDITION, [IF-TRUE] [, ELIF-CONDITION, [IF-TRUE]]... [, ELSE-BRANCH])
55 dnl
56 dnl Works like AS_IF(), but allows elif-branches too.
57 dnl ---------------------------------------------------------------------------
58 m4_define([__mule_if_helper],
59 [m4_if( [$#], 0,,
60 [$#], 1, [m4_ifvaln([$1], [m4_n([else]) $1])],
61 [m4_n([elif $1; then]) m4_ifvaln([$2], [$2], :)])dnl
62 m4_if(m4_eval([$# > 2]), 1, [$0(m4_shiftn(2, $@))])])
64 m4_define([MULE_IF],
65 [m4_if( [$#], 0,,
66 [$#], 1,,
67 [m4_n([if $1; then]) m4_ifval([$2],[$2], :)
68 m4_if(m4_eval([$# > 2]), 1, [__mule_if_helper(m4_shiftn(2, $@))])m4_n([fi])])])
70 dnl ---------------------------------------------------------------------------
71 dnl MULE_WARNING(MESSAGE)
72 dnl
73 dnl Works like AC_MSG_WARN(), but the warning will be reproduced at the end of
74 dnl the configure run. An empty line is prepended at the final output and a
75 dnl newline is appended for free.
76 dnl ---------------------------------------------------------------------------
77 m4_define([_MULE_WARNINGS],
78 [m4_ifdef([_m4_divert(BODY)], incr(_m4_divert(BODY)), [5000])])
79 m4_define([_MULE_WARNCOUNT], [0])
81 m4_divert_push(_MULE_WARNINGS)dnl
82 if test ${_mule_has_warnings:-no} = yes; then
83 echo ""
84 echo ""
85 echo " *** Warnings during configuration ***"
86 fi
87 m4_divert_pop()dnl
89 m4_define([MULE_WARNING],
90 [AC_MSG_WARN(
91 m4_pushdef([_mule_Prefix], [ ])dnl
92 m4_foreach([_mule_Line], m4_quote(m4_split([$1], [
93 ])), [
94 m4_text_wrap(m4_defn([_mule_Line]), _mule_Prefix)])[]dnl
95 m4_popdef([_mule_Prefix])dnl
96 )
97 _mule_warning_[]_MULE_WARNCOUNT[]=yes
98 _mule_has_warnings=yes
99 m4_divert_push(_MULE_WARNINGS)dnl
100 if test ${_mule_warning_[]_MULE_WARNCOUNT[]:-no} = yes; then
101 cat <<_MULEEOT
103 m4_pushdef([_mule_Prefix1], [* ])dnl
104 m4_pushdef([_mule_Prefix], [ ])dnl
105 m4_foreach([_mule_Line], m4_quote(m4_split([$1], [
106 ])), [m4_text_wrap(m4_defn([_mule_Line]), _mule_Prefix, _mule_Prefix1)
107 m4_define([_mule_Prefix1], _mule_Prefix)dnl
108 ])[]dnl
109 m4_popdef([_mule_Prefix])dnl
110 m4_popdef([_mule_Prefix1])dnl
111 _MULEEOT
112 fi
113 m4_divert_pop()dnl
114 m4_define([_MULE_WARNCOUNT], incr(_MULE_WARNCOUNT))])
116 dnl ---------------------------------------------------------------------------
117 dnl MULE_CHECK_SYSTEM
118 dnl
119 dnl Checks host system type, and sets system-specific flags accordingly.
120 dnl Sets $SYS to the name of the host os.
121 dnl ---------------------------------------------------------------------------
122 AC_DEFUN([MULE_CHECK_SYSTEM],
123 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
125 case "${host_os}" in
126 darwin*)
127 SYS=darwin
128 MULECPPFLAGS="-no-cpp-precomp -D_INTL_REDIRECT_MACROS -DNOPCH";
129 MULELDFLAGS="-bind_at_load"
130 touch src/Scanner.cpp
131 ;;
132 openbsd*)
133 SYS=openbsd
134 LIBS="$LIBS -L/usr/local/lib"
135 X11LIBS="-lX11 -L/usr/X11R6/lib"
136 MULECPPFLAGS="-D__OPENBSD__"
137 ;;
138 *cygwin* | *mingw32*)
139 SYS=win32
140 MULECPPFLAGS="-DNOMINMAX"
141 ;;
142 solaris*)
143 SYS=solaris
144 RESOLV_LIB="-lresolv -lnsl"
145 X11LIBS="-lX11"
146 LIBS="$LIBS -lrt"
147 ;;
148 *netbsd*)
149 SYS=netbsd
150 # Now this is against autoconf recommendation that configure should not modify CPPFLAGS and LDFLAGS
151 # However, these values in NetBSD are required even to run the tests, and this is the easiest way to do it.
152 # Still, we prepend them, instead of adding, so the user may override them.
153 MULE_PREPEND([CPPFLAGS], [-I/usr/pkg/include])
154 MULE_PREPEND([LDFLAGS], [-R/usr/pkg/lib -L/usr/pkg/lib])
155 ;;
156 *)
157 SYS=unknown
158 ;;
159 esac
161 # -lpthread is needed by Debian but FreeBSD < 5 doesn't support it
162 AS_IF([test ${SYS:-unknown} != win32],
163 [
164 AC_MSG_CHECKING([if this is a FreeBSD 4 or earlier system])
165 AS_IF([test x"`uname -s`" = xFreeBSD && test 0`uname -r | cut -c 1` -lt 5],
166 [
167 MULE_ADDFLAG([LD], [-pthread])
168 AC_MSG_RESULT(yes)
169 ], [
170 MULE_ADDFLAG([LD], [-lpthread])
171 AC_MSG_RESULT(no)
172 ])
173 ])
175 AC_SUBST([RESOLV_LIB])dnl
176 AC_SUBST([X11LIBS])dnl
177 AC_SUBST([MULECPPFLAGS])dnl
178 AC_SUBST([MULECFLAGS])dnl
179 AC_SUBST([MULECXXFLAGS])dnl
180 AC_SUBST([MULELDFLAGS])dnl
181 AC_SUBST([MULERCFLAGS])dnl
182 ])
184 dnl ---------------------------------------------------------------------------
185 dnl _MULE_CHECK_DEBUG_FLAG
186 dnl ---------------------------------------------------------------------------
187 AC_DEFUN([_MULE_CHECK_DEBUG_FLAG],
188 [AC_REQUIRE([MULE_CHECK_GLIBCXX])dnl
190 AC_ARG_ENABLE(
191 [debug],
192 [AS_HELP_STRING([--disable-debug], [disable additional debugging output])],
193 [USE_DEBUG=${enableval:-yes}], [USE_DEBUG=yes])
195 AS_IF([test $USE_DEBUG = yes],
196 [
197 MULE_ADDFLAG([CPP], [-D__DEBUG__])
198 MULE_ADDCCXXFLAG([-g])
199 AS_IF([test ${GLIBCXX:-no} = yes], [MULE_ADDFLAG([CPP], [-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC])])
200 AS_IF([test ${GCC:-no} = yes], [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef -ggdb -fno-inline -fmessage-length=0])])
201 AS_IF([test ${SYS:-unknown} = win32], [MULE_ADDFLAG([RC], [-D__DEBUG__])])
202 ], [
203 AS_IF([test ${GCC:-no} = yes], [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef])])
204 ])
205 ])
207 dnl ---------------------------------------------------------------------------
208 dnl _MULE_CHECK_PROFILE_FLAG
209 dnl ---------------------------------------------------------------------------
210 AC_DEFUN([_MULE_CHECK_PROFILE_FLAG],
211 [
212 AC_ARG_ENABLE(
213 [profile],
214 [AS_HELP_STRING([--enable-profile], [enable code profiling])],
215 [USE_PROFILE=${enableval:-no}], [USE_PROFILE=no])
217 AS_IF([test $USE_PROFILE = yes],
218 [
219 MULE_ADDCCXXFLAG([-pg])
220 MULE_ADDFLAG([LD], [-pg])
221 ])
222 ])
224 dnl ---------------------------------------------------------------------------
225 dnl _MULE_CHECK_OPTIMIZE_FLAG
226 dnl ---------------------------------------------------------------------------
227 AC_DEFUN([_MULE_CHECK_OPTIMIZE_FLAG],
228 [
229 AC_ARG_ENABLE(
230 [optimize],
231 [AS_HELP_STRING([--enable-optimize], [enable code optimization])],
232 [USE_OPTIMIZE=${enableval:-no}], [USE_OPTIMIZE=no])
234 AS_IF([test $USE_OPTIMIZE = yes], [MULE_ADDCCXXFLAG([-O2])])
235 ])
237 dnl ---------------------------------------------------------------------------
238 dnl MULE_COMPILATION_FLAGS
239 dnl
240 dnl Checks type of compilation requested by user, and sets various flags
241 dnl accordingly.
242 dnl ---------------------------------------------------------------------------
243 AC_DEFUN([MULE_COMPILATION_FLAGS],
244 [
245 _MULE_CHECK_DEBUG_FLAG
246 _MULE_CHECK_OPTIMIZE_FLAG
247 _MULE_CHECK_PROFILE_FLAG
249 AC_MSG_CHECKING([if the applications should be statically linked])
250 AC_ARG_ENABLE(
251 [static],
252 [AS_HELP_STRING([--enable-static], [produce a statically linked executable])],
253 [AS_IF([test ${enableval:-no} = yes], [MULE_ADDFLAG([LD], [-static])])])
254 AC_MSG_RESULT(${enableval:-no})
256 MULE_ADDFLAG([CPP], [-DUSE_WX_EXTENSIONS])
257 ])
259 dnl ---------------------------------------------------------------------------
260 dnl MULE_CHECK_GLIBCXX
261 dnl
262 dnl Checks whether we use the GNU C++ Library.
263 dnl ---------------------------------------------------------------------------
264 AC_DEFUN([MULE_CHECK_GLIBCXX],
265 [dnl
266 AC_REQUIRE([AC_PROG_EGREP])dnl
267 AC_REQUIRE([AC_PROG_CXXCPP])dnl
268 AC_LANG_ASSERT([C++])dnl
270 AC_MSG_CHECKING([if we're using the GNU C++ library])
271 AC_PREPROC_IFELSE([
272 AC_LANG_SOURCE([[
273 #include <string>
274 #ifndef __GLIBCXX__
275 #error Non-GNU C++ library found.
276 #endif
277 ]])
278 ], [GLIBCXX=yes], [GLIBCXX=no])
279 AC_MSG_RESULT([$GLIBCXX])
280 ])
282 dnl ---------------------------------------------------------------------------
283 dnl MULE_CHECK_WX_SUPPORTS_LARGEFILE
284 dnl
285 dnl Test that wxWidgets is built with support for large-files. If not
286 dnl configure is terminated.
287 dnl ---------------------------------------------------------------------------
288 AC_DEFUN([MULE_CHECK_WX_SUPPORTS_LARGEFILE],
289 [AC_LANG_ASSERT([C++])dnl
291 dnl Backup current flags and setup flags for testing
292 MULE_BACKUP([CPPFLAGS])
293 MULE_APPEND([CPPFLAGS], [$WX_CPPFLAGS])
295 AC_MSG_CHECKING([that wxWidgets has support for large files])
296 AC_PREPROC_IFELSE([
297 AC_LANG_SOURCE([[
298 #include <wx/wx.h>
299 #if !HAVE_LARGEFILE_SUPPORT && !defined(_LARGE_FILES) && !defined(__WXMSW__)
300 #error No LargeFile support!
301 #endif
302 ]])
303 ], [
304 AC_MSG_RESULT([yes])
305 ], [
306 AC_MSG_RESULT([no])
307 AC_MSG_ERROR([
308 Support for large files in wxWidgets is required by aMule.
309 To continue you must recompile wxWidgets with support for
310 large files enabled.])
311 ])
313 dnl Restore backup'd flags
314 MULE_RESTORE([CPPFLAGS])
315 ])
318 dnl --------------------------------------------------------------------------
319 dnl MULE_CHECK_CCACHE
320 dnl
321 dnl Checks if ccache is requested and available, and makes use of it
322 dnl --------------------------------------------------------------------------
323 AC_DEFUN([MULE_CHECK_CCACHE],
324 [
325 AC_ARG_ENABLE([ccache],
326 [AS_HELP_STRING([--enable-ccache], [enable ccache support for fast recompilation])])
328 AC_ARG_WITH([ccache-prefix],
329 [AS_HELP_STRING([--with-ccache-prefix=PREFIX], [prefix where ccache is installed])])
331 AC_MSG_CHECKING([whether ccache support should be added])
332 AC_MSG_RESULT([${enable_ccache:-no}])
334 AS_IF([test ${enable_ccache:-no} = yes], [
335 AC_MSG_CHECKING([for ccache presence])
336 AS_IF([test -z "$with_ccache_prefix"], [
337 ccache_full=`which ccache`
338 with_ccache_prefix=`dirname ${ccache_full}`
339 ])
340 AS_IF([$with_ccache_prefix/ccache -V >/dev/null 2>&1], [
341 AC_MSG_RESULT([yes])
342 CC="$with_ccache_prefix/ccache $CC"
343 CXX="$with_ccache_prefix/ccache $CXX"
344 BUILD_CC="$with_ccache_prefix/ccache $BUILD_CC"
345 ], [
346 enable_ccache=no
347 AC_MSG_RESULT([no])
348 ])
349 ])
350 ])
353 dnl ----------------------------------------------------
354 dnl MULE_CHECK_BFD
355 dnl check if bfd.h is on the system and usable
356 dnl ----------------------------------------------------
357 AC_DEFUN([MULE_CHECK_BFD],
358 [
359 AC_MSG_CHECKING([for bfd])
360 MULE_BACKUP([LIBS])
361 MULE_BACKUP([LDFLAGS])
362 MULE_PREPEND([LIBS], [-lbfd -liberty ${ZLIB_LIBS}])
363 MULE_APPEND([LDFLAGS], [${ZLIB_LDFLAGS}])
364 AC_LINK_IFELSE([
365 AC_LANG_PROGRAM([[
366 #include <ansidecl.h>
367 #include <bfd.h>
368 ]], [[
369 char *dummy = bfd_errmsg(bfd_get_error());
370 ]])
371 ], [
372 AC_MSG_RESULT([yes])
373 BFD_CPPFLAGS="-DHAVE_BFD"
374 BFD_LIBS="-lbfd -liberty"
375 ], [
376 AC_MSG_RESULT([no])
377 MULE_WARNING([bfd.h not found or unusable, please install binutils development package if you are a developer or want to help testing aMule])
378 ])
379 MULE_RESTORE([LIBS])
380 MULE_RESTORE([LDFLAGS])
382 AC_SUBST([BFD_CPPFLAGS])dnl
383 AC_SUBST([BFD_LIBS])dnl
384 ])
387 dnl ----------------------------------------------------
388 dnl MULE_CHECK_FLEX_EXTENDED
389 dnl check if flex can produce header files
390 dnl ----------------------------------------------------
391 AC_DEFUN([MULE_CHECK_FLEX_EXTENDED],
392 [
393 AC_MSG_CHECKING([for extended flex capabilities])
395 extended_flex=`flex --help | grep header-file`
396 AS_IF([test -n "$extended_flex"], [HAVE_FLEX_EXTENDED=yes], [HAVE_FLEX_EXTENDED=no])
397 AC_MSG_RESULT($HAVE_FLEX_EXTENDED)
399 AS_IF([test $HAVE_FLEX_EXTENDED = no], [AC_MSG_NOTICE([Your flex version doesn't support --header-file flag. This is not critical, but an upgrade is recommended])])
400 ])
403 dnl ----------------------------------------------------
404 dnl MULE_CHECK_EXCEPTIONS
405 dnl Checks for broken exception-handling. This is needed
406 dnl because exception handling is broken for some archs/
407 dnl compilers.
408 dnl ----------------------------------------------------
409 AC_DEFUN([MULE_CHECK_EXCEPTIONS],
410 [AC_LANG_ASSERT([C++])dnl
412 AC_MSG_CHECKING([for exception-handling])
413 AC_RUN_IFELSE([
414 AC_LANG_PROGRAM(, [[
415 try {
416 throw 1;
417 } catch (int) {
418 return 0;
419 }
420 return 1;
421 ]])
422 ], [
423 AC_MSG_RESULT([yes])
424 ], [
425 AC_MSG_RESULT([no])
426 AC_MSG_ERROR([Exception handling does not work. Broken compiler?])
427 ], [
428 AC_MSG_RESULT([undeterminable])
429 MULE_WARNING(
430 [Cross-compilation detected, so exception handling cannot be tested.
431 Note that broken exception handling in your compiler may lead to unexpected crashes.])
432 ])
433 ])
436 dnl ---------------------------------------------------------------------------
437 dnl MULE_CHECK_REGEX([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
438 dnl
439 dnl This function will test the existance of a POSIX compliant regex library.
440 dnl ---------------------------------------------------------------------------
441 AC_DEFUN([MULE_CHECK_REGEX],
442 [
443 AC_CHECK_HEADERS([sys/types.h])
444 AC_MSG_CHECKING([for a POSIX compliant regex library])
445 regex_found=no
446 for REGEX_LIBS in '' -lgnurx -lregex; do
447 MULE_BACKUP([LIBS])
448 MULE_PREPEND([LIBS], [$REGEX_LIBS])
449 AC_LINK_IFELSE([
450 AC_LANG_PROGRAM([[
451 #ifdef HAVE_SYS_TYPES_H
452 # include <sys/types.h>
453 #endif
454 #include <regex.h>
455 ]], [[
456 regex_t preg;
457 regcomp(&preg, "", REG_EXTENDED);
458 regmatch_t *pmatch;
459 regexec(&preg, "", 0, pmatch, 0);
460 regfree(&preg);
461 ]])
462 ], [
463 MULE_RESTORE([LIBS])
464 regex_found=yes
465 break;
466 ], [MULE_RESTORE([LIBS])])
467 done
468 AC_MSG_RESULT([$regex_found])
469 AS_IF([test $regex_found = yes], [$1], [$2])
470 AC_SUBST([REGEX_LIBS])dnl
471 ])
474 dnl ---------------------------------------------------------------------------
475 dnl MULE_CHECK_CXXABI
476 dnl
477 dnl This function will test the header <cxxabi.h> and abi::__cxa_demangle()
478 dnl ---------------------------------------------------------------------------
479 AC_DEFUN([MULE_CHECK_CXXABI],
480 [AC_LANG_ASSERT([C++])dnl
482 AC_MSG_CHECKING([for <cxxabi.h> and __cxa_demangle()])
483 AC_LINK_IFELSE([
484 AC_LANG_PROGRAM([[
485 #include <cxxabi.h>
486 ]], [[
487 int status;
488 char * demangled = abi::__cxa_demangle("", 0, 0, &status);
489 std::type_info *ti = abi::__cxa_current_exception_type();
490 ]])
491 ], [
492 AH_TEMPLATE([HAVE_CXXABI], [Define to 1 if you have the <cxxabi.h> header which declares abi::__cxa_demangle()])
493 AC_DEFINE([HAVE_CXXABI])
494 AC_MSG_RESULT([yes])
495 ], [
496 AC_MSG_RESULT([no])
497 ])
498 ])
501 dnl ---------------------------------------------------------------------------
502 dnl MULE_CHECK_EXECINFO
503 dnl
504 dnl This function will test the header <execinfo.h> and backtrace()
505 dnl ---------------------------------------------------------------------------
506 AC_DEFUN([MULE_CHECK_EXECINFO],
507 [
508 AC_MSG_CHECKING([for <execinfo.h> and backtrace()])
509 AC_LINK_IFELSE([
510 AC_LANG_PROGRAM([[
511 #include <execinfo.h>
512 ]], [[
513 void *bt[1];
514 int n = backtrace(&bt, 1);
515 const char **bt_syms = backtrace_symbols(bt, n);
516 ]])
517 ], [
518 AH_TEMPLATE([HAVE_EXECINFO], [Define to 1 if you have the <execinfo.h> header which declares backtrace()])
519 AC_DEFINE([HAVE_EXECINFO])
520 AC_MSG_RESULT([yes])
521 ], [
522 AC_MSG_RESULT([no])
523 ])
524 ])
527 dnl ---------------------------------------------------------------------------
528 dnl MULE_DENOISER
529 dnl
530 dnl Test for denoising level and add denoiser commands to config.status
531 dnl ---------------------------------------------------------------------------
532 AC_DEFUN([MULE_DENOISER],
533 [
534 AC_ARG_WITH([denoise-level],
535 [AS_HELP_STRING([--with-denoise-level=<level>], [Specifies denoising level (0-4):])
536 AS_HELP_STRING([], [0 - Do nothing])
537 AS_HELP_STRING([], [4 - Suppress all normal output])
538 AS_HELP_STRING([], [(for more information see src/utils/scripts/denoiser.rules)])
539 ])
541 AC_MSG_CHECKING([denoising level])
542 AS_IF([test ${with_denoise_level:-5} = yes], [with_denoise_level=5])
543 AS_IF([test ${with_denoise_level:-5} = no], [with_denoise_level=0])
544 AS_IF([test ${with_denoise_level:-5} -gt 4],
545 [AS_IF([test "${svndate:+set}" = "set"], [with_denoise_level=0], [with_denoise_level=4])])
546 AC_MSG_RESULT([$with_denoise_level])
548 AC_CONFIG_COMMANDS([denoiser], [[if test $denoiserlevel -gt 0; then
549 if test ! -d src/utils/scripts; then mkdir -p src/utils/scripts; fi
550 sed -e "1{x;s/.*/1/;x;};/^[ ]*\$/d;/^#if /{/level.*$denoiserlevel/{x;s/^/1/;x;b0;};x;s/^/0/;x;:0;d;};/^#else/{x;/^1/{s/1/0/;b1;};s/0/1/;:1;x;d;};/^#endif/{x;s/.//;x;d;};/^[ ]*#/d;x;/^1/{x;b;};x;d" \
551 $srcdir/src/utils/scripts/denoiser.rules > src/utils/scripts/denoiser.sed
552 for i in `find . -name 'Makefile' -print`; do
553 if test -n "`head -n 1 $i | grep '^#'`"; then
554 sed -f src/utils/scripts/denoiser.sed $i > $i.tmp && mv $i.tmp $i
555 fi
556 done
557 fi]], [denoiserlevel=$with_denoise_level])
558 ])