acinclude.m4

   1 #                                                       -*- Autoconf -*-
   2 # This file is part of the aMule Project.
   3 #
   4 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   5 #
   6 # Any parts of this program derived from the xMule, lMule or eMule project,
   7 # or contributed by third-party developers are copyrighted by their
   8 # respective authors.
   9 #
  10 # This program is free software; you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 2 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program; if not, write to the Free Software
  22 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  23 #
  24
  25 dnl ---------------------------------------------------------------------------
  26 dnl Helper functions
  27 dnl ---------------------------------------------------------------------------
  28 m4_pattern_forbid(MULE_)dnl Check for unexpanded *MULE_* macros
  29 m4_pattern_allow(AMULE_)dnl Allow the *AMULE_* names
  30
  31 dnl MULE_APPEND(VARNAME, VALUE)
  32 AC_DEFUN([MULE_APPEND], [$1="$$1 $2"])
  33
  34 dnl MULE_PREPEND(VARNAME, VALUE)
  35 AC_DEFUN([MULE_PREPEND], [$1="$2 $$1"])
  36
  37 dnl MULE_ADDFLAG(FLAGTYPE, VALUE)
  38 AC_DEFUN([MULE_ADDFLAG], [MULE_APPEND([MULE[]$1[]FLAGS], [$2])])
  39
  40 dnl MULE_ADDCCXXFLAG(VALUE)
  41 AC_DEFUN([MULE_ADDCCXXFLAG],
  42 [
  43         MULE_ADDFLAG([C], [$1])
  44         MULE_ADDFLAG([CXX], [$1])
  45 ])
  46
  47 dnl MULE_BACKUP(VAR)
  48 AC_DEFUN([MULE_BACKUP], [mule_backup_$1="$$1"])
  49
  50 dnl MULE_RESTORE(VAR)
  51 AC_DEFUN([MULE_RESTORE], [$1="$mule_backup_$1"])
  52
  53 dnl ---------------------------------------------------------------------------
  54 dnl MULE_IF(CONDITION, [IF-TRUE] [, ELIF-CONDITION, [IF-TRUE]]... [, ELSE-BRANCH])
  55 dnl
  56 dnl Works like AS_IF(), but allows elif-branches too.
  57 dnl ---------------------------------------------------------------------------
  58 m4_define([__mule_if_helper],
  59 [m4_if( [$#], 0,,
  60         [$#], 1, [m4_ifvaln([$1], [m4_n([else])  $1])],
  61         [m4_n([elif $1; then])  m4_ifvaln([$2], [$2], :)])dnl
  62 m4_if(m4_eval([$# > 2]), 1, [$0(m4_shiftn(2, $@))])])
  63
  64 m4_define([MULE_IF],
  65 [m4_if( [$#], 0,,
  66         [$#], 1,,
  67         [m4_n([if $1; then])  m4_ifval([$2],[$2], :)
  68 m4_if(m4_eval([$# > 2]), 1, [__mule_if_helper(m4_shiftn(2, $@))])m4_n([fi])])])
  69
  70 dnl ---------------------------------------------------------------------------
  71 dnl MULE_WARNING(MESSAGE)
  72 dnl
  73 dnl Works like AC_MSG_WARN(), but the warning will be reproduced at the end of
  74 dnl the configure run. An empty line is prepended at the final output and a
  75 dnl newline is appended for free.
  76 dnl ---------------------------------------------------------------------------
  77 m4_define([_MULE_WARNINGS],
  78         [m4_ifdef([_m4_divert(BODY)], incr(_m4_divert(BODY)), [5000])])
  79 m4_define([_MULE_WARNCOUNT], [0])
  80
  81 m4_divert_push(_MULE_WARNINGS)dnl
  82 if test ${_mule_has_warnings:-no} = yes; then
  83 echo ""
  84 echo ""
  85 echo " *** Warnings during configuration ***"
  86 fi
  87 m4_divert_pop()dnl
  88
  89 m4_define([MULE_WARNING],
  90 [AC_MSG_WARN(
  91 m4_pushdef([_mule_Prefix], [        ])dnl
  92 m4_foreach([_mule_Line], m4_quote(m4_split([$1], [
  93 ])), [
  94 m4_text_wrap(m4_defn([_mule_Line]), _mule_Prefix)])[]dnl
  95 m4_popdef([_mule_Prefix])dnl
  96 )
  97 _mule_warning_[]_MULE_WARNCOUNT[]=yes
  98 _mule_has_warnings=yes
  99 m4_divert_push(_MULE_WARNINGS)dnl
 100 if test ${_mule_warning_[]_MULE_WARNCOUNT[]:-no} = yes; then
 101 cat <<_MULEEOT
 102
 103 m4_pushdef([_mule_Prefix1], [* ])dnl
 104 m4_pushdef([_mule_Prefix], [  ])dnl
 105 m4_foreach([_mule_Line], m4_quote(m4_split([$1], [
 106 ])), [m4_text_wrap(m4_defn([_mule_Line]), _mule_Prefix, _mule_Prefix1)
 107 m4_define([_mule_Prefix1], _mule_Prefix)dnl
 108 ])[]dnl
 109 m4_popdef([_mule_Prefix])dnl
 110 m4_popdef([_mule_Prefix1])dnl
 111 _MULEEOT
 112 fi
 113 m4_divert_pop()dnl
 114 m4_define([_MULE_WARNCOUNT], incr(_MULE_WARNCOUNT))])
 115
 116 dnl ---------------------------------------------------------------------------
 117 dnl MULE_CHECK_SYSTEM
 118 dnl
 119 dnl Checks host system type, and sets system-specific flags accordingly.
 120 dnl Sets $SYS to the name of the host os.
 121 dnl ---------------------------------------------------------------------------
 122 AC_DEFUN([MULE_CHECK_SYSTEM],
 123 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
 124
 125         case "${host_os}" in
 126         darwin*)
 127                 SYS=darwin
 128                 MULECPPFLAGS="-no-cpp-precomp -D_INTL_REDIRECT_MACROS -DNOPCH";
 129                 MULELDFLAGS="-bind_at_load"
 130                 touch src/Scanner.cpp
 131                 ;;
 132         openbsd*)
 133                 SYS=openbsd
 134                 LIBS="$LIBS -L/usr/local/lib"
 135                 X11LIBS="-lX11 -L/usr/X11R6/lib"
 136                 MULECPPFLAGS="-D__OPENBSD__"
 137                 ;;
 138         *cygwin* | *mingw32*)
 139                 SYS=win32
 140                 MULECPPFLAGS="-DNOMINMAX"
 141                 ;;
 142         solaris*)
 143                 SYS=solaris
 144                 RESOLV_LIB="-lresolv -lnsl"
 145                 X11LIBS="-lX11"
 146                 LIBS="$LIBS -lrt"
 147                 ;;
 148         *netbsd*)
 149                 SYS=netbsd
 150                 # Now this is against autoconf recommendation that configure should not modify CPPFLAGS and LDFLAGS
 151                 # However, these values in NetBSD are required even to run the tests, and this is the easiest way to do it.
 152                 # Still, we prepend them, instead of adding, so the user may override them.
 153                 MULE_PREPEND([CPPFLAGS], [-I/usr/pkg/include])
 154                 MULE_PREPEND([LDFLAGS], [-R/usr/pkg/lib -L/usr/pkg/lib])
 155                 ;;
 156         *irix*)
 157                 SYS=irix
 158                 MULECPPFLAGS="-D__IRIX__"
 159                 ;;
 160         *)
 161                 SYS=unknown
 162                 ;;
 163         esac
 164
 165         # -lpthread is needed by Debian but FreeBSD < 5 doesn't support it
 166         AS_IF([test ${SYS:-unknown} != win32],
 167         [
 168                 AC_MSG_CHECKING([if this is a FreeBSD 4 or earlier system])
 169                 AS_IF([test x"`uname -s`" = xFreeBSD && test 0`uname -r | cut -c 1` -lt 5],
 170                 [
 171                         MULE_ADDFLAG([LD], [-pthread])
 172                         AC_MSG_RESULT(yes)
 173                 ], [
 174                         MULE_ADDFLAG([LD], [-lpthread])
 175                         AC_MSG_RESULT(no)
 176                 ])
 177         ])
 178
 179 AC_SUBST([RESOLV_LIB])dnl
 180 AC_SUBST([X11LIBS])dnl
 181 AC_SUBST([MULECPPFLAGS])dnl
 182 AC_SUBST([MULECFLAGS])dnl
 183 AC_SUBST([MULECXXFLAGS])dnl
 184 AC_SUBST([MULELDFLAGS])dnl
 185 AC_SUBST([MULERCFLAGS])dnl
 186 ])
 187
 188 dnl ---------------------------------------------------------------------------
 189 dnl _MULE_CHECK_DEBUG_FLAG
 190 dnl ---------------------------------------------------------------------------
 191 AC_DEFUN([_MULE_CHECK_DEBUG_FLAG],
 192 [AC_REQUIRE([MULE_CHECK_GLIBCXX])dnl
 193
 194         AC_ARG_ENABLE(
 195                 [debug],
 196                 [AS_HELP_STRING([--disable-debug], [disable additional debugging output])],
 197                 [USE_DEBUG=${enableval:-yes}], [USE_DEBUG=yes])
 198
 199         AS_IF([test $USE_DEBUG = yes],
 200         [
 201                 MULE_ADDFLAG([CPP], [-D__DEBUG__])
 202                 MULE_ADDCCXXFLAG([-g])
 203                 AS_IF([test ${GLIBCXX:-no} = yes],      [MULE_ADDFLAG([CPP], [-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC])])
 204                 AS_IF([test ${GCC:-no} = yes],          [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef -ggdb -fno-inline -fmessage-length=0])])
 205                 AS_IF([test ${SYS:-unknown} = win32],   [MULE_ADDFLAG([RC], [-D__DEBUG__])])
 206         ], [
 207                 AS_IF([test ${GCC:-no} = yes], [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef])])
 208         ])
 209 ])
 210
 211 dnl ---------------------------------------------------------------------------
 212 dnl _MULE_CHECK_PROFILE_FLAG
 213 dnl ---------------------------------------------------------------------------
 214 AC_DEFUN([_MULE_CHECK_PROFILE_FLAG],
 215 [
 216         AC_ARG_ENABLE(
 217                 [profile],
 218                 [AS_HELP_STRING([--enable-profile], [enable code profiling])],
 219                 [USE_PROFILE=${enableval:-no}], [USE_PROFILE=no])
 220
 221         AS_IF([test $USE_PROFILE = yes],
 222         [
 223                 MULE_ADDCCXXFLAG([-pg])
 224                 MULE_ADDFLAG([LD], [-pg])
 225         ])
 226 ])
 227
 228 dnl ---------------------------------------------------------------------------
 229 dnl _MULE_CHECK_OPTIMIZE_FLAG
 230 dnl ---------------------------------------------------------------------------
 231 AC_DEFUN([_MULE_CHECK_OPTIMIZE_FLAG],
 232 [
 233         AC_ARG_ENABLE(
 234                 [optimize],
 235                 [AS_HELP_STRING([--enable-optimize], [enable code optimization])],
 236                 [USE_OPTIMIZE=${enableval:-no}], [USE_OPTIMIZE=no])
 237
 238         AS_IF([test $USE_OPTIMIZE = yes], [MULE_ADDCCXXFLAG([-O2])])
 239 ])
 240
 241 dnl ---------------------------------------------------------------------------
 242 dnl MULE_COMPILATION_FLAGS
 243 dnl
 244 dnl Checks type of compilation requested by user, and sets various flags
 245 dnl accordingly.
 246 dnl ---------------------------------------------------------------------------
 247 AC_DEFUN([MULE_COMPILATION_FLAGS],
 248 [
 249         _MULE_CHECK_DEBUG_FLAG
 250         _MULE_CHECK_OPTIMIZE_FLAG
 251         _MULE_CHECK_PROFILE_FLAG
 252
 253         AC_MSG_CHECKING([if the applications should be statically linked])
 254         AC_ARG_ENABLE(
 255                 [static],
 256                 [AS_HELP_STRING([--enable-static], [produce a statically linked executable])],
 257                 [AS_IF([test ${enableval:-no} = yes], [MULE_ADDFLAG([LD], [-static])])])
 258         AC_MSG_RESULT(${enableval:-no})
 259
 260         MULE_ADDFLAG([CPP], [-DUSE_WX_EXTENSIONS])
 261 ])
 262
 263 dnl ---------------------------------------------------------------------------
 264 dnl MULE_CHECK_GLIBCXX
 265 dnl
 266 dnl Checks whether we use the GNU C++ Library.
 267 dnl ---------------------------------------------------------------------------
 268 AC_DEFUN([MULE_CHECK_GLIBCXX],
 269 [dnl
 270 AC_REQUIRE([AC_PROG_EGREP])dnl
 271 AC_REQUIRE([AC_PROG_CXXCPP])dnl
 272 AC_LANG_ASSERT([C++])dnl
 273
 274         AC_MSG_CHECKING([if we're using the GNU C++ library])
 275         AC_PREPROC_IFELSE([
 276                 AC_LANG_SOURCE([[
 277                         #include <string>
 278                         #ifndef __GLIBCXX__
 279                         #error Non-GNU C++ library found.
 280                         #endif
 281                 ]])
 282         ], [GLIBCXX=yes], [GLIBCXX=no])
 283         AC_MSG_RESULT([$GLIBCXX])
 284 ])
 285
 286 dnl ---------------------------------------------------------------------------
 287 dnl MULE_CHECK_WX_SUPPORTS_LARGEFILE
 288 dnl
 289 dnl Test that wxWidgets is built with support for large-files. If not
 290 dnl configure is terminated.
 291 dnl ---------------------------------------------------------------------------
 292 AC_DEFUN([MULE_CHECK_WX_SUPPORTS_LARGEFILE],
 293 [AC_LANG_ASSERT([C++])dnl
 294
 295         dnl Backup current flags and setup flags for testing
 296         MULE_BACKUP([CPPFLAGS])
 297         MULE_APPEND([CPPFLAGS], [$WX_CPPFLAGS])
 298
 299         AC_MSG_CHECKING([that wxWidgets has support for large files])
 300         AC_PREPROC_IFELSE([
 301                 AC_LANG_SOURCE([[
 302                         #include <wx/wx.h>
 303                         #include <wx/filefn.h>
 304                         #ifndef wxHAS_LARGE_FILES
 305                                 #error No LargeFile support!
 306                         #endif
 307                 ]])
 308         ], [
 309                 AC_MSG_RESULT([yes])
 310         ], [
 311                 AC_MSG_RESULT([no])
 312                 AC_MSG_ERROR([
 313         Support for large files in wxWidgets is required by aMule.
 314         To continue you must recompile wxWidgets with support for
 315         large files enabled.])
 316         ])
 317
 318         dnl Restore backup'd flags
 319         MULE_RESTORE([CPPFLAGS])
 320 ])
 321
 322
 323 dnl --------------------------------------------------------------------------
 324 dnl MULE_CHECK_CCACHE
 325 dnl
 326 dnl Checks if ccache is requested and available, and makes use of it
 327 dnl --------------------------------------------------------------------------
 328 AC_DEFUN([MULE_CHECK_CCACHE],
 329 [
 330         AC_ARG_ENABLE([ccache],
 331                 [AS_HELP_STRING([--enable-ccache], [enable ccache support for fast recompilation])])
 332
 333         AC_ARG_WITH([ccache-prefix],
 334                 [AS_HELP_STRING([--with-ccache-prefix=PREFIX], [prefix where ccache is installed])])
 335
 336         AC_MSG_CHECKING([whether ccache support should be added])
 337         AC_MSG_RESULT([${enable_ccache:-no}])
 338
 339         AS_IF([test ${enable_ccache:-no} = yes], [
 340                 AC_MSG_CHECKING([for ccache presence])
 341                 AS_IF([test -z "$with_ccache_prefix"], [
 342                         ccache_full=`which ccache`
 343                         with_ccache_prefix=`dirname ${ccache_full}`
 344                 ])
 345                 AS_IF([$with_ccache_prefix/ccache -V >/dev/null 2>&1], [
 346                         AC_MSG_RESULT([yes])
 347                         CC="$with_ccache_prefix/ccache $CC"
 348                         CXX="$with_ccache_prefix/ccache $CXX"
 349                         BUILD_CC="$with_ccache_prefix/ccache $BUILD_CC"
 350                 ], [
 351                         enable_ccache=no
 352                         AC_MSG_RESULT([no])
 353                 ])
 354         ])
 355 ])
 356
 357
 358 dnl ----------------------------------------------------
 359 dnl MULE_CHECK_BFD
 360 dnl check if bfd.h is on the system and usable
 361 dnl ----------------------------------------------------
 362 AC_DEFUN([MULE_CHECK_BFD],
 363 [AC_REQUIRE([MULE_CHECK_NLS])dnl
 364
 365         AC_MSG_CHECKING([for bfd])
 366         result=no
 367         for bfd_ldadd in "" "${LIBINTL}"; do
 368                 MULE_BACKUP([LIBS])
 369                 MULE_BACKUP([LDFLAGS])
 370                 MULE_PREPEND([LIBS], [-lbfd -liberty ${bfd_ldadd} ${ZLIB_LIBS}])
 371                 MULE_APPEND([LDFLAGS], [${ZLIB_LDFLAGS}])
 372                 AC_LINK_IFELSE([
 373                         AC_LANG_PROGRAM([[
 374                                 #include <ansidecl.h>
 375                                 #include <bfd.h>
 376                         ]], [[
 377                                 char *dummy = bfd_errmsg(bfd_get_error());
 378                         ]])
 379                 ], [
 380                         result=yes
 381                         BFD_CPPFLAGS="-DHAVE_BFD"
 382                         BFD_LIBS="-lbfd -liberty ${bfd_ldadd}"
 383                         MULE_RESTORE([LIBS])
 384                         MULE_RESTORE([LDFLAGS])
 385                         break
 386                 ])
 387                 MULE_RESTORE([LIBS])
 388                 MULE_RESTORE([LDFLAGS])
 389         done
 390
 391         AC_MSG_RESULT([$result])
 392
 393         AS_IF([test $result = no],
 394                 [MULE_WARNING([bfd.h not found or unusable, please install binutils development package if you are a developer or want to help testing aMule])])
 395
 396 AC_SUBST([BFD_CPPFLAGS])dnl
 397 AC_SUBST([BFD_LIBS])dnl
 398 ])
 399
 400
 401 dnl ----------------------------------------------------
 402 dnl MULE_CHECK_FLEX_EXTENDED
 403 dnl check if flex can produce header files
 404 dnl ----------------------------------------------------
 405 AC_DEFUN([MULE_CHECK_FLEX_EXTENDED],
 406 [
 407         AC_MSG_CHECKING([for extended flex capabilities])
 408
 409         extended_flex=`flex --help | grep header-file`
 410         AS_IF([test -n "$extended_flex"], [HAVE_FLEX_EXTENDED=yes], [HAVE_FLEX_EXTENDED=no])
 411         AC_MSG_RESULT($HAVE_FLEX_EXTENDED)
 412
 413         AS_IF([test $HAVE_FLEX_EXTENDED = no], [AC_MSG_NOTICE([Your flex version doesn't support --header-file flag. This is not critical, but an upgrade is recommended])])
 414 ])
 415
 416
 417 dnl ----------------------------------------------------
 418 dnl MULE_CHECK_EXCEPTIONS
 419 dnl Checks for broken exception-handling. This is needed
 420 dnl because exception handling is broken for some archs/
 421 dnl compilers.
 422 dnl ----------------------------------------------------
 423 AC_DEFUN([MULE_CHECK_EXCEPTIONS],
 424 [AC_LANG_ASSERT([C++])dnl
 425
 426         AC_MSG_CHECKING([for exception-handling])
 427         AC_RUN_IFELSE([
 428                 AC_LANG_PROGRAM(, [[
 429                         try {
 430                                 throw 1;
 431                         } catch (int) {
 432                                 return 0;
 433                         }
 434                         return 1;
 435                 ]])
 436         ], [
 437                 AC_MSG_RESULT([yes])
 438         ], [
 439                 AC_MSG_RESULT([no])
 440                 AC_MSG_ERROR([Exception handling does not work. Broken compiler?])
 441         ], [
 442                 AC_MSG_RESULT([undeterminable])
 443                 MULE_WARNING(
 444                         [Cross-compilation detected, so exception handling cannot be tested.
 445                         Note that broken exception handling in your compiler may lead to unexpected crashes.])
 446         ])
 447 ])
 448
 449
 450 dnl ---------------------------------------------------------------------------
 451 dnl MULE_CHECK_CXXABI
 452 dnl
 453 dnl This function will test the header <cxxabi.h> and abi::__cxa_demangle()
 454 dnl ---------------------------------------------------------------------------
 455 AC_DEFUN([MULE_CHECK_CXXABI],
 456 [AC_LANG_ASSERT([C++])dnl
 457
 458         AC_MSG_CHECKING([for <cxxabi.h> and __cxa_demangle()])
 459         AC_LINK_IFELSE([
 460                 AC_LANG_PROGRAM([[
 461                         #include <cxxabi.h>
 462                 ]], [[
 463                         int status;
 464                         char * demangled = abi::__cxa_demangle("", 0, 0, &status);
 465                         std::type_info *ti = abi::__cxa_current_exception_type();
 466                 ]])
 467         ], [
 468                 AH_TEMPLATE([HAVE_CXXABI], [Define to 1 if you have the <cxxabi.h> header which declares abi::__cxa_demangle()])
 469                 AC_DEFINE([HAVE_CXXABI])
 470                 AC_MSG_RESULT([yes])
 471         ], [
 472                 AC_MSG_RESULT([no])
 473         ])
 474 ])
 475
 476
 477 dnl ---------------------------------------------------------------------------
 478 dnl MULE_CHECK_EXECINFO
 479 dnl
 480 dnl This function will test the header <execinfo.h> and backtrace()
 481 dnl ---------------------------------------------------------------------------
 482 AC_DEFUN([MULE_CHECK_EXECINFO],
 483 [
 484         AC_MSG_CHECKING([for <execinfo.h> and backtrace()])
 485         AC_LINK_IFELSE([
 486                 AC_LANG_PROGRAM([[
 487                         #include <execinfo.h>
 488                 ]], [[
 489                         void *bt[1];
 490                         int n = backtrace(&bt, 1);
 491                         const char **bt_syms = backtrace_symbols(bt, n);
 492                 ]])
 493         ], [
 494                 AH_TEMPLATE([HAVE_EXECINFO], [Define to 1 if you have the <execinfo.h> header which declares backtrace()])
 495                 AC_DEFINE([HAVE_EXECINFO])
 496                 AC_MSG_RESULT([yes])
 497         ], [
 498                 AC_MSG_RESULT([no])
 499         ])
 500 ])
 501
 502
 503 dnl ---------------------------------------------------------------------------
 504 dnl MULE_DENOISER
 505 dnl
 506 dnl Test for denoising level and add denoiser commands to config.status
 507 dnl ---------------------------------------------------------------------------
 508 AC_DEFUN([MULE_DENOISER],
 509 [
 510         AC_ARG_WITH([denoise-level],
 511                 [AS_HELP_STRING([--with-denoise-level=<level>], [Specifies denoising level (0-4):])
 512                 AS_HELP_STRING([], [0 - Do nothing])
 513                 AS_HELP_STRING([], [4 - Suppress all normal output])
 514                 AS_HELP_STRING([], [(for more information see src/utils/scripts/denoiser.rules)])
 515         ])
 516
 517         AC_MSG_CHECKING([denoising level])
 518         AS_IF([test ${with_denoise_level:-5} = yes], [with_denoise_level=5])
 519         AS_IF([test ${with_denoise_level:-5} = no], [with_denoise_level=0])
 520         AS_IF([test ${with_denoise_level:-5} -gt 4],
 521                 [AS_IF([test "${svndate:+set}" = "set"], [with_denoise_level=0], [with_denoise_level=4])])
 522         AC_MSG_RESULT([$with_denoise_level])
 523
 524         AC_CONFIG_COMMANDS([denoiser], [[if test $denoiserlevel -gt 0; then
 525                 if test ! -d src/utils/scripts; then mkdir -p src/utils/scripts; fi
 526                 sed -e "1{x;s/.*/1/;x;};/^[     ]*\$/d;/^#if /{/level.*$denoiserlevel/{x;s/^/1/;x;b0;};x;s/^/0/;x;:0;d;};/^#else/{x;/^1/{s/1/0/;b1;};s/0/1/;:1;x;d;};/^#endif/{x;s/.//;x;d;};/^[        ]*#/d;x;/^1/{x;b;};x;d" \
 527                         $srcdir/src/utils/scripts/denoiser.rules > src/utils/scripts/denoiser.sed
 528                 for i in `find . -name 'Makefile' -print`; do
 529                         if test -n "`head -n 1 $i | grep '^#'`"; then
 530                                 sed -f src/utils/scripts/denoiser.sed $i > $i.tmp && mv $i.tmp $i
 531                         fi
 532                 done
 533         fi]], [denoiserlevel=$with_denoise_level])
 534 ])