configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29
  30 AC_CONFIG_SRCDIR([src/amule.cpp])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_MAINTAINER_MODE
  33
  34 dnl Check host system.
  35 MULE_CHECK_SYSTEM
  36
  37 dnl Checks for programs.
  38 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  39 MULE_BACKUP([CFLAGS])
  40 MULE_BACKUP([CXXFLAGS])
  41 MULE_BACKUP([BUILD_CFLAGS])
  42 AC_PROG_CXX
  43 AC_PROG_CXXCPP
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  47 MULE_RESTORE([CFLAGS])
  48 MULE_RESTORE([CXXFLAGS])
  49 MULE_RESTORE([BUILD_CFLAGS])
  50 AC_PROG_AWK
  51 AC_PROG_EGREP
  52 AC_PROG_MAKE_SET
  53 AC_PROG_LEX
  54 AC_PROG_INSTALL
  55 AC_PROG_RANLIB
  56 AC_PROG_YACC
  57
  58 dnl Find the right ranlib, even when cross-compiling
  59 dnl And for some other tools for cross compilation
  60 AC_CHECK_TOOL(RANLIB, ranlib)
  61 AC_CHECK_TOOL(STRIP, strip)
  62 AC_CHECK_TOOL(AR, ar)
  63 AC_CHECK_TOOL(LD, ld)
  64
  65 dnl
  66 dnl Add args to configure
  67 dnl
  68 AC_ARG_ENABLE(
  69         [monolithic],
  70         [AS_HELP_STRING(
  71                 [--disable-monolithic],
  72                 [disable building of the monolithic aMule app])],
  73         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
  74
  75 AC_ARG_ENABLE(
  76         [amule-daemon],
  77         [AS_HELP_STRING(
  78                 [--enable-amule-daemon],
  79                 [compile aMule daemon version])],
  80         [AMULE_DAEMON=$enableval], [AMULE_DAEMON=no])
  81
  82 AC_ARG_ENABLE(
  83         [amulecmd],
  84         [AS_HELP_STRING(
  85                 [--enable-amulecmd],
  86                 [compile aMule command line client])],
  87         [AMULECMD=$enableval], [AMULECMD=no])
  88
  89 AC_ARG_ENABLE(
  90         [webserver],
  91         [AS_HELP_STRING(
  92                 [--enable-webserver],
  93                 [compile aMule WebServer])],
  94         [WEB=$enableval], [WEB=no])
  95
  96 AC_ARG_ENABLE(
  97         [amule-gui],
  98         [AS_HELP_STRING(
  99                 [--enable-amule-gui],
 100                 [compile aMule remote GUI (EXPERIMENTAL)])],
 101         [AMULE_GUI=$enableval], [AMULE_GUI=no])
 102
 103 AC_ARG_ENABLE(
 104         [cas],
 105         [AS_HELP_STRING(
 106                 [--enable-cas],
 107                 [compile C aMule Statistics])],
 108         [CAS=$enableval], [CAS=no])
 109
 110 AC_ARG_ENABLE(
 111         [wxcas],
 112         [AS_HELP_STRING(
 113                 [--enable-wxcas],
 114                 [compile aMule GUI Statistics])],
 115         [WXCAS=$enableval], [WXCAS=no])
 116
 117 AC_ARG_ENABLE(
 118         [ed2k],
 119         [AS_HELP_STRING(
 120                 [--disable-ed2k],
 121                 [don't compile aMule ed2k links handler])],
 122         [ED2K=$enableval], [ED2K=yes])
 123
 124 AC_ARG_ENABLE(
 125         [alc],
 126         [AS_HELP_STRING(
 127                 [--enable-alc],
 128                 [compile aMuleLinkCreator GUI version])],
 129         [ALC=$enableval], [ALC=no])
 130
 131 AC_ARG_ENABLE(
 132         [alcc],
 133         [AS_HELP_STRING(
 134                 [--enable-alcc],
 135                 [compile aMuleLinkCreator for console])],
 136         [ALCC=$enableval], [ALCC=no])
 137
 138 AC_ARG_ENABLE(
 139         [monolithic],
 140         [AS_HELP_STRING(
 141                 [--disable-monolithic],
 142                 [disable building of the monolithic aMule app])],
 143         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
 144
 145 AC_ARG_ENABLE(
 146         [upnp],
 147         [AS_HELP_STRING(
 148                 [--disable-upnp],
 149                 [do not compile UPnP code])],
 150         [ENABLE_UPNP=$enableval], [ENABLE_UPNP=yes])
 151
 152 AC_ARG_ENABLE(
 153         [xas],
 154         [AS_HELP_STRING(
 155                 [--disable-xas],
 156                 [do not install xas XChat2 plugin])],
 157         [XAS=$enableval], [XAS=yes])
 158
 159 AC_ARG_ENABLE(
 160         [geoip],
 161         [AS_HELP_STRING(
 162                 [--enable-geoip],
 163                 [compile with GeoIP IP2Country library])],
 164         [ENABLE_IP2COUNTRY=$enableval], [ENABLE_IP2COUNTRY=no])
 165
 166 AS_IF([test ${ENABLE_IP2COUNTRY:-no} = yes], [GEOIP_LIBS="-lGeoIP"])
 167
 168 AC_ARG_WITH(
 169         [geoip-headers],
 170         AS_HELP_STRING([--with-geoip-headers=DIR],
 171                 [GeoIP include files location]),
 172         [GEOIP_CPPFLAGS="-I$withval"])
 173
 174 AC_ARG_WITH(
 175         [geoip-lib],
 176         AS_HELP_STRING([--with-geoip-lib=DIR],
 177                 [GeoIP library location]),
 178         [GEOIP_LDFLAGS="-L$withval"])
 179
 180 AC_ARG_WITH(
 181         [geoip-static],
 182         AS_HELP_STRING([--with-geoip-static],
 183                 [Explicitly link GeoIP statically (default=no)]),
 184         [AS_IF([test "$withval" != "no"], [GEOIP_LIBS="-Wl,-Bstatic $GEOIP_LIBS -Wl,-Bdynamic"])])
 185
 186 # Default is yes, because they're most likely compatible.
 187 # However, this is only used when cross-compiling.
 188 AC_ARG_WITH(
 189         [gnu-malloc],
 190         [AS_HELP_STRING([--without-gnu-malloc],
 191                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
 192         [gnumalloc=$withval], [gnumalloc=yes])
 193
 194
 195 # Checking for libs before all other stuff to break
 196 # configure as soon as possible in case of a missing one
 197 # to avoid losing too much time
 198
 199 # Check for zlib
 200 MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])
 201
 202 AS_IF([test x$CAS = xyes], [
 203         # Check for gd
 204         MULE_CHECK_GDLIB([2.0.0], [
 205                 CAS_DEFS="-D__GD__"
 206                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 207         ], [CAS_DEFS=])
 208         AS_IF([test -z "$CAS_DEFS"],
 209                 [MULE_WARNING(
 210                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 211                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 212                         Or this might also be that your gdlib-config has other name.
 213                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 214                         If you use compiled packages check if you have devel pack installed.
 215                         To download the latest version check http://www.boutell.com/gd for sources.])])
 216 ], [GDLIB_VERSION="not_needed"])
 217 AC_SUBST([CAS_DEFS])dnl
 218
 219
 220 AS_IF([test x$WEB = xyes],
 221         [MULE_CHECK_REGEX(, [
 222                 WEB=disabled
 223                 MULE_WARNING([amuleweb has been disabled because configure could not find a POSIX compliant regex library.])
 224         ])
 225 ])
 226 AS_IF([test x$WEB = xyes],
 227         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 228                 MULE_WARNING(
 229                         [libpng >= 1.2.0 not found.
 230                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 231                 ])
 232         ], [LIBPNG_VERSION="not_needed"])
 233 AC_SUBST([AMULEWEB_DEFS])dnl
 234
 235
 236 # Check for perl File::Copy
 237 AC_MSG_CHECKING([for File::Copy])
 238 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])], [AC_MSG_ERROR([File::Copy perl module is required])])
 239
 240
 241 # Check if we need the GUI
 242 AC_MSG_CHECKING([whether we need the GUI])
 243 AS_IF([test x$MONOLITHIC = xyes], [need_gui=yes])
 244 AS_IF([test x$WXCAS = xyes], [need_gui=yes])
 245 AS_IF([test x$ALC = xyes], [need_gui=yes])
 246 AS_IF([test x$AMULE_GUI = xyes], [need_gui=yes])
 247 AS_IF([test x${need_gui:+set} != xset], [need_gui=no])
 248 AC_MSG_RESULT($need_gui)
 249
 250
 251 # Check for GeoIP (required for IP2Country capability)
 252 AS_IF([test ${ENABLE_IP2COUNTRY:-no} = yes], [
 253         MULE_APPEND([GEOIP_CPPFLAGS], [-DENABLE_IP2COUNTRY=1])
 254         MULE_BACKUP([CPPFLAGS])
 255         MULE_APPEND([CPPFLAGS], [$GEOIP_CPPFLAGS])
 256         MULE_BACKUP([LDFLAGS])
 257         MULE_APPEND([LDFLAGS], [$GEOIP_LDFLAGS])
 258         AC_CHECK_HEADER([GeoIP.h],,
 259                 [AC_MSG_ERROR([--enable-geoip passed to configure, but the GeoIP header files were not found])])
 260         AC_CHECK_LIB([GeoIP], [GeoIP_open],
 261                 [AC_DEFINE(SUPPORT_GEOIP, 1, Define if you want GeoIP support.)],
 262                 [AC_MSG_ERROR([--enable-geoip passed to configure, but the GeoIP libraries were not found])])
 263         MULE_RESTORE([CPPFLAGS])
 264         MULE_RESTORE([LDFLAGS])
 265 ])
 266 AC_SUBST([GEOIP_CPPFLAGS])dnl
 267 AC_SUBST([GEOIP_LDFLAGS])dnl
 268 AC_SUBST([GEOIP_LIBS])dnl
 269
 270
 271 # Check for wx
 272 WX_CONFIG_OPTIONS
 273 WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 274 # Force using a static wxWidgets library if the executable is to be linked statically.
 275 AS_IF([test ${enable_static:-no} = yes], [WX_SHARED=0])
 276 # Force using a unicode build of the library
 277 WX_UNICODE=1
 278 DEBUG=$WX_DEBUG
 279 WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 280 WX_CONFIG_CHECK([2.8.0], [wxWin=1],,, [$WXCONFIG_FLAGS])
 281 if test "$wxWin" != 1; then
 282         AC_MSG_ERROR([
 283                 wxWidgets must be installed on your system but wx-config
 284                 script couldn't be found. Please check that wx-config is
 285                 in path or specified by --with-wx-config=path flag, the
 286                 directory where wxWidgets libraries are installed (returned
 287                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 288                 equivalent variable and wxWidgets version is 2.8.0 or above.
 289         ])
 290 fi
 291 WX_DETECT_STANDARD_OPTION_VALUES
 292
 293 # We also need wxBase
 294 WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 295 WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 296 WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 297 AC_SUBST([WXBASE_LIBS])
 298 AC_SUBST([WXBASE_CPPFLAGS])
 299
 300 dnl Get flags for windres
 301 AC_ARG_VAR([RC], [Resource Compiler])dnl
 302 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 303 AS_IF([test ${SYS:-unknown} = win32],
 304 [
 305         AC_CHECK_TOOL([RC], [windres], [:])
 306         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 307 ])
 308
 309
 310 # Check for libupnp
 311 AS_IF([test "${ENABLE_UPNP:-yes}" = yes], [
 312         LIBUPNP_CHECK(
 313                 [1.6.6],
 314                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 315                 [ENABLE_UPNP=disabled
 316                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 317         )
 318 ])dnl
 319
 320
 321 # Check for Crypto++
 322 MULE_CHECK_CRYPTOPP([5.1], [
 323         # Check for CryptoPP >= 5.5
 324         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 325 ], [
 326         AC_MSG_ERROR([
 327         Could not find crypto++ header file "$cryptopp_file_with_version".
 328         Please try again with --with-crypto-prefix=/my_crypto_prefix
 329         (replace /my_crypto_prefix with a valid path to your crypto++
 330         installation directory).])
 331 ])
 332
 333 dnl Checks requiring C++
 334 AC_LANG_PUSH([C++])
 335 MULE_CHECK_GLIBCXX
 336 MULE_CHECK_WX_SUPPORTS_LARGEFILE
 337
 338 # Check if the compiler is broken, wrt. exceptions.
 339 MULE_CHECK_EXCEPTIONS
 340
 341 MULE_CHECK_CXXABI
 342 AC_LANG_POP([C++])
 343
 344 # Check for bfd.h (to have proper backtraces without using wxExecute)
 345 MULE_CHECK_BFD
 346 MULE_CHECK_EXECINFO
 347
 348 # Ok, we have all needed libs, now checking for other stuff
 349 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 350
 351 # Flush standard test results for speeding cache
 352 AC_CACHE_SAVE
 353
 354 dnl -------------------------------------------------------------------------------
 355 dnl Start of autoscan stuff
 356 dnl -------------------------------------------------------------------------------
 357 # Checks for header files.
 358 AC_PATH_X
 359 AC_FUNC_ALLOCA
 360 AC_HEADER_DIRENT
 361 AC_HEADER_STDC
 362 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h  nl_types.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h])
 363 AC_HEADER_SYS_WAIT
 364
 365 # Checks for typedefs, structures, and compiler characteristics.
 366 AC_HEADER_STDBOOL
 367 AC_C_CONST
 368 AC_C_INLINE
 369 AC_TYPE_MODE_T
 370 AC_TYPE_OFF_T
 371 AC_TYPE_SIZE_T
 372 AC_HEADER_TIME
 373 AC_STRUCT_TM
 374 AC_TYPE_UID_T
 375 AC_C_VOLATILE
 376 AC_CHECK_TYPES([ptrdiff_t])
 377
 378 # Checks for library functions.
 379 AC_FUNC_CLOSEDIR_VOID
 380 AC_PROG_GCC_TRADITIONAL
 381 AC_FUNC_FORK
 382 AS_IF([test x$SYS != xwin32], [
 383         AC_FUNC_GETMNTENT
 384         AC_FUNC_LSTAT
 385         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 386 ])
 387 AC_FUNC_MEMCMP
 388 AC_FUNC_MMAP
 389 AC_FUNC_SELECT_ARGTYPES
 390 AC_FUNC_SETVBUF_REVERSED
 391 AC_TYPE_SIGNAL
 392 AC_FUNC_STAT
 393 AC_FUNC_STRFTIME
 394 AC_FUNC_STRTOD
 395 AC_FUNC_VPRINTF
 396 dnl Some other functions that worth checking deeper:
 397 dnl AC_FUNC_CLOSEDIR_VOID
 398 dnl AC_FUNC_MEMCMP
 399 dnl AC_FUNC_MMAP
 400 dnl AC_FUNC_STAT
 401 dnl AC_FUNC_STRTOD
 402 dnl AC_FUNC_SETVBUF_REVERSED
 403 dnl Anyways, do we actually USE them?
 404 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 405         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 406         ac_cv_func_malloc_0_nonnull=yes
 407         ac_cv_func_realloc_0_nonnull=yes
 408 ])
 409 AC_FUNC_MALLOC
 410 AC_FUNC_REALLOC
 411 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getpass gettimeofday inet_ntoa localeconv memmove mempcpy memset munmap nl_langinfo pow select setlocale socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul])
 412 #-------------------------------------------------------------------------------
 413 # End of autoscan stuff
 414 #-------------------------------------------------------------------------------
 415
 416 dnl
 417 dnl autoscan has missed these ones.
 418 dnl
 419 AC_CHECK_FUNCS([mkdir getrlimit setrlimit getopt_long])
 420
 421 MULE_BACKUP([CPPFLAGS])
 422 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 423 AC_FUNC_STRERROR_R
 424 MULE_RESTORE([CPPFLAGS])
 425
 426 # Look for a way to preallocate disk space for files.
 427 MULE_CHECK_FALLOCATE
 428
 429 # Checking Native Language Support
 430 dnl Sets gettext version.
 431 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 432 AM_GNU_GETTEXT_VERSION(0.11.5)
 433 MULE_CHECK_NLS
 434
 435 # Flush standard test results for speeding cache
 436 AC_CACHE_SAVE
 437
 438 # Other tests
 439 # aMule options
 440 MULE_COMPILATION_FLAGS
 441
 442 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 443 AC_MSG_CHECKING([for docdir])
 444 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 445 AC_SUBST([docdir])dnl
 446 AC_MSG_RESULT([$docdir])
 447
 448 # Try to set the SVN checkout-date
 449 AC_MSG_CHECKING([for SVNDATE])
 450 if test -f "$srcdir/SVNDATE" # SVNDATE for tarballs
 451 then
 452         svndate=`cat $srcdir/SVNDATE`
 453 elif test -d $srcdir/.svn # SVNDATE for svn
 454 then
 455         svndate="rev. `svnversion $srcdir | sed -e 's/[[0-9]][[0-9]]*:\(.*\)/\1/' -e 's/\([[0-9]][[0-9]]*\).*/\1/'`"
 456 fi
 457 AC_MSG_RESULT(${svndate:-None required})
 458 AS_IF([test -n "$svndate"], [
 459             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 460             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 461 ])
 462 AC_SUBST([SVNDATE], [$svndate])dnl
 463
 464 dnl Set up the denoiser
 465 MULE_DENOISER
 466
 467 AM_CONDITIONAL(WEB, test x$WEB = xyes)
 468 AM_CONDITIONAL(ED2K, test x$ED2K = xyes)
 469 AM_CONDITIONAL(CAS, test x$CAS = xyes)
 470 AM_CONDITIONAL(WXCAS, test x$WXCAS = xyes)
 471 AM_CONDITIONAL(ALC, test x$ALC = xyes)
 472 AM_CONDITIONAL(ALCC, test x$ALCC = xyes)
 473 AM_CONDITIONAL(AMULE_GUI, test x$AMULE_GUI = xyes)
 474 AM_CONDITIONAL(AMULE_DAEMON, test x$AMULE_DAEMON = xyes)
 475 AM_CONDITIONAL(COMPILE_CMD, test x$AMULECMD = xyes)
 476 AM_CONDITIONAL(MONOLITHIC, test x$MONOLITHIC = xyes)
 477 AM_CONDITIONAL(XAS, test x$XAS = xyes)
 478 AM_CONDITIONAL(ENABLE_UPNP, test x$ENABLE_UPNP = xyes)
 479 AM_CONDITIONAL(ENABLE_IP2COUNTRY, test x$ENABLE_IP2COUNTRY = xyes)
 480 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 481 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 482 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 483 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 484 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 485
 486 # Check for readline library
 487 if test x$AMULECMD = xyes -o x$WEB = xyes; then
 488         VL_LIB_READLINE
 489 fi
 490
 491 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 492
 493 MULE_CHECK_CCACHE
 494
 495 dnl
 496 dnl Generate the Makefiles
 497 dnl
 498 AC_CONFIG_FILES([Makefile
 499                  docs/Makefile
 500                  docs/man/Makefile
 501                  intl/Makefile
 502                  src/Makefile
 503                  src/pixmaps/Makefile
 504                  src/pixmaps/flags_xpm/Makefile
 505                  src/libs/Makefile
 506                  src/libs/ec/Makefile
 507                  src/libs/ec/cpp/Makefile
 508                  src/libs/common/Makefile
 509                  src/utils/Makefile
 510                  src/utils/aLinkCreator/Makefile
 511                  src/utils/aLinkCreator/docs/Makefile
 512                  src/utils/aLinkCreator/src/Makefile
 513                  src/utils/cas/Makefile
 514                  src/utils/cas/docs/Makefile
 515                  src/utils/fileview/Makefile
 516                  src/utils/wxCas/Makefile
 517                  src/utils/wxCas/docs/Makefile
 518                  src/utils/wxCas/src/Makefile
 519                  src/utils/xas/Makefile
 520                  src/utils/xas/autostart-xas
 521                  src/utils/xas/docs/Makefile
 522                  src/skins/Makefile
 523                  src/webserver/Makefile
 524                  src/webserver/src/Makefile
 525                  src/webserver/default/Makefile
 526                  src/webserver/php-default/Makefile
 527                  src/webserver/chicane/Makefile
 528                  src/webserver/litoral/Makefile
 529                  unittests/Makefile
 530                  unittests/muleunit/Makefile
 531                  unittests/tests/Makefile])
 532 dnl
 533 dnl autoscan has missed these, i wonder why...
 534 dnl
 535 AC_CONFIG_FILES([po/Makefile.in
 536                  Compilation.flags])
 537 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 538 AC_OUTPUT
 539
 540 echo
 541 echo
 542 echo "  Configure script has finished system check."
 543 echo
 544 echo "  Configured aMule ${PACKAGE_VERSION} for '${host}'."
 545 echo
 546 echo "  aMule enabled options:"
 547 echo
 548 echo "  **** aMule Core ****"
 549 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 550 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 551 echo "  Should aMule be compiled in debug mode?                    ${USE_DEBUG:-no}"
 552 echo "  Should aMule be compiled with profiling?                   ${USE_PROFILE:-no}"
 553 echo "  Should aMule be compiled with optimizations?               ${USE_OPTIMIZE:-no}"
 554 echo "  Should aMule be compiled with UPnP support?                ${ENABLE_UPNP:-yes}"
 555 echo "  Should aMule be compiled with IP2country support?          ${ENABLE_IP2COUNTRY:-no}"
 556 echo "  Should aMule monolithic application be built?              ${MONOLITHIC:-yes}"
 557 echo "  Should aMule daemon version be built?                      ${AMULE_DAEMON:-no}"
 558 echo "  Should aMule remote gui be built? (EXPERIMENTAL)           ${AMULE_GUI:-no}"
 559 echo "  Crypto++ library/headers style?                            ${CRYPTOPP_STYLE:-not found}"
 560
 561 echo
 562 echo "  **** aMule TextClient ****"
 563 echo "  Should aMule Command Line Client be built?                 ${AMULECMD:-no}"
 564 echo
 565 echo "  **** aMule WebServer ****"
 566 echo "  Should aMule WebServer be built?                           ${WEB:-no}"
 567 echo
 568 echo "  **** aMule ED2K Links Handler ****"
 569 echo "  Should aMule ED2K Links Handler be built?                  ${ED2K:-yes}"
 570 echo
 571 echo "  **** aMuleLinkCreator ****"
 572 echo "  Should aMuleLinkCreator GUI version (alc) be built?        ${ALC:-no}"
 573 echo "  Should aMuleLinkCreator for console (alcc) be built?       ${ALCC:-no}"
 574 echo
 575 echo "  **** aMule Statistics ****"
 576 echo "  Should C aMule Statistics (CAS) be built?                  ${CAS:-no}"
 577 echo "  Should aMule GUI Statistics (wxCas) be built?              ${WXCAS:-no}"
 578 echo "  Should xas XChat2 plugin be installed?                     ${XAS:-yes}"
 579
 580 echo
 581 echo "  **** General Libraries and Tools ****"
 582 echo "  Should ccache support be enabled?                          ${enable_ccache:-no}"
 583 echo "  Libraries aMule will use to build:"
 584 wxinfo="$WX_PORT"
 585 AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 586 AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 587 echo "                                       wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 588 echo "                                       crypto++              ${CRYPTOPP_VERSION_STRING} (${CRYPTOPP_STYLE}, in ${CRYPTOPP_PREFIX})"
 589 AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 590 AS_IF([test x${ENABLE_UPNP} = xyes], [dnl
 591 echo "                                       libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"
 592 ])dnl
 593 if test x${WEB:-no} != xno; then
 594 AS_IF([test $regex_found = no],
 595         [regex_found="Not detected"],
 596         [AS_IF([test -z "$REGEX_LIB"],
 597                 [regex_found=system],
 598                 [regex_found="standalone (in $REGEX_LIB)"])])
 599 echo "                                       regex                 $regex_found"
 600 fi
 601 if test ${enable_nls:-yes} = yes; then
 602 AS_IF([test x$USE_NLS = xno],
 603         [libintl_found="Not detected"],
 604         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 605                 [libintl_found="included"],
 606                 [libintl_found="system"])])
 607 echo "                                       libintl               $libintl_found"
 608 fi
 609 if test x$LIBPNG_VERSION != xnot_needed; then
 610 echo "                                       libpng                ${LIBPNG_VERSION:-Not detected}"
 611 fi
 612 if test x$GDLIB_VERSION != xnot_needed; then
 613 echo "                                       libgd                 ${GDLIB_VERSION:-Not detected}"
 614 fi
 615 echo "                                       zlib                  ${ZLIB_VERSION:-Not detected}"