configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29
  30 AC_CONFIG_SRCDIR([src/amule.cpp])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_MAINTAINER_MODE
  33
  34 dnl Check host system.
  35 MULE_CHECK_SYSTEM
  36
  37 dnl Checks for programs.
  38 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  39 MULE_BACKUP([CFLAGS])
  40 MULE_BACKUP([CXXFLAGS])
  41 MULE_BACKUP([BUILD_CFLAGS])
  42 AC_PROG_CXX
  43 AC_PROG_CXXCPP
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  47 MULE_RESTORE([CFLAGS])
  48 MULE_RESTORE([CXXFLAGS])
  49 MULE_RESTORE([BUILD_CFLAGS])
  50 AC_PROG_AWK
  51 AC_PROG_EGREP
  52 AC_PROG_MAKE_SET
  53 AC_PROG_LEX
  54 AC_PROG_INSTALL
  55 AC_PROG_RANLIB
  56 AC_PROG_YACC
  57
  58 dnl Find the right ranlib, even when cross-compiling
  59 dnl And for some other tools for cross compilation
  60 AC_CHECK_TOOL(RANLIB, ranlib)
  61 AC_CHECK_TOOL(STRIP, strip)
  62 AC_CHECK_TOOL(AR, ar)
  63 AC_CHECK_TOOL(LD, ld)
  64
  65 dnl
  66 dnl Add args to configure
  67 dnl
  68 AC_ARG_ENABLE(
  69         [monolithic],
  70         [AS_HELP_STRING(
  71                 [--disable-monolithic],
  72                 [disable building of the monolithic aMule app])],
  73         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
  74
  75 AC_ARG_ENABLE(
  76         [amule-daemon],
  77         [AS_HELP_STRING(
  78                 [--enable-amule-daemon],
  79                 [compile aMule daemon version])],
  80         [AMULE_DAEMON=$enableval], [AMULE_DAEMON=no])
  81
  82 AC_ARG_ENABLE(
  83         [amulecmd],
  84         [AS_HELP_STRING(
  85                 [--enable-amulecmd],
  86                 [compile aMule command line client])],
  87         [AMULECMD=$enableval], [AMULECMD=no])
  88
  89 AC_ARG_ENABLE(
  90         [webserver],
  91         [AS_HELP_STRING(
  92                 [--enable-webserver],
  93                 [compile aMule WebServer])],
  94         [WEB=$enableval], [WEB=no])
  95
  96 AC_ARG_ENABLE(
  97         [amule-gui],
  98         [AS_HELP_STRING(
  99                 [--enable-amule-gui],
 100                 [compile aMule remote GUI (EXPERIMENTAL)])],
 101         [AMULE_GUI=$enableval], [AMULE_GUI=no])
 102
 103 AC_ARG_ENABLE(
 104         [cas],
 105         [AS_HELP_STRING(
 106                 [--enable-cas],
 107                 [compile C aMule Statistics])],
 108         [CAS=$enableval], [CAS=no])
 109
 110 AC_ARG_ENABLE(
 111         [wxcas],
 112         [AS_HELP_STRING(
 113                 [--enable-wxcas],
 114                 [compile aMule GUI Statistics])],
 115         [WXCAS=$enableval], [WXCAS=no])
 116
 117 AC_ARG_ENABLE(
 118         [ed2k],
 119         [AS_HELP_STRING(
 120                 [--disable-ed2k],
 121                 [don't compile aMule ed2k links handler])],
 122         [ED2K=$enableval], [ED2K=yes])
 123
 124 AC_ARG_ENABLE(
 125         [alc],
 126         [AS_HELP_STRING(
 127                 [--enable-alc],
 128                 [compile aMuleLinkCreator GUI version])],
 129         [ALC=$enableval], [ALC=no])
 130
 131 AC_ARG_ENABLE(
 132         [alcc],
 133         [AS_HELP_STRING(
 134                 [--enable-alcc],
 135                 [compile aMuleLinkCreator for console])],
 136         [ALCC=$enableval], [ALCC=no])
 137
 138 AC_ARG_ENABLE(
 139         [monolithic],
 140         [AS_HELP_STRING(
 141                 [--disable-monolithic],
 142                 [disable building of the monolithic aMule app])],
 143         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
 144
 145 AC_ARG_ENABLE(
 146         [upnp],
 147         [AS_HELP_STRING(
 148                 [--disable-upnp],
 149                 [do not compile UPnP code])],
 150         [ENABLE_UPNP=$enableval], [ENABLE_UPNP=yes])
 151
 152 AC_ARG_ENABLE(
 153         [xas],
 154         [AS_HELP_STRING(
 155                 [--enable-xas],
 156                 [install xas XChat2 plugin])],
 157         [XAS=$enableval], [XAS=no])
 158
 159 AC_ARG_ENABLE(
 160         [fileview],
 161         [AS_HELP_STRING(
 162                 [--enable-fileview],
 163                 [compile aMule file viewer for console (EXPERIMENTAL)])],
 164         [FILEVIEW=$enableval], [FILEVIEW=no])
 165
 166 # Default is yes, because they're most likely compatible.
 167 # However, this is only used when cross-compiling.
 168 AC_ARG_WITH(
 169         [gnu-malloc],
 170         [AS_HELP_STRING([--without-gnu-malloc],
 171                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
 172         [gnumalloc=$withval], [gnumalloc=yes])
 173
 174
 175 # Checking for libs before all other stuff to break
 176 # configure as soon as possible in case of a missing one
 177 # to avoid losing too much time
 178
 179 # Check for zlib
 180 MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])
 181
 182 AS_IF([test x$CAS = xyes], [
 183         # Check for gd
 184         MULE_CHECK_GDLIB([2.0.0], [
 185                 CAS_DEFS="-D__GD__"
 186                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 187         ], [CAS_DEFS=])
 188         AS_IF([test -z "$CAS_DEFS"],
 189                 [MULE_WARNING(
 190                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 191                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 192                         Or this might also be that your gdlib-config has other name.
 193                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 194                         If you use compiled packages check if you have devel pack installed.
 195                         To download the latest version check http://www.boutell.com/gd for sources.])])
 196 ], [GDLIB_VERSION="not_needed"])
 197 AC_SUBST([CAS_DEFS])dnl
 198
 199
 200 AS_IF([test x$WEB = xyes],
 201         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 202                 MULE_WARNING(
 203                         [libpng >= 1.2.0 not found.
 204                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 205                 ])
 206         ], [LIBPNG_VERSION="not_needed"])
 207 AC_SUBST([AMULEWEB_DEFS])dnl
 208
 209
 210 # Check for perl File::Copy
 211 AC_MSG_CHECKING([for File::Copy])
 212 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])], [AC_MSG_ERROR([File::Copy perl module is required])])
 213
 214
 215 # Check if we need the GUI
 216 AC_MSG_CHECKING([whether we need the GUI])
 217 AS_IF([test x$MONOLITHIC = xyes], [need_gui=yes])
 218 AS_IF([test x$WXCAS = xyes], [need_gui=yes])
 219 AS_IF([test x$ALC = xyes], [need_gui=yes])
 220 AS_IF([test x$AMULE_GUI = xyes], [need_gui=yes])
 221 AS_IF([test x${need_gui:+set} != xset], [need_gui=no])
 222 AC_MSG_RESULT($need_gui)
 223
 224 # Check if we need to install skins
 225 AS_IF([test x$MONOLITHIC = xyes], [INSTALL_SKINS=yes])
 226 AS_IF([test x$AMULE_GUI = xyes], [INSTALL_SKINS=yes])
 227 AS_IF([test x${INSTALL_SKINS:+set} != xset], [INSTALL_SKINS=no])
 228
 229 # Check for GeoIP (required for IP2Country capability)
 230 MULE_CHECK_GEOIP
 231
 232 # Check for wx
 233 WX_CONFIG_OPTIONS
 234 WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 235 # Force using a static wxWidgets library if the executable is to be linked statically.
 236 AS_IF([test ${enable_static:-no} = yes], [WX_SHARED=0])
 237 # Force using a unicode build of the library
 238 WX_UNICODE=1
 239 DEBUG=$WX_DEBUG
 240 WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 241 WX_CONFIG_CHECK([2.8.8], [wxWin=1],,, [$WXCONFIG_FLAGS])
 242 if test "$wxWin" != 1; then
 243         AC_MSG_ERROR([
 244                 wxWidgets must be installed on your system but wx-config
 245                 script couldn't be found. Please check that wx-config is
 246                 in path or specified by --with-wx-config=path flag, the
 247                 directory where wxWidgets libraries are installed (returned
 248                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 249                 equivalent variable and wxWidgets version is 2.8.8 or above.
 250         ])
 251 fi
 252 WX_DETECT_STANDARD_OPTION_VALUES
 253
 254 # We also need wxBase
 255 WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 256 WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 257 WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 258 AC_SUBST([WXBASE_LIBS])
 259 AC_SUBST([WXBASE_CPPFLAGS])
 260
 261 AS_IF([test ${need_gui} = yes -a "${WX_PORT}" = base],
 262         [AC_MSG_ERROR([
 263                 The selected components need a wxWidgets library with GUI,
 264                 but your installation is base-only.  Please install a GUI
 265                 enabled version of wxWidgets and then retry.
 266         ])]
 267 )
 268
 269 dnl Get flags for windres
 270 AC_ARG_VAR([RC], [Resource Compiler])dnl
 271 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 272 AS_IF([test ${SYS:-unknown} = win32],
 273 [
 274         AC_CHECK_TOOL([RC], [windres], [:])
 275         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 276 ])
 277
 278
 279 # Check for libupnp
 280 AS_IF([test "${ENABLE_UPNP:-yes}" = yes], [
 281         LIBUPNP_CHECK(
 282                 [1.6.6],
 283                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 284                 [ENABLE_UPNP=disabled
 285                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 286         )
 287 ])dnl
 288
 289
 290 # Check for Crypto++
 291 MULE_CHECK_CRYPTOPP([5.1], [
 292         # Check for CryptoPP >= 5.5
 293         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 294 ], [
 295         AC_MSG_ERROR([
 296         Could not find crypto++ header file "$cryptopp_file_with_version".
 297         Please try again with --with-crypto-prefix=/my_crypto_prefix
 298         (replace /my_crypto_prefix with a valid path to your crypto++
 299         installation directory).])
 300 ])
 301
 302 dnl Checks requiring C++
 303 AC_LANG_PUSH([C++])
 304 MULE_CHECK_GLIBCXX
 305 MULE_CHECK_WX_SUPPORTS_LARGEFILE
 306
 307 # Check if the compiler is broken, wrt. exceptions.
 308 MULE_CHECK_EXCEPTIONS
 309
 310 MULE_CHECK_CXXABI
 311 AC_LANG_POP([C++])
 312
 313 # Ok, we have all needed libs, now checking for other stuff
 314 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 315
 316 # Flush standard test results for speeding cache
 317 AC_CACHE_SAVE
 318
 319 dnl -------------------------------------------------------------------------------
 320 dnl Start of autoscan stuff
 321 dnl -------------------------------------------------------------------------------
 322 # Checks for header files.
 323 AC_FUNC_ALLOCA
 324 AC_HEADER_DIRENT
 325 AC_HEADER_STDC
 326 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h  nl_types.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h errno.h signal.h])
 327 AC_HEADER_SYS_WAIT
 328
 329 # Checks for typedefs, structures, and compiler characteristics.
 330 AC_HEADER_STDBOOL
 331 AC_C_CONST
 332 AC_C_INLINE
 333 AC_TYPE_MODE_T
 334 AC_TYPE_OFF_T
 335 AC_TYPE_SIZE_T
 336 AC_HEADER_TIME
 337 AC_STRUCT_TM
 338 AC_TYPE_UID_T
 339 AC_C_VOLATILE
 340 AC_CHECK_TYPES([ptrdiff_t])
 341
 342 # Checks for library functions.
 343 AC_FUNC_CLOSEDIR_VOID
 344 AC_PROG_GCC_TRADITIONAL
 345 AC_FUNC_FORK
 346 AS_IF([test x$SYS != xwin32], [
 347         AC_FUNC_GETMNTENT
 348         AC_FUNC_LSTAT
 349         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 350 ])
 351 AC_FUNC_MEMCMP
 352 AC_FUNC_SELECT_ARGTYPES
 353 AC_FUNC_SETVBUF_REVERSED
 354 AC_TYPE_SIGNAL
 355 AC_FUNC_STAT
 356 AC_FUNC_STRFTIME
 357 AC_FUNC_STRTOD
 358 AC_FUNC_VPRINTF
 359 dnl Some other functions that worth checking deeper:
 360 dnl AC_FUNC_CLOSEDIR_VOID
 361 dnl AC_FUNC_MEMCMP
 362 dnl AC_FUNC_MMAP
 363 dnl AC_FUNC_STAT
 364 dnl AC_FUNC_STRTOD
 365 dnl AC_FUNC_SETVBUF_REVERSED
 366 dnl Anyways, do we actually USE them?
 367 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 368         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 369         ac_cv_func_malloc_0_nonnull=yes
 370         ac_cv_func_realloc_0_nonnull=yes
 371 ])
 372 AC_FUNC_MALLOC
 373 AC_FUNC_REALLOC
 374 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getpass gettimeofday inet_ntoa localeconv memmove mempcpy memset nl_langinfo pow select setlocale socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul sigaction])
 375 #-------------------------------------------------------------------------------
 376 # End of autoscan stuff
 377 #-------------------------------------------------------------------------------
 378
 379 dnl
 380 dnl autoscan has missed these ones.
 381 dnl
 382 AC_CHECK_FUNCS([mkdir getrlimit setrlimit getopt_long])
 383
 384 dnl This must be *before* MULE_CHECK_NLS
 385 AC_ARG_ENABLE([mmap],
 386         [AS_HELP_STRING([--enable-mmap], [enable using mapped memory if supported])])
 387
 388 AS_IF([test ${enable_mmap:-no} = yes], [
 389         AC_CHECK_HEADERS([sys/mman.h])
 390         AC_FUNC_MMAP
 391         AC_CHECK_FUNCS([munmap sysconf])
 392         AS_IF([test $ac_cv_func_sysconf = yes], [
 393                 AC_MSG_CHECKING([for pagesize constant for sysconf])
 394                 AC_LINK_IFELSE([
 395                         AC_LANG_PROGRAM([[
 396                                 #include <unistd.h>
 397                         ]], [[
 398                                 return sysconf(_SC_PAGESIZE);
 399                         ]])
 400                 ], [
 401                         AC_MSG_RESULT([_SC_PAGESIZE])
 402                         AC_DEFINE([HAVE__SC_PAGESIZE], [1], [Define to 1 if you have the _SC_PAGESIZE constant in <unistd.h>])
 403                 ], [
 404                         AC_LINK_IFELSE([
 405                                 AC_LANG_PROGRAM([[
 406                                         #include <unistd.h>
 407                                 ]], [[
 408                                         return sysconf(_SC_PAGE_SIZE);
 409                                 ]])
 410                         ], [
 411                                 AC_MSG_RESULT([_SC_PAGE_SIZE])
 412                                 AC_DEFINE([HAVE__SC_PAGE_SIZE], [1], [Define to 1 if you have the _SC_PAGE_SIZE constant in <unistd.h>, but not _SC_PAGESIZE])
 413                         ], [
 414                                 AC_MSG_RESULT([none])
 415                         ])
 416                 ])
 417         ])
 418 ], [
 419         # fake the result of the test for munmap() for the gettext macros
 420         ac_cv_func_munmap=no
 421 ])
 422
 423
 424 MULE_BACKUP([CPPFLAGS])
 425 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 426 AC_FUNC_STRERROR_R
 427 MULE_RESTORE([CPPFLAGS])
 428
 429 # Look for a way to preallocate disk space for files.
 430 MULE_CHECK_FALLOCATE
 431
 432 # Checking Native Language Support
 433 dnl Sets gettext version.
 434 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 435 AM_GNU_GETTEXT_VERSION(0.11.5)
 436 MULE_CHECK_NLS
 437
 438 # Check for bfd.h (to have proper backtraces without using wxExecute)
 439 MULE_CHECK_BFD
 440 MULE_CHECK_EXECINFO
 441
 442 # Flush standard test results for speeding cache
 443 AC_CACHE_SAVE
 444
 445 # Other tests
 446 # aMule options
 447 MULE_COMPILATION_FLAGS
 448
 449 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 450 AC_MSG_CHECKING([for docdir])
 451 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 452 AC_SUBST([docdir])dnl
 453 AC_MSG_RESULT([$docdir])
 454
 455 # Try to set the SVN checkout-date
 456 AC_MSG_CHECKING([for SVNDATE])
 457 if test -f "$srcdir/.svn-revision" # SVNDATE for tarballs
 458 then
 459         svndate="rev. `cat $srcdir/.svn-revision`"
 460 elif test -d $srcdir/.svn # SVNDATE for svn
 461 then
 462         svndate="rev. `svnversion $srcdir | sed -e 's/[[0-9]][[0-9]]*:\(.*\)/\1/' -e 's/\([[0-9]][[0-9]]*\).*/\1/'`"
 463 fi
 464 AC_MSG_RESULT(${svndate:-None required})
 465 AS_IF([test -n "$svndate"], [
 466             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 467             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 468 ])
 469 AC_SUBST([SVNDATE], [$svndate])dnl
 470
 471 dnl Set up the denoiser
 472 MULE_DENOISER
 473
 474 AM_CONDITIONAL(WEB, test x$WEB = xyes)
 475 AM_CONDITIONAL(ED2K, test x$ED2K = xyes)
 476 AM_CONDITIONAL(CAS, test x$CAS = xyes)
 477 AM_CONDITIONAL(WXCAS, test x$WXCAS = xyes)
 478 AM_CONDITIONAL(ALC, test x$ALC = xyes)
 479 AM_CONDITIONAL(ALCC, test x$ALCC = xyes)
 480 AM_CONDITIONAL(AMULE_GUI, test x$AMULE_GUI = xyes)
 481 AM_CONDITIONAL(AMULE_DAEMON, test x$AMULE_DAEMON = xyes)
 482 AM_CONDITIONAL(COMPILE_CMD, test x$AMULECMD = xyes)
 483 AM_CONDITIONAL(MONOLITHIC, test x$MONOLITHIC = xyes)
 484 AM_CONDITIONAL(XAS, test x$XAS = xyes)
 485 AM_CONDITIONAL(FILEVIEW, test x$FILEVIEW = xyes)
 486 AM_CONDITIONAL(ENABLE_UPNP, test x$ENABLE_UPNP = xyes)
 487 AM_CONDITIONAL(ENABLE_IP2COUNTRY, test x$ENABLE_IP2COUNTRY = xyes)
 488 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 489 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 490 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 491 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 492 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 493 AM_CONDITIONAL(INSTALL_SKINS, test x$INSTALL_SKINS = xyes)
 494
 495 # Check for readline library
 496 if test x$AMULECMD = xyes -o x$WEB = xyes; then
 497         VL_LIB_READLINE
 498 fi
 499
 500 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 501
 502 MULE_CHECK_CCACHE
 503
 504 dnl
 505 dnl Generate the Makefiles
 506 dnl
 507 AC_CONFIG_FILES([Makefile
 508                  docs/Makefile
 509                  docs/man/Makefile
 510                  intl/Makefile
 511                  src/Makefile
 512                  src/pixmaps/Makefile
 513                  src/pixmaps/flags_xpm/Makefile
 514                  src/libs/Makefile
 515                  src/libs/ec/Makefile
 516                  src/libs/ec/cpp/Makefile
 517                  src/libs/common/Makefile
 518                  src/utils/Makefile
 519                  src/utils/aLinkCreator/Makefile
 520                  src/utils/aLinkCreator/docs/Makefile
 521                  src/utils/aLinkCreator/src/Makefile
 522                  src/utils/cas/Makefile
 523                  src/utils/cas/docs/Makefile
 524                  src/utils/fileview/Makefile
 525                  src/utils/wxCas/Makefile
 526                  src/utils/wxCas/docs/Makefile
 527                  src/utils/wxCas/src/Makefile
 528                  src/utils/xas/Makefile
 529                  src/utils/xas/autostart-xas
 530                  src/utils/xas/docs/Makefile
 531                  src/skins/Makefile
 532                  src/webserver/Makefile
 533                  src/webserver/src/Makefile
 534                  src/webserver/default/Makefile
 535                  unittests/Makefile
 536                  unittests/muleunit/Makefile
 537                  unittests/tests/Makefile])
 538 dnl
 539 dnl autoscan has missed these, i wonder why...
 540 dnl
 541 AC_CONFIG_FILES([po/Makefile.in
 542                  Compilation.flags])
 543 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 544 AC_OUTPUT
 545
 546 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 547
 548 echo
 549 echo
 550 echo "  Configure script has finished system check."
 551 echo
 552 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 553 echo
 554 echo "  aMule enabled options:"
 555 echo
 556 echo "  **** aMule Core ****"
 557 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 558 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 559 echo "  Should aMule be compiled in debug mode?                    ${USE_DEBUG:-no}"
 560 echo "  Should aMule be compiled with profiling?                   ${USE_PROFILE:-no}"
 561 echo "  Should aMule be compiled with optimizations?               ${USE_OPTIMIZE:-no}"
 562 echo "  Should aMule be compiled with UPnP support?                ${ENABLE_UPNP:-yes}"
 563 echo "  Should aMule be compiled with IP2country support?          ${ENABLE_IP2COUNTRY:-no}"
 564 echo "  Should aMule monolithic application be built?              ${MONOLITHIC:-yes}"
 565 echo "  Should aMule daemon version be built?                      ${AMULE_DAEMON:-no}"
 566 echo "  Should aMule remote gui be built? (EXPERIMENTAL)           ${AMULE_GUI:-no}"
 567 echo "  Crypto++ library/headers style?                            ${CRYPTOPP_STYLE:-not found}"
 568
 569 echo
 570 echo "  **** aMule TextClient ****"
 571 echo "  Should aMule Command Line Client be built?                 ${AMULECMD:-no}"
 572 echo
 573 echo "  **** aMule WebServer ****"
 574 echo "  Should aMule WebServer be built?                           ${WEB:-no}"
 575 echo
 576 echo "  **** aMule ED2K Links Handler ****"
 577 echo "  Should aMule ED2K Links Handler be built?                  ${ED2K:-yes}"
 578 echo
 579 echo "  **** aMuleLinkCreator ****"
 580 echo "  Should aMuleLinkCreator GUI version (alc) be built?        ${ALC:-no}"
 581 echo "  Should aMuleLinkCreator for console (alcc) be built?       ${ALCC:-no}"
 582 echo
 583 echo "  **** aMule Statistics ****"
 584 echo "  Should C aMule Statistics (CAS) be built?                  ${CAS:-no}"
 585 echo "  Should aMule GUI Statistics (wxCas) be built?              ${WXCAS:-no}"
 586 echo "  Should xas XChat2 plugin be installed?                     ${XAS:-yes}"
 587
 588 echo
 589 echo "  **** General Libraries and Tools ****"
 590 echo "  Should ccache support be enabled?                          ${enable_ccache:-no}"
 591 echo "  Libraries aMule will use to build:"
 592 wxinfo="$WX_PORT"
 593 AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 594 AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 595 echo "                                       wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 596 echo "                                       crypto++              ${CRYPTOPP_VERSION_STRING} (${CRYPTOPP_STYLE}, in ${CRYPTOPP_PREFIX})"
 597 AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 598 AS_IF([test x${ENABLE_UPNP} = xyes], [echo "                                       libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"])
 599 if test ${enable_nls:-yes} = yes; then
 600 AS_IF([test x$USE_NLS = xno],
 601         [libintl_found="Not detected"],
 602         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 603                 [libintl_found="included"],
 604                 [libintl_found="system"])])
 605 echo "                                       libintl               $libintl_found"
 606 fi
 607 AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 608 AS_IF([test ${ENABLE_IP2COUNTRY:-no} = yes], [echo "                                       libGeoIP              ${geoip_style}"])
 609 if test x$LIBPNG_VERSION != xnot_needed; then
 610 echo "                                       libpng                ${LIBPNG_VERSION:-Not detected}"
 611 fi
 612 if test x$GDLIB_VERSION != xnot_needed; then
 613 echo "                                       libgd                 ${GDLIB_VERSION:-Not detected}"
 614 fi
 615 echo "                                       zlib                  ${ZLIB_VERSION:-Not detected}"