configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2011 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  30
  31 AC_PREREQ(2.59)
  32
  33 AC_CONFIG_SRCDIR([src/amule.cpp])
  34 AC_CONFIG_HEADERS([config.h])
  35 AM_MAINTAINER_MODE
  36
  37 dnl Check host system.
  38 MULE_CHECK_SYSTEM
  39
  40 dnl Checks for programs.
  41 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  42 MULE_BACKUP([CFLAGS])
  43 MULE_BACKUP([CXXFLAGS])
  44 MULE_BACKUP([BUILD_CFLAGS])
  45 AC_PROG_CXX
  46 AC_PROG_CXXCPP
  47 AC_PROG_CC
  48 AC_PROG_CPP
  49 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  50 MULE_RESTORE([CFLAGS])
  51 MULE_RESTORE([CXXFLAGS])
  52 MULE_RESTORE([BUILD_CFLAGS])
  53 AC_PROG_AWK
  54 AC_PROG_EGREP
  55 AC_PROG_MAKE_SET
  56 AC_PROG_LEX
  57 AC_PROG_INSTALL
  58 AC_PROG_RANLIB
  59 AC_PROG_YACC
  60
  61 dnl Find the right ranlib, even when cross-compiling
  62 dnl And for some other tools for cross compilation
  63 AC_CHECK_TOOL(RANLIB, ranlib)
  64 AC_CHECK_TOOL(STRIP, strip)
  65 AC_CHECK_TOOL(AR, ar)
  66 AC_CHECK_TOOL(LD, ld)
  67
  68 dnl Selectable components
  69 MULE_ARG_ENABLE([monolithic],   [yes],  [disable building of the monolithic aMule app], [MONOLITHIC])
  70 MULE_ARG_ENABLE([amule-daemon], [no],   [compile aMule daemon version], [AMULE_DAEMON])
  71 MULE_ARG_ENABLE([amulecmd],     [no],   [compile aMule command line client], [COMPILE_CMD])
  72 MULE_ARG_ENABLE([webserver],    [no],   [compile aMule WebServer], [WEB])
  73 MULE_ARG_ENABLE([amule-gui],    [no],   [compile aMule remote GUI], [AMULE_GUI])
  74 MULE_ARG_ENABLE([cas],          [no],   [compile C aMule Statistics], [CAS])
  75 MULE_ARG_ENABLE([wxcas],        [no],   [compile aMule GUI Statistics], [WXCAS])
  76 MULE_ARG_ENABLE([ed2k],         [yes],  [don't compile aMule ed2k links handler], [ED2K])
  77 MULE_ARG_ENABLE([alc],          [no],   [compile aMuleLinkCreator GUI version], [ALC])
  78 MULE_ARG_ENABLE([alcc],         [no],   [compile aMuleLinkCreator for console], [ALCC])
  79 MULE_ARG_ENABLE([xas],          [no],   [install xas XChat2 plugin], [XAS])
  80 MULE_ARG_ENABLE([fileview],     [no],   [compile aMule file viewer for console (EXPERIMENTAL)], [FILEVIEW])
  81 MULE_ARG_ENABLE([plasmamule],   [no],   [compile aMule plasma applet and engine])
  82
  83 # Run all the tests with static linkage if we want a statically linked binary
  84 MULE_ARG_ENABLE([static], [no], [produce a statically linked executable])
  85 MULE_IF_ENABLED([static], [MULE_APPEND([LDFLAGS], [-static])])
  86
  87 KDE_CONFIG_OPTIONS
  88 QT_CONFIG_OPTIONS
  89
  90 # Default is yes, because they're most likely compatible.
  91 # However, this is only used when cross-compiling.
  92 AC_ARG_WITH(
  93         [gnu-malloc],
  94         [AS_HELP_STRING([--without-gnu-malloc],
  95                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
  96         [gnumalloc=$withval], [gnumalloc=yes])
  97
  98
  99 # Checking for libs before all other stuff to break
 100 # configure as soon as possible in case of a missing one
 101 # to avoid losing too much time
 102
 103 # Check for zlib
 104 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 105         [MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])])
 106
 107 MULE_IF_ENABLED([cas], [
 108         # Check for gd
 109         MULE_CHECK_GDLIB([2.0.0], [
 110                 CAS_DEFS="-D__GD__"
 111                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 112         ], [CAS_DEFS=])
 113         AS_IF([test -z "$CAS_DEFS"],
 114                 [MULE_WARNING(
 115                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 116                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 117                         Or this might also be that your gdlib-config has other name.
 118                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 119                         If you use compiled packages check if you have devel pack installed.
 120                         To download the latest version check http://www.boutell.com/gd for sources.])])
 121 ])
 122 AC_SUBST([CAS_DEFS])dnl
 123
 124 MULE_IF_ENABLED([webserver],
 125         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 126                 MULE_WARNING(
 127                         [libpng >= 1.2.0 not found.
 128                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 129                 ])
 130         ])
 131 AC_SUBST([AMULEWEB_DEFS])dnl
 132
 133 # Check for perl File::Copy
 134 AC_MSG_CHECKING([for File::Copy])
 135 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])],
 136         [MULE_WARNING(
 137                 [File::Copy perl module is required by the mldonkey_importer script.
 138                 If you want to use this script please install File::Copy from CPAN.])])
 139
 140 # Check if we need to install skins
 141 MULE_IF_ENABLED_ANY([monolithic, amule-gui], [INSTALL_SKINS=yes], [INSTALL_SKINS=no])
 142
 143 # Check for GeoIP (required for IP2Country capability)
 144 MULE_IF_ENABLED_ANY([monolithic, amule-gui], [MULE_CHECK_GEOIP])
 145
 146 # Check for wx
 147 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview],
 148         [WX_CONFIG_OPTIONS
 149         WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 150         # Force using a static wxWidgets library if the executable is to be linked statically.
 151         MULE_IF_ENABLED([static], [WX_SHARED=0])
 152         # Force using a unicode build of the library
 153         MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, fileview], [WX_UNICODE=1])
 154         DEBUG=$WX_DEBUG
 155         WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 156         WX_CONFIG_CHECK([2.8.12], [wxWin=1],,, [$WXCONFIG_FLAGS])
 157         AS_IF([test "$wxWin" != 1],
 158                 [AC_MSG_ERROR([
 159                 wxWidgets must be installed on your system but wx-config
 160                 script couldn't be found. Please check that wx-config is
 161                 in path or specified by --with-wx-config=path flag, the
 162                 directory where wxWidgets libraries are installed (returned
 163                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 164                 equivalent variable and wxWidgets version is 2.8.12 or above.
 165                 ])]
 166         )
 167         AS_IF([test "${WX_VERSION_FULL}" = "2.9.0"], [AC_MSG_ERROR([
 168                 This version of wxWidgets is known to not work with aMule.
 169                 Please upgrade to a newer version.]
 170                 )]
 171         )
 172         WX_DETECT_STANDARD_OPTION_VALUES
 173
 174         # We also need wxBase
 175         WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 176         WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 177         WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 178
 179         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 180 ])
 181 AC_SUBST([WXBASE_LIBS])dnl
 182 AC_SUBST([WXBASE_CPPFLAGS])dnl
 183
 184 MULE_IF_ENABLED_ANY([monolithic, amule-gui, wxcas, alc],
 185 [AS_IF([test "${WX_PORT}" = base],
 186         [AC_MSG_ERROR([
 187                 The selected components need a wxWidgets library with GUI,
 188                 but your installation is base-only.  Please install a GUI
 189                 enabled version of wxWidgets and then retry.
 190         ])]
 191 )])
 192
 193 dnl Resource compiler for W32
 194 AC_ARG_VAR([RC], [Resource Compiler])dnl
 195 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 196 AS_IF([test ${SYS:-unknown} = win32], [AC_CHECK_TOOL([RC], [windres], [:])])
 197
 198
 199 # Check for libupnp
 200 MULE_ARG_ENABLE([upnp], [yes], [do not compile UPnP code])
 201 MULE_IF_ENABLED_ANY([monolithic, amule-daemon],, [MULE_ENABLEVAR([upnp])=no])
 202 MULE_IF_ENABLED([upnp], [
 203         LIBUPNP_CHECK(
 204                 [1.6.6],
 205                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 206                 [MULE_ENABLEVAR([upnp])=disabled
 207                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 208         )
 209 ])dnl
 210
 211
 212 # Check for Crypto++
 213 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 214 [MULE_CHECK_CRYPTOPP([5.1], [
 215         # Check for CryptoPP >= 5.5
 216         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 217 ], [
 218         AC_MSG_ERROR([
 219         Could not find crypto++ header file "$cryptopp_file_with_version".
 220         Please try again with --with-crypto-prefix=/my_crypto_prefix
 221         (replace /my_crypto_prefix with a valid path to your crypto++
 222         installation directory).])
 223 ])])
 224
 225 dnl Checks requiring C++
 226 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, ed2k, alc, alcc, wxcas, fileview],
 227 [AC_LANG_PUSH([C++])
 228 MULE_CHECK_GLIBCXX
 229 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, alc, alcc], [MULE_CHECK_WX_SUPPORTS_LARGEFILE])
 230
 231 # Check if the compiler is broken, wrt. exceptions.
 232 MULE_CHECK_EXCEPTIONS
 233
 234 MULE_CHECK_CXXABI
 235 AC_LANG_POP([C++])
 236 ])
 237
 238 # Ok, we have all needed libs, now checking for other stuff
 239 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 240
 241 # Flush standard test results for speeding cache
 242 AC_CACHE_SAVE
 243
 244 dnl -------------------------------------------------------------------------------
 245 dnl Start of autoscan stuff
 246 dnl -------------------------------------------------------------------------------
 247 # Checks for header files.
 248 AC_FUNC_ALLOCA
 249 AC_HEADER_DIRENT
 250 AC_HEADER_STDC
 251 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h  nl_types.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h errno.h signal.h])
 252 AC_HEADER_SYS_WAIT
 253
 254 # Checks for typedefs, structures, and compiler characteristics.
 255 AC_HEADER_STDBOOL
 256 AC_C_CONST
 257 AC_C_INLINE
 258 AC_TYPE_MODE_T
 259 AC_TYPE_OFF_T
 260 AC_TYPE_SIZE_T
 261 AC_HEADER_TIME
 262 AC_STRUCT_TM
 263 AC_TYPE_UID_T
 264 AC_C_VOLATILE
 265 AC_CHECK_TYPES([ptrdiff_t])
 266
 267 # Checks for library functions.
 268 AC_FUNC_CLOSEDIR_VOID
 269 AC_PROG_GCC_TRADITIONAL
 270 AC_FUNC_FORK
 271 AS_IF([test x$SYS != xwin32], [
 272         AC_FUNC_GETMNTENT
 273         AC_FUNC_LSTAT
 274         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 275 ])
 276 AC_FUNC_MEMCMP
 277 AC_FUNC_SELECT_ARGTYPES
 278 AC_FUNC_SETVBUF_REVERSED
 279 AC_TYPE_SIGNAL
 280 AC_FUNC_STAT
 281 AC_FUNC_STRFTIME
 282 AC_FUNC_STRTOD
 283 AC_FUNC_VPRINTF
 284 dnl Some other functions that worth checking deeper:
 285 dnl AC_FUNC_CLOSEDIR_VOID
 286 dnl AC_FUNC_MEMCMP
 287 dnl AC_FUNC_MMAP
 288 dnl AC_FUNC_STAT
 289 dnl AC_FUNC_STRTOD
 290 dnl AC_FUNC_SETVBUF_REVERSED
 291 dnl Anyways, do we actually USE them?
 292 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 293         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 294         ac_cv_func_malloc_0_nonnull=yes
 295         ac_cv_func_realloc_0_nonnull=yes
 296 ])
 297 AC_FUNC_MALLOC
 298 AC_FUNC_REALLOC
 299 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getpass gettimeofday inet_ntoa localeconv memmove mempcpy memset nl_langinfo pow select setlocale socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul sigaction])
 300 #-------------------------------------------------------------------------------
 301 # End of autoscan stuff
 302 #-------------------------------------------------------------------------------
 303
 304 dnl
 305 dnl autoscan has missed these ones.
 306 dnl
 307 AC_CHECK_FUNCS([mkdir getrlimit setrlimit getopt_long])
 308
 309 dnl This must be *before* MULE_CHECK_NLS
 310 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_MMAP])
 311
 312 MULE_BACKUP([CPPFLAGS])
 313 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 314 AC_FUNC_STRERROR_R
 315 MULE_RESTORE([CPPFLAGS])
 316
 317 # Look for a way to preallocate disk space for files.
 318 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_FALLOCATE])
 319
 320 # Checking Native Language Support
 321 dnl Sets gettext version.
 322 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 323 AM_GNU_GETTEXT_VERSION(0.11.5)
 324 MULE_CHECK_NLS
 325
 326 # Check for bfd.h (to have proper backtraces without using wxExecute)
 327 MULE_CHECK_BFD
 328 MULE_CHECK_EXECINFO
 329
 330 # Flush standard test results for speeding cache
 331 AC_CACHE_SAVE
 332
 333 # Other tests
 334 # aMule options
 335 MULE_COMPILATION_FLAGS
 336
 337 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 338 AC_MSG_CHECKING([for docdir])
 339 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 340 AC_SUBST([docdir])dnl
 341 AC_MSG_RESULT([$docdir])
 342
 343 # Try to set the SVN checkout-date
 344 AC_MSG_CHECKING([for SVNDATE])
 345 if test -f "$srcdir/.svn-revision" # SVNDATE for tarballs
 346 then
 347         svndate="rev. `cat $srcdir/.svn-revision`"
 348 elif test -d $srcdir/.svn # SVNDATE for svn
 349 then
 350         svndate="rev. `svnversion $srcdir | sed -e 's/[[0-9]][[0-9]]*:\(.*\)/\1/' -e 's/\([[0-9]][[0-9]]*\).*/\1/'`"
 351 fi
 352 AC_MSG_RESULT(${svndate:-None required})
 353 AS_IF([test -n "$svndate"], [
 354             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 355             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 356 ])
 357 AC_SUBST([SVNDATE], [$svndate])dnl
 358
 359 dnl Set up the denoiser
 360 MULE_DENOISER
 361
 362 MULE_IF_ENABLED([plasmamule], [PLASMAMULE_CHECKS])
 363
 364 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 365 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 366 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 367 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 368 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 369 AM_CONDITIONAL(INSTALL_SKINS, test x$INSTALL_SKINS = xyes)
 370 AM_CONDITIONAL(PLASMAMULE, test MULE_IS_ENABLED([plasmamule]))
 371
 372 AM_CONDITIONAL([COMPILE_LIB_COMMON],    [test MULE_IS_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui, fileview])])
 373 AM_CONDITIONAL([COMPILE_LIB_EC],        [test MULE_IS_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui])])
 374
 375 # Check for readline library
 376 MULE_IF_ENABLED_ANY([amulecmd, webserver], [VL_LIB_READLINE])
 377
 378 AS_IF([test ${PLASMAMULE:-no} = yes],
 379 [PLASMAMULE_CHECKS])
 380
 381 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 382
 383 MULE_CHECK_CCACHE
 384
 385 dnl
 386 dnl Generate the Makefiles
 387 dnl
 388 AC_CONFIG_FILES([Makefile
 389                  docs/Makefile
 390                  docs/man/Makefile
 391                  intl/Makefile
 392                  src/Makefile
 393                  src/pixmaps/Makefile
 394                  src/pixmaps/flags_xpm/Makefile
 395                  src/libs/Makefile
 396                  src/libs/ec/Makefile
 397                  src/libs/ec/cpp/Makefile
 398                  src/libs/common/Makefile
 399                  src/utils/Makefile
 400                  src/utils/aLinkCreator/Makefile
 401                  src/utils/aLinkCreator/docs/Makefile
 402                  src/utils/aLinkCreator/src/Makefile
 403                  src/utils/cas/Makefile
 404                  src/utils/cas/docs/Makefile
 405                  src/utils/fileview/Makefile
 406                  src/utils/plasmamule/Makefile
 407                  src/utils/wxCas/Makefile
 408                  src/utils/wxCas/docs/Makefile
 409                  src/utils/wxCas/src/Makefile
 410                  src/utils/xas/Makefile
 411                  src/utils/xas/autostart-xas
 412                  src/utils/xas/docs/Makefile
 413                  src/skins/Makefile
 414                  src/webserver/Makefile
 415                  src/webserver/src/Makefile
 416                  src/webserver/default/Makefile
 417                  unittests/Makefile
 418                  unittests/muleunit/Makefile
 419                  unittests/tests/Makefile])
 420 dnl
 421 dnl autoscan has missed these, i wonder why...
 422 dnl
 423 AC_CONFIG_FILES([po/Makefile.in
 424                  Compilation.flags])
 425 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 426 AC_OUTPUT
 427
 428 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 429
 430 echo
 431 echo
 432 echo "  Configure script has finished system check."
 433 echo
 434 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 435 echo
 436 echo "  aMule enabled options:"
 437 echo
 438 echo "  **** aMule Core ****"
 439 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 440 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 441 echo "  Should aMule be compiled in debug mode?                    MULE_STATUSOF([debug])"
 442 echo "  Should aMule be compiled with profiling?                   MULE_STATUSOF([profile])"
 443 echo "  Should aMule be compiled with optimizations?               MULE_STATUSOF([optimize])"
 444 echo "  Should aMule be compiled with UPnP support?                MULE_STATUSOF([upnp])"
 445 echo "  Should aMule be compiled with IP2country support?          MULE_STATUSOF([geoip])"
 446 echo "  Should aMule monolithic application be built?              MULE_STATUSOF([monolithic])"
 447 echo "  Should aMule daemon version be built?                      MULE_STATUSOF([amule-daemon])"
 448 echo "  Should aMule remote gui be built?                          MULE_STATUSOF([amule-gui])"
 449 echo "  Crypto++ library/headers style?                            ${CRYPTOPP_STYLE:-not found}"
 450
 451 echo
 452 echo "  **** aMule TextClient ****"
 453 echo "  Should aMule Command Line Client be built?                 MULE_STATUSOF([amulecmd])"
 454 echo
 455 echo "  **** aMule WebServer ****"
 456 echo "  Should aMule WebServer be built?                           MULE_STATUSOF([webserver])"
 457 echo
 458 echo "  **** aMule ED2K Links Handler ****"
 459 echo "  Should aMule ED2K Links Handler be built?                  MULE_STATUSOF([ed2k])"
 460 echo
 461 echo "  **** aMuleLinkCreator ****"
 462 echo "  Should aMuleLinkCreator GUI version (alc) be built?        MULE_STATUSOF([alc])"
 463 echo "  Should aMuleLinkCreator for console (alcc) be built?       MULE_STATUSOF([alcc])"
 464 echo
 465 echo "  **** aMule Statistics ****"
 466 echo "  Should C aMule Statistics (CAS) be built?                  MULE_STATUSOF([cas])"
 467 echo "  Should aMule GUI Statistics (wxCas) be built?              MULE_STATUSOF([wxcas])"
 468 echo "  Should xas XChat2 plugin be installed?                     MULE_STATUSOF([xas])"
 469 echo "  Should plasmaMule plasma-applet be build?                  MULE_STATUSOF([plasmamule])"
 470
 471 echo
 472 echo "  **** General Libraries and Tools ****"
 473 echo "  Should ccache support be enabled?                          MULE_STATUSOF([ccache])"
 474 echo "  Libraries aMule will use to build:"
 475 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview], [
 476         wxinfo="$WX_PORT"
 477         AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 478         AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 479         echo "                             wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 480 ])
 481 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 482         [echo "                             crypto++              ${CRYPTOPP_VERSION_STRING} (${CRYPTOPP_STYLE}, in ${CRYPTOPP_PREFIX})"])
 483 MULE_IF_ENABLED([upnp], [
 484         AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 485         echo "                             libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"
 486 ])
 487 if test ${enable_nls:-yes} = yes; then
 488 AS_IF([test x$USE_NLS = xno],
 489         [libintl_found="Not detected"],
 490         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 491                 [libintl_found="included"],
 492                 [libintl_found="system"])])
 493 echo "                             libintl               $libintl_found"
 494 fi
 495 MULE_IF_ENABLED([geoip],
 496         [AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 497         MULE_IF_ENABLED_ANY([monolithic, amule-gui],
 498                 [echo "                             libGeoIP              ${geoip_style}"])])
 499 MULE_IF_ENABLED([webserver],
 500         [echo "                             libpng                ${LIBPNG_VERSION:-Not detected}"])
 501 MULE_IF_ENABLED([cas],
 502         [echo "                             libgd                 ${GDLIB_VERSION:-Not detected}"])
 503 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 504         [echo "                             zlib                  ${ZLIB_VERSION:-Not detected}"])
 505 MULE_IF_ENABLED([plasmamule],
 506 [echo "                             qt-moc                ${QT_MOC} ${QT_MOC_VERSION}"
 507 echo "                             qt-core-libs          ${QT_CORE_LIBS}"
 508 echo "                             qt-gui-libs           ${QT_GUI_LIBS}"
 509 echo "                             kde4-config           ${KDE4_CONFIG} (${KDE_CONF_VER})"
 510 echo "                             kde-headers           ${KDE_HEADER_DIR}"
 511 echo "                             kde-services-path     ${KDE_SERVICE_PATH}"
 512 echo "                             kde-module-path       ${KDE_MODULE_PATH}"
 513 echo "                             kde-icon-path         ${KDE_ICON_PATH}"
 514 echo "                             kde-mime-path         ${KDE_MIME_PATH}"
 515 echo "                             kde-applinks-path     ${KDE_APPLNK_PATH}"
 516 ])