configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29
  30 AC_CONFIG_SRCDIR([src/amule.cpp])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_MAINTAINER_MODE
  33
  34 dnl Check host system.
  35 MULE_CHECK_SYSTEM
  36
  37 dnl Checks for programs.
  38 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  39 MULE_BACKUP([CFLAGS])
  40 MULE_BACKUP([CXXFLAGS])
  41 MULE_BACKUP([BUILD_CFLAGS])
  42 AC_PROG_CXX
  43 AC_PROG_CXXCPP
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  47 MULE_RESTORE([CFLAGS])
  48 MULE_RESTORE([CXXFLAGS])
  49 MULE_RESTORE([BUILD_CFLAGS])
  50 AC_PROG_AWK
  51 AC_PROG_EGREP
  52 AC_PROG_MAKE_SET
  53 AC_PROG_LEX
  54 AC_PROG_INSTALL
  55 AC_PROG_RANLIB
  56 AC_PROG_YACC
  57
  58 dnl Find the right ranlib, even when cross-compiling
  59 dnl And for some other tools for cross compilation
  60 AC_CHECK_TOOL(RANLIB, ranlib)
  61 AC_CHECK_TOOL(STRIP, strip)
  62 AC_CHECK_TOOL(AR, ar)
  63 AC_CHECK_TOOL(LD, ld)
  64
  65 dnl Selectable components
  66 MULE_ARG_ENABLE([monolithic],   [yes],  [disable building of the monolithic aMule app], [MONOLITHIC])
  67 MULE_ARG_ENABLE([amule-daemon], [no],   [compile aMule daemon version], [AMULE_DAEMON])
  68 MULE_ARG_ENABLE([amulecmd],     [no],   [compile aMule command line client], [COMPILE_CMD])
  69 MULE_ARG_ENABLE([webserver],    [no],   [compile aMule WebServer], [WEB])
  70 MULE_ARG_ENABLE([amule-gui],    [no],   [compile aMule remote GUI (EXPERIMENTAL)], [AMULE_GUI])
  71 MULE_ARG_ENABLE([cas],          [no],   [compile C aMule Statistics], [CAS])
  72 MULE_ARG_ENABLE([wxcas],        [no],   [compile aMule GUI Statistics], [WXCAS])
  73 MULE_ARG_ENABLE([ed2k],         [yes],  [don't compile aMule ed2k links handler], [ED2K])
  74 MULE_ARG_ENABLE([alc],          [no],   [compile aMuleLinkCreator GUI version], [ALC])
  75 MULE_ARG_ENABLE([alcc],         [no],   [compile aMuleLinkCreator for console], [ALCC])
  76 MULE_ARG_ENABLE([xas],          [no],   [install xas XChat2 plugin], [XAS])
  77 MULE_ARG_ENABLE([fileview],     [no],   [compile aMule file viewer for console (EXPERIMENTAL)], [FILEVIEW])
  78 MULE_ARG_ENABLE([plasmamule],   [no],   [compile aMule plasma applet and engine])
  79
  80 # Run all the tests with static linkage if we want a statically linked binary
  81 MULE_ARG_ENABLE([static], [no], [produce a statically linked executable])
  82 MULE_IF_ENABLED([static], [MULE_APPEND([LDFLAGS], [-static])])
  83
  84 KDE_CONFIG_OPTIONS
  85 QT_CONFIG_OPTIONS
  86
  87 # Default is yes, because they're most likely compatible.
  88 # However, this is only used when cross-compiling.
  89 AC_ARG_WITH(
  90         [gnu-malloc],
  91         [AS_HELP_STRING([--without-gnu-malloc],
  92                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
  93         [gnumalloc=$withval], [gnumalloc=yes])
  94
  95
  96 # Checking for libs before all other stuff to break
  97 # configure as soon as possible in case of a missing one
  98 # to avoid losing too much time
  99
 100 # Check for zlib
 101 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 102         [MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])])
 103
 104 MULE_IF_ENABLED([cas], [
 105         # Check for gd
 106         MULE_CHECK_GDLIB([2.0.0], [
 107                 CAS_DEFS="-D__GD__"
 108                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 109         ], [CAS_DEFS=])
 110         AS_IF([test -z "$CAS_DEFS"],
 111                 [MULE_WARNING(
 112                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 113                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 114                         Or this might also be that your gdlib-config has other name.
 115                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 116                         If you use compiled packages check if you have devel pack installed.
 117                         To download the latest version check http://www.boutell.com/gd for sources.])])
 118 ])
 119 AC_SUBST([CAS_DEFS])dnl
 120
 121 MULE_IF_ENABLED([webserver],
 122         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 123                 MULE_WARNING(
 124                         [libpng >= 1.2.0 not found.
 125                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 126                 ])
 127         ])
 128 AC_SUBST([AMULEWEB_DEFS])dnl
 129
 130 # Check for perl File::Copy
 131 AC_MSG_CHECKING([for File::Copy])
 132 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])],
 133         [MULE_WARNING(
 134                 [File::Copy perl module is required by the mldonkey_importer script.
 135                 If you want to use this script please install File::Copy from CPAN.])])
 136
 137 # Check if we need to install skins
 138 MULE_IF_ENABLED_ANY([monolithic, amule-gui], [INSTALL_SKINS=yes], [INSTALL_SKINS=no])
 139
 140 # Check for GeoIP (required for IP2Country capability)
 141 MULE_IF_ENABLED_ANY([monolithic, amule-gui], [MULE_CHECK_GEOIP])
 142
 143 # Check for wx
 144 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview],
 145         [WX_CONFIG_OPTIONS
 146         WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 147         # Force using a static wxWidgets library if the executable is to be linked statically.
 148         MULE_IF_ENABLED([static], [WX_SHARED=0])
 149         # Force using a unicode build of the library
 150         MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, fileview], [WX_UNICODE=1])
 151         DEBUG=$WX_DEBUG
 152         WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 153         WX_CONFIG_CHECK([2.8.8], [wxWin=1],,, [$WXCONFIG_FLAGS])
 154         AS_IF([test "$wxWin" != 1],
 155                 [AC_MSG_ERROR([
 156                 wxWidgets must be installed on your system but wx-config
 157                 script couldn't be found. Please check that wx-config is
 158                 in path or specified by --with-wx-config=path flag, the
 159                 directory where wxWidgets libraries are installed (returned
 160                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 161                 equivalent variable and wxWidgets version is 2.8.8 or above.
 162                 ])]
 163         )
 164         AS_IF([test "${WX_VERSION_FULL}" = "2.9.0"], [AC_MSG_ERROR([
 165                 This version of wxWidgets is known to not work with aMule.
 166                 Please upgrade to a newer version.]
 167                 )]
 168         )
 169         WX_DETECT_STANDARD_OPTION_VALUES
 170
 171         # We also need wxBase
 172         WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 173         WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 174         WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 175
 176         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 177 ])
 178 AC_SUBST([WXBASE_LIBS])dnl
 179 AC_SUBST([WXBASE_CPPFLAGS])dnl
 180
 181 MULE_IF_ENABLED_ANY([monolithic, amule-gui, wxcas, alc],
 182 [AS_IF([test "${WX_PORT}" = base],
 183         [AC_MSG_ERROR([
 184                 The selected components need a wxWidgets library with GUI,
 185                 but your installation is base-only.  Please install a GUI
 186                 enabled version of wxWidgets and then retry.
 187         ])]
 188 )])
 189
 190 dnl Resource compiler for W32
 191 AC_ARG_VAR([RC], [Resource Compiler])dnl
 192 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 193 AS_IF([test ${SYS:-unknown} = win32], [AC_CHECK_TOOL([RC], [windres], [:])])
 194
 195
 196 # Check for libupnp
 197 MULE_ARG_ENABLE([upnp], [yes], [do not compile UPnP code])
 198 MULE_IF_ENABLED_ANY([monolithic, amule-daemon],, [MULE_ENABLEVAR([upnp])=no])
 199 MULE_IF_ENABLED([upnp], [
 200         LIBUPNP_CHECK(
 201                 [1.6.6],
 202                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 203                 [MULE_ENABLEVAR([upnp])=disabled
 204                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 205         )
 206 ])dnl
 207
 208
 209 # Check for Crypto++
 210 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 211 [MULE_CHECK_CRYPTOPP([5.1], [
 212         # Check for CryptoPP >= 5.5
 213         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 214 ], [
 215         AC_MSG_ERROR([
 216         Could not find crypto++ header file "$cryptopp_file_with_version".
 217         Please try again with --with-crypto-prefix=/my_crypto_prefix
 218         (replace /my_crypto_prefix with a valid path to your crypto++
 219         installation directory).])
 220 ])])
 221
 222 dnl Checks requiring C++
 223 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, ed2k, alc, alcc, wxcas, fileview],
 224 [AC_LANG_PUSH([C++])
 225 MULE_CHECK_GLIBCXX
 226 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, alc, alcc], [MULE_CHECK_WX_SUPPORTS_LARGEFILE])
 227
 228 # Check if the compiler is broken, wrt. exceptions.
 229 MULE_CHECK_EXCEPTIONS
 230
 231 MULE_CHECK_CXXABI
 232 AC_LANG_POP([C++])
 233 ])
 234
 235 # Ok, we have all needed libs, now checking for other stuff
 236 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 237
 238 # Flush standard test results for speeding cache
 239 AC_CACHE_SAVE
 240
 241 dnl -------------------------------------------------------------------------------
 242 dnl Start of autoscan stuff
 243 dnl -------------------------------------------------------------------------------
 244 # Checks for header files.
 245 AC_FUNC_ALLOCA
 246 AC_HEADER_DIRENT
 247 AC_HEADER_STDC
 248 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h  nl_types.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h errno.h signal.h])
 249 AC_HEADER_SYS_WAIT
 250
 251 # Checks for typedefs, structures, and compiler characteristics.
 252 AC_HEADER_STDBOOL
 253 AC_C_CONST
 254 AC_C_INLINE
 255 AC_TYPE_MODE_T
 256 AC_TYPE_OFF_T
 257 AC_TYPE_SIZE_T
 258 AC_HEADER_TIME
 259 AC_STRUCT_TM
 260 AC_TYPE_UID_T
 261 AC_C_VOLATILE
 262 AC_CHECK_TYPES([ptrdiff_t])
 263
 264 # Checks for library functions.
 265 AC_FUNC_CLOSEDIR_VOID
 266 AC_PROG_GCC_TRADITIONAL
 267 AC_FUNC_FORK
 268 AS_IF([test x$SYS != xwin32], [
 269         AC_FUNC_GETMNTENT
 270         AC_FUNC_LSTAT
 271         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 272 ])
 273 AC_FUNC_MEMCMP
 274 AC_FUNC_SELECT_ARGTYPES
 275 AC_FUNC_SETVBUF_REVERSED
 276 AC_TYPE_SIGNAL
 277 AC_FUNC_STAT
 278 AC_FUNC_STRFTIME
 279 AC_FUNC_STRTOD
 280 AC_FUNC_VPRINTF
 281 dnl Some other functions that worth checking deeper:
 282 dnl AC_FUNC_CLOSEDIR_VOID
 283 dnl AC_FUNC_MEMCMP
 284 dnl AC_FUNC_MMAP
 285 dnl AC_FUNC_STAT
 286 dnl AC_FUNC_STRTOD
 287 dnl AC_FUNC_SETVBUF_REVERSED
 288 dnl Anyways, do we actually USE them?
 289 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 290         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 291         ac_cv_func_malloc_0_nonnull=yes
 292         ac_cv_func_realloc_0_nonnull=yes
 293 ])
 294 AC_FUNC_MALLOC
 295 AC_FUNC_REALLOC
 296 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getpass gettimeofday inet_ntoa localeconv memmove mempcpy memset nl_langinfo pow select setlocale socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul sigaction])
 297 #-------------------------------------------------------------------------------
 298 # End of autoscan stuff
 299 #-------------------------------------------------------------------------------
 300
 301 dnl
 302 dnl autoscan has missed these ones.
 303 dnl
 304 AC_CHECK_FUNCS([mkdir getrlimit setrlimit getopt_long])
 305
 306 dnl This must be *before* MULE_CHECK_NLS
 307 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_MMAP])
 308
 309 MULE_BACKUP([CPPFLAGS])
 310 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 311 AC_FUNC_STRERROR_R
 312 MULE_RESTORE([CPPFLAGS])
 313
 314 # Look for a way to preallocate disk space for files.
 315 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_FALLOCATE])
 316
 317 # Checking Native Language Support
 318 dnl Sets gettext version.
 319 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 320 AM_GNU_GETTEXT_VERSION(0.11.5)
 321 MULE_CHECK_NLS
 322
 323 # Check for bfd.h (to have proper backtraces without using wxExecute)
 324 MULE_CHECK_BFD
 325 MULE_CHECK_EXECINFO
 326
 327 # Flush standard test results for speeding cache
 328 AC_CACHE_SAVE
 329
 330 # Other tests
 331 # aMule options
 332 MULE_COMPILATION_FLAGS
 333
 334 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 335 AC_MSG_CHECKING([for docdir])
 336 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 337 AC_SUBST([docdir])dnl
 338 AC_MSG_RESULT([$docdir])
 339
 340 # Try to set the SVN checkout-date
 341 AC_MSG_CHECKING([for SVNDATE])
 342 if test -f "$srcdir/.svn-revision" # SVNDATE for tarballs
 343 then
 344         svndate="rev. `cat $srcdir/.svn-revision`"
 345 elif test -d $srcdir/.svn # SVNDATE for svn
 346 then
 347         svndate="rev. `svnversion $srcdir | sed -e 's/[[0-9]][[0-9]]*:\(.*\)/\1/' -e 's/\([[0-9]][[0-9]]*\).*/\1/'`"
 348 fi
 349 AC_MSG_RESULT(${svndate:-None required})
 350 AS_IF([test -n "$svndate"], [
 351             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 352             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 353 ])
 354 AC_SUBST([SVNDATE], [$svndate])dnl
 355
 356 dnl Set up the denoiser
 357 MULE_DENOISER
 358
 359 AS_IF([test ${PLASMAMULE:-no} = yes],
 360 [PLASMAMULE_CHECKS])
 361
 362 MULE_IF_ENABLED([plasmamule], [PLASMAMULE_CHECKS])
 363
 364 AM_CONDITIONAL(ENABLE_UPNP, test MULE_IS_ENABLED([upnp]))
 365 AM_CONDITIONAL(ENABLE_IP2COUNTRY, test MULE_IS_ENABLED([geoip]))
 366 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 367 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 368 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 369 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 370 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 371 AM_CONDITIONAL(INSTALL_SKINS, test x$INSTALL_SKINS = xyes)
 372 AM_CONDITIONAL(PLASMAMULE, test MULE_IS_ENABLED([plasmamule]))
 373
 374 # Check for readline library
 375 MULE_IF_ENABLED_ANY([amulecmd, webserver], [VL_LIB_READLINE])
 376
 377 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 378
 379 MULE_CHECK_CCACHE
 380
 381 dnl
 382 dnl Generate the Makefiles
 383 dnl
 384 AC_CONFIG_FILES([Makefile
 385                  docs/Makefile
 386                  docs/man/Makefile
 387                  intl/Makefile
 388                  src/Makefile
 389                  src/pixmaps/Makefile
 390                  src/pixmaps/flags_xpm/Makefile
 391                  src/libs/Makefile
 392                  src/libs/ec/Makefile
 393                  src/libs/ec/cpp/Makefile
 394                  src/libs/common/Makefile
 395                  src/utils/Makefile
 396                  src/utils/aLinkCreator/Makefile
 397                  src/utils/aLinkCreator/docs/Makefile
 398                  src/utils/aLinkCreator/src/Makefile
 399                  src/utils/cas/Makefile
 400                  src/utils/cas/docs/Makefile
 401                  src/utils/fileview/Makefile
 402                  src/utils/plasmamule/Makefile
 403                  src/utils/wxCas/Makefile
 404                  src/utils/wxCas/docs/Makefile
 405                  src/utils/wxCas/src/Makefile
 406                  src/utils/xas/Makefile
 407                  src/utils/xas/autostart-xas
 408                  src/utils/xas/docs/Makefile
 409                  src/skins/Makefile
 410                  src/webserver/Makefile
 411                  src/webserver/src/Makefile
 412                  src/webserver/default/Makefile
 413                  unittests/Makefile
 414                  unittests/muleunit/Makefile
 415                  unittests/tests/Makefile])
 416 dnl
 417 dnl autoscan has missed these, i wonder why...
 418 dnl
 419 AC_CONFIG_FILES([po/Makefile.in
 420                  Compilation.flags])
 421 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 422 AC_OUTPUT
 423
 424 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 425
 426 echo
 427 echo
 428 echo "  Configure script has finished system check."
 429 echo
 430 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 431 echo
 432 echo "  aMule enabled options:"
 433 echo
 434 echo "  **** aMule Core ****"
 435 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 436 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 437 echo "  Should aMule be compiled in debug mode?                    MULE_STATUSOF([debug])"
 438 echo "  Should aMule be compiled with profiling?                   MULE_STATUSOF([profile])"
 439 echo "  Should aMule be compiled with optimizations?               MULE_STATUSOF([optimize])"
 440 echo "  Should aMule be compiled with UPnP support?                MULE_STATUSOF([upnp])"
 441 echo "  Should aMule be compiled with IP2country support?          MULE_STATUSOF([geoip])"
 442 echo "  Should aMule monolithic application be built?              MULE_STATUSOF([monolithic])"
 443 echo "  Should aMule daemon version be built?                      MULE_STATUSOF([amule-daemon])"
 444 echo "  Should aMule remote gui be built? (EXPERIMENTAL)           MULE_STATUSOF([amule-gui])"
 445 echo "  Crypto++ library/headers style?                            ${CRYPTOPP_STYLE:-not found}"
 446
 447 echo
 448 echo "  **** aMule TextClient ****"
 449 echo "  Should aMule Command Line Client be built?                 MULE_STATUSOF([amulecmd])"
 450 echo
 451 echo "  **** aMule WebServer ****"
 452 echo "  Should aMule WebServer be built?                           MULE_STATUSOF([webserver])"
 453 echo
 454 echo "  **** aMule ED2K Links Handler ****"
 455 echo "  Should aMule ED2K Links Handler be built?                  MULE_STATUSOF([ed2k])"
 456 echo
 457 echo "  **** aMuleLinkCreator ****"
 458 echo "  Should aMuleLinkCreator GUI version (alc) be built?        MULE_STATUSOF([alc])"
 459 echo "  Should aMuleLinkCreator for console (alcc) be built?       MULE_STATUSOF([alcc])"
 460 echo
 461 echo "  **** aMule Statistics ****"
 462 echo "  Should C aMule Statistics (CAS) be built?                  MULE_STATUSOF([cas])"
 463 echo "  Should aMule GUI Statistics (wxCas) be built?              MULE_STATUSOF([wxcas])"
 464 echo "  Should xas XChat2 plugin be installed?                     MULE_STATUSOF([xas])"
 465 echo "  Should plasmaMule plasma-applet be build?                  MULE_STATUSOF([plasmamule])"
 466
 467 echo
 468 echo "  **** General Libraries and Tools ****"
 469 echo "  Should ccache support be enabled?                          MULE_STATUSOF([ccache])"
 470 echo "  Libraries aMule will use to build:"
 471 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview], [
 472         wxinfo="$WX_PORT"
 473         AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 474         AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 475         echo "                                       wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 476 ])
 477 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 478         [echo "                                       crypto++              ${CRYPTOPP_VERSION_STRING} (${CRYPTOPP_STYLE}, in ${CRYPTOPP_PREFIX})"])
 479 MULE_IF_ENABLED([upnp], [
 480         AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 481         echo "                                       libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"
 482 ])
 483 if test ${enable_nls:-yes} = yes; then
 484 AS_IF([test x$USE_NLS = xno],
 485         [libintl_found="Not detected"],
 486         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 487                 [libintl_found="included"],
 488                 [libintl_found="system"])])
 489 echo "                                       libintl               $libintl_found"
 490 fi
 491 MULE_IF_ENABLED([geoip],
 492         [AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 493         MULE_IF_ENABLED_ANY([monolithic, amule-gui],
 494                 [echo "                                       libGeoIP              ${geoip_style}"])])
 495 MULE_IF_ENABLED([webserver],
 496         [echo "                                       libpng                ${LIBPNG_VERSION:-Not detected}"])
 497 MULE_IF_ENABLED([cas],
 498         [echo "                                       libgd                 ${GDLIB_VERSION:-Not detected}"])
 499 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 500         [echo "                                       zlib                  ${ZLIB_VERSION:-Not detected}"])
 501 MULE_IF_ENABLED([plasmamule],
 502 [echo "                                       qt-moc                ${QT_MOC} ${QT_MOC_VERSION}"
 503 echo "                                       qt-core-libs          ${QT_CORE_LIBS}"
 504 echo "                                       qt-gui-libs           ${QT_GUI_LIBS}"
 505 echo "                                       kde4-config           ${KDE4_CONFIG} (${KDE_CONF_VER})"
 506 echo "                                       kde-headers           ${KDE_HEADER_DIR}"
 507 echo "                                       kde-services-path     ${KDE_SERVICE_PATH}"
 508 echo "                                       kde-module-path       ${KDE_MODULE_PATH}"
 509 echo "                                       kde-icon-path         ${KDE_ICON_PATH}"
 510 echo "  **** You have to run kbuildsycoca after installing to let plasma know the changes ****"])