configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29
  30 AC_CONFIG_SRCDIR([src/amule.cpp])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_MAINTAINER_MODE
  33
  34 dnl Check host system.
  35 MULE_CHECK_SYSTEM
  36
  37 dnl Checks for programs.
  38 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  39 MULE_BACKUP([CFLAGS])
  40 MULE_BACKUP([CXXFLAGS])
  41 MULE_BACKUP([BUILD_CFLAGS])
  42 AC_PROG_CXX
  43 AC_PROG_CXXCPP
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  47 MULE_RESTORE([CFLAGS])
  48 MULE_RESTORE([CXXFLAGS])
  49 MULE_RESTORE([BUILD_CFLAGS])
  50 AC_PROG_AWK
  51 AC_PROG_EGREP
  52 AC_PROG_MAKE_SET
  53 AC_PROG_LEX
  54 AC_PROG_INSTALL
  55 AC_PROG_RANLIB
  56 AC_PROG_YACC
  57
  58 dnl Find the right ranlib, even when cross-compiling
  59 dnl And for some other tools for cross compilation
  60 AC_CHECK_TOOL(RANLIB, ranlib)
  61 AC_CHECK_TOOL(STRIP, strip)
  62 AC_CHECK_TOOL(AR, ar)
  63 AC_CHECK_TOOL(LD, ld)
  64
  65 dnl
  66 dnl Add args to configure
  67 dnl
  68 AC_ARG_ENABLE(
  69         [monolithic],
  70         [AS_HELP_STRING(
  71                 [--disable-monolithic],
  72                 [disable building of the monolithic aMule app])],
  73         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
  74
  75 AC_ARG_ENABLE(
  76         [amule-daemon],
  77         [AS_HELP_STRING(
  78                 [--enable-amule-daemon],
  79                 [compile aMule daemon version])],
  80         [AMULE_DAEMON=$enableval], [AMULE_DAEMON=no])
  81
  82 AC_ARG_ENABLE(
  83         [amulecmd],
  84         [AS_HELP_STRING(
  85                 [--enable-amulecmd],
  86                 [compile aMule command line client])],
  87         [AMULECMD=$enableval], [AMULECMD=no])
  88
  89 AC_ARG_ENABLE(
  90         [webserver],
  91         [AS_HELP_STRING(
  92                 [--enable-webserver],
  93                 [compile aMule WebServer])],
  94         [WEB=$enableval], [WEB=no])
  95
  96 AC_ARG_ENABLE(
  97         [amule-gui],
  98         [AS_HELP_STRING(
  99                 [--enable-amule-gui],
 100                 [compile aMule remote GUI (EXPERIMENTAL)])],
 101         [AMULE_GUI=$enableval], [AMULE_GUI=no])
 102
 103 AC_ARG_ENABLE(
 104         [cas],
 105         [AS_HELP_STRING(
 106                 [--enable-cas],
 107                 [compile C aMule Statistics])],
 108         [CAS=$enableval], [CAS=no])
 109
 110 AC_ARG_ENABLE(
 111         [wxcas],
 112         [AS_HELP_STRING(
 113                 [--enable-wxcas],
 114                 [compile aMule GUI Statistics])],
 115         [WXCAS=$enableval], [WXCAS=no])
 116
 117 AC_ARG_ENABLE(
 118         [ed2k],
 119         [AS_HELP_STRING(
 120                 [--disable-ed2k],
 121                 [don't compile aMule ed2k links handler])],
 122         [ED2K=$enableval], [ED2K=yes])
 123
 124 AC_ARG_ENABLE(
 125         [alc],
 126         [AS_HELP_STRING(
 127                 [--enable-alc],
 128                 [compile aMuleLinkCreator GUI version])],
 129         [ALC=$enableval], [ALC=no])
 130
 131 AC_ARG_ENABLE(
 132         [alcc],
 133         [AS_HELP_STRING(
 134                 [--enable-alcc],
 135                 [compile aMuleLinkCreator for console])],
 136         [ALCC=$enableval], [ALCC=no])
 137
 138 AC_ARG_ENABLE(
 139         [monolithic],
 140         [AS_HELP_STRING(
 141                 [--disable-monolithic],
 142                 [disable building of the monolithic aMule app])],
 143         [MONOLITHIC=$enableval], [MONOLITHIC=yes])
 144
 145 AC_ARG_ENABLE(
 146         [upnp],
 147         [AS_HELP_STRING(
 148                 [--disable-upnp],
 149                 [do not compile UPnP code])],
 150         [ENABLE_UPNP=$enableval], [ENABLE_UPNP=yes])
 151
 152 AC_ARG_ENABLE(
 153         [xas],
 154         [AS_HELP_STRING(
 155                 [--enable-xas],
 156                 [install xas XChat2 plugin])],
 157         [XAS=$enableval], [XAS=no])
 158
 159 # Default is yes, because they're most likely compatible.
 160 # However, this is only used when cross-compiling.
 161 AC_ARG_WITH(
 162         [gnu-malloc],
 163         [AS_HELP_STRING([--without-gnu-malloc],
 164                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
 165         [gnumalloc=$withval], [gnumalloc=yes])
 166
 167
 168 # Checking for libs before all other stuff to break
 169 # configure as soon as possible in case of a missing one
 170 # to avoid losing too much time
 171
 172 # Check for zlib
 173 MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])
 174
 175 AS_IF([test x$CAS = xyes], [
 176         # Check for gd
 177         MULE_CHECK_GDLIB([2.0.0], [
 178                 CAS_DEFS="-D__GD__"
 179                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 180         ], [CAS_DEFS=])
 181         AS_IF([test -z "$CAS_DEFS"],
 182                 [MULE_WARNING(
 183                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 184                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 185                         Or this might also be that your gdlib-config has other name.
 186                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 187                         If you use compiled packages check if you have devel pack installed.
 188                         To download the latest version check http://www.boutell.com/gd for sources.])])
 189 ], [GDLIB_VERSION="not_needed"])
 190 AC_SUBST([CAS_DEFS])dnl
 191
 192
 193 AS_IF([test x$WEB = xyes],
 194         [MULE_CHECK_REGEX(, [
 195                 WEB=disabled
 196                 MULE_WARNING([amuleweb has been disabled because configure could not find a POSIX compliant regex library.])
 197         ])
 198 ])
 199 AS_IF([test x$WEB = xyes],
 200         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 201                 MULE_WARNING(
 202                         [libpng >= 1.2.0 not found.
 203                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 204                 ])
 205         ], [LIBPNG_VERSION="not_needed"])
 206 AC_SUBST([AMULEWEB_DEFS])dnl
 207
 208
 209 # Check for perl File::Copy
 210 AC_MSG_CHECKING([for File::Copy])
 211 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])], [AC_MSG_ERROR([File::Copy perl module is required])])
 212
 213
 214 # Check if we need the GUI
 215 AC_MSG_CHECKING([whether we need the GUI])
 216 AS_IF([test x$MONOLITHIC = xyes], [need_gui=yes])
 217 AS_IF([test x$WXCAS = xyes], [need_gui=yes])
 218 AS_IF([test x$ALC = xyes], [need_gui=yes])
 219 AS_IF([test x$AMULE_GUI = xyes], [need_gui=yes])
 220 AS_IF([test x${need_gui:+set} != xset], [need_gui=no])
 221 AC_MSG_RESULT($need_gui)
 222
 223 # Check if we need to install skins
 224 AS_IF([test x$MONOLITHIC = xyes], [INSTALL_SKINS=yes])
 225 AS_IF([test x$AMULE_GUI = xyes], [INSTALL_SKINS=yes])
 226 AS_IF([test x${INSTALL_SKINS:+set} != xset], [INSTALL_SKINS=no])
 227
 228 # Check for GeoIP (required for IP2Country capability)
 229 MULE_CHECK_GEOIP
 230
 231 # Check for wx
 232 WX_CONFIG_OPTIONS
 233 WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 234 # Force using a static wxWidgets library if the executable is to be linked statically.
 235 AS_IF([test ${enable_static:-no} = yes], [WX_SHARED=0])
 236 # Force using a unicode build of the library
 237 WX_UNICODE=1
 238 DEBUG=$WX_DEBUG
 239 WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 240 WX_CONFIG_CHECK([2.8.0], [wxWin=1],,, [$WXCONFIG_FLAGS])
 241 if test "$wxWin" != 1; then
 242         AC_MSG_ERROR([
 243                 wxWidgets must be installed on your system but wx-config
 244                 script couldn't be found. Please check that wx-config is
 245                 in path or specified by --with-wx-config=path flag, the
 246                 directory where wxWidgets libraries are installed (returned
 247                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 248                 equivalent variable and wxWidgets version is 2.8.0 or above.
 249         ])
 250 fi
 251 WX_DETECT_STANDARD_OPTION_VALUES
 252
 253 # We also need wxBase
 254 WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 255 WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 256 WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 257 AC_SUBST([WXBASE_LIBS])
 258 AC_SUBST([WXBASE_CPPFLAGS])
 259
 260 dnl Get flags for windres
 261 AC_ARG_VAR([RC], [Resource Compiler])dnl
 262 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 263 AS_IF([test ${SYS:-unknown} = win32],
 264 [
 265         AC_CHECK_TOOL([RC], [windres], [:])
 266         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 267 ])
 268
 269
 270 # Check for libupnp
 271 AS_IF([test "${ENABLE_UPNP:-yes}" = yes], [
 272         LIBUPNP_CHECK(
 273                 [1.6.6],
 274                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 275                 [ENABLE_UPNP=disabled
 276                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 277         )
 278 ])dnl
 279
 280
 281 # Check for Crypto++
 282 MULE_CHECK_CRYPTOPP([5.1], [
 283         # Check for CryptoPP >= 5.5
 284         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 285 ], [
 286         AC_MSG_ERROR([
 287         Could not find crypto++ header file "$cryptopp_file_with_version".
 288         Please try again with --with-crypto-prefix=/my_crypto_prefix
 289         (replace /my_crypto_prefix with a valid path to your crypto++
 290         installation directory).])
 291 ])
 292
 293 dnl Checks requiring C++
 294 AC_LANG_PUSH([C++])
 295 MULE_CHECK_GLIBCXX
 296 MULE_CHECK_WX_SUPPORTS_LARGEFILE
 297
 298 # Check if the compiler is broken, wrt. exceptions.
 299 MULE_CHECK_EXCEPTIONS
 300
 301 MULE_CHECK_CXXABI
 302 AC_LANG_POP([C++])
 303
 304 # Check for bfd.h (to have proper backtraces without using wxExecute)
 305 MULE_CHECK_BFD
 306 MULE_CHECK_EXECINFO
 307
 308 # Ok, we have all needed libs, now checking for other stuff
 309 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 310
 311 # Flush standard test results for speeding cache
 312 AC_CACHE_SAVE
 313
 314 dnl -------------------------------------------------------------------------------
 315 dnl Start of autoscan stuff
 316 dnl -------------------------------------------------------------------------------
 317 # Checks for header files.
 318 AC_PATH_X
 319 AC_FUNC_ALLOCA
 320 AC_HEADER_DIRENT
 321 AC_HEADER_STDC
 322 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h  nl_types.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h sys/mman.h unistd.h])
 323 AC_HEADER_SYS_WAIT
 324
 325 # Checks for typedefs, structures, and compiler characteristics.
 326 AC_HEADER_STDBOOL
 327 AC_C_CONST
 328 AC_C_INLINE
 329 AC_TYPE_MODE_T
 330 AC_TYPE_OFF_T
 331 AC_TYPE_SIZE_T
 332 AC_HEADER_TIME
 333 AC_STRUCT_TM
 334 AC_TYPE_UID_T
 335 AC_C_VOLATILE
 336 AC_CHECK_TYPES([ptrdiff_t])
 337
 338 # Checks for library functions.
 339 AC_FUNC_CLOSEDIR_VOID
 340 AC_PROG_GCC_TRADITIONAL
 341 AC_FUNC_FORK
 342 AS_IF([test x$SYS != xwin32], [
 343         AC_FUNC_GETMNTENT
 344         AC_FUNC_LSTAT
 345         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 346 ])
 347 AC_FUNC_MEMCMP
 348 AC_FUNC_MMAP
 349 AC_FUNC_SELECT_ARGTYPES
 350 AC_FUNC_SETVBUF_REVERSED
 351 AC_TYPE_SIGNAL
 352 AC_FUNC_STAT
 353 AC_FUNC_STRFTIME
 354 AC_FUNC_STRTOD
 355 AC_FUNC_VPRINTF
 356 dnl Some other functions that worth checking deeper:
 357 dnl AC_FUNC_CLOSEDIR_VOID
 358 dnl AC_FUNC_MEMCMP
 359 dnl AC_FUNC_MMAP
 360 dnl AC_FUNC_STAT
 361 dnl AC_FUNC_STRTOD
 362 dnl AC_FUNC_SETVBUF_REVERSED
 363 dnl Anyways, do we actually USE them?
 364 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 365         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 366         ac_cv_func_malloc_0_nonnull=yes
 367         ac_cv_func_realloc_0_nonnull=yes
 368 ])
 369 AC_FUNC_MALLOC
 370 AC_FUNC_REALLOC
 371 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getpass gettimeofday inet_ntoa localeconv memmove mempcpy memset munmap nl_langinfo pow select setlocale socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul mmap])
 372 #-------------------------------------------------------------------------------
 373 # End of autoscan stuff
 374 #-------------------------------------------------------------------------------
 375
 376 dnl
 377 dnl autoscan has missed these ones.
 378 dnl
 379 AC_CHECK_FUNCS([mkdir getrlimit setrlimit getopt_long])
 380
 381 MULE_BACKUP([CPPFLAGS])
 382 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 383 AC_FUNC_STRERROR_R
 384 MULE_RESTORE([CPPFLAGS])
 385
 386 # Look for a way to preallocate disk space for files.
 387 MULE_CHECK_FALLOCATE
 388
 389 # Checking Native Language Support
 390 dnl Sets gettext version.
 391 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 392 AM_GNU_GETTEXT_VERSION(0.11.5)
 393 MULE_CHECK_NLS
 394
 395 # Flush standard test results for speeding cache
 396 AC_CACHE_SAVE
 397
 398 # Other tests
 399 # aMule options
 400 MULE_COMPILATION_FLAGS
 401
 402 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 403 AC_MSG_CHECKING([for docdir])
 404 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 405 AC_SUBST([docdir])dnl
 406 AC_MSG_RESULT([$docdir])
 407
 408 # Try to set the SVN checkout-date
 409 AC_MSG_CHECKING([for SVNDATE])
 410 if test -f "$srcdir/.svn-revision" # SVNDATE for tarballs
 411 then
 412         svndate="rev. `cat $srcdir/.svn-revision`"
 413 elif test -d $srcdir/.svn # SVNDATE for svn
 414 then
 415         svndate="rev. `svnversion $srcdir | sed -e 's/[[0-9]][[0-9]]*:\(.*\)/\1/' -e 's/\([[0-9]][[0-9]]*\).*/\1/'`"
 416 fi
 417 AC_MSG_RESULT(${svndate:-None required})
 418 AS_IF([test -n "$svndate"], [
 419             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 420             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 421 ])
 422 AC_SUBST([SVNDATE], [$svndate])dnl
 423
 424 dnl Set up the denoiser
 425 MULE_DENOISER
 426
 427 AM_CONDITIONAL(WEB, test x$WEB = xyes)
 428 AM_CONDITIONAL(ED2K, test x$ED2K = xyes)
 429 AM_CONDITIONAL(CAS, test x$CAS = xyes)
 430 AM_CONDITIONAL(WXCAS, test x$WXCAS = xyes)
 431 AM_CONDITIONAL(ALC, test x$ALC = xyes)
 432 AM_CONDITIONAL(ALCC, test x$ALCC = xyes)
 433 AM_CONDITIONAL(AMULE_GUI, test x$AMULE_GUI = xyes)
 434 AM_CONDITIONAL(AMULE_DAEMON, test x$AMULE_DAEMON = xyes)
 435 AM_CONDITIONAL(COMPILE_CMD, test x$AMULECMD = xyes)
 436 AM_CONDITIONAL(MONOLITHIC, test x$MONOLITHIC = xyes)
 437 AM_CONDITIONAL(XAS, test x$XAS = xyes)
 438 AM_CONDITIONAL(ENABLE_UPNP, test x$ENABLE_UPNP = xyes)
 439 AM_CONDITIONAL(ENABLE_IP2COUNTRY, test x$ENABLE_IP2COUNTRY = xyes)
 440 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 441 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 442 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 443 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 444 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 445 AM_CONDITIONAL(INSTALL_SKINS, test x$INSTALL_SKINS = xyes)
 446
 447 # Check for readline library
 448 if test x$AMULECMD = xyes -o x$WEB = xyes; then
 449         VL_LIB_READLINE
 450 fi
 451
 452 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 453
 454 MULE_CHECK_CCACHE
 455
 456 dnl
 457 dnl Generate the Makefiles
 458 dnl
 459 AC_CONFIG_FILES([Makefile
 460                  docs/Makefile
 461                  docs/man/Makefile
 462                  intl/Makefile
 463                  src/Makefile
 464                  src/pixmaps/Makefile
 465                  src/pixmaps/flags_xpm/Makefile
 466                  src/libs/Makefile
 467                  src/libs/ec/Makefile
 468                  src/libs/ec/cpp/Makefile
 469                  src/libs/common/Makefile
 470                  src/utils/Makefile
 471                  src/utils/aLinkCreator/Makefile
 472                  src/utils/aLinkCreator/docs/Makefile
 473                  src/utils/aLinkCreator/src/Makefile
 474                  src/utils/cas/Makefile
 475                  src/utils/cas/docs/Makefile
 476                  src/utils/fileview/Makefile
 477                  src/utils/wxCas/Makefile
 478                  src/utils/wxCas/docs/Makefile
 479                  src/utils/wxCas/src/Makefile
 480                  src/utils/xas/Makefile
 481                  src/utils/xas/autostart-xas
 482                  src/utils/xas/docs/Makefile
 483                  src/skins/Makefile
 484                  src/webserver/Makefile
 485                  src/webserver/src/Makefile
 486                  src/webserver/default/Makefile
 487                  unittests/Makefile
 488                  unittests/muleunit/Makefile
 489                  unittests/tests/Makefile])
 490 dnl
 491 dnl autoscan has missed these, i wonder why...
 492 dnl
 493 AC_CONFIG_FILES([po/Makefile.in
 494                  Compilation.flags])
 495 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 496 AC_OUTPUT
 497
 498 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 499
 500 echo
 501 echo
 502 echo "  Configure script has finished system check."
 503 echo
 504 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 505 echo
 506 echo "  aMule enabled options:"
 507 echo
 508 echo "  **** aMule Core ****"
 509 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 510 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 511 echo "  Should aMule be compiled in debug mode?                    ${USE_DEBUG:-no}"
 512 echo "  Should aMule be compiled with profiling?                   ${USE_PROFILE:-no}"
 513 echo "  Should aMule be compiled with optimizations?               ${USE_OPTIMIZE:-no}"
 514 echo "  Should aMule be compiled with UPnP support?                ${ENABLE_UPNP:-yes}"
 515 echo "  Should aMule be compiled with IP2country support?          ${ENABLE_IP2COUNTRY:-no}"
 516 echo "  Should aMule monolithic application be built?              ${MONOLITHIC:-yes}"
 517 echo "  Should aMule daemon version be built?                      ${AMULE_DAEMON:-no}"
 518 echo "  Should aMule remote gui be built? (EXPERIMENTAL)           ${AMULE_GUI:-no}"
 519 echo "  Crypto++ library/headers style?                            ${CRYPTOPP_STYLE:-not found}"
 520
 521 echo
 522 echo "  **** aMule TextClient ****"
 523 echo "  Should aMule Command Line Client be built?                 ${AMULECMD:-no}"
 524 echo
 525 echo "  **** aMule WebServer ****"
 526 echo "  Should aMule WebServer be built?                           ${WEB:-no}"
 527 echo
 528 echo "  **** aMule ED2K Links Handler ****"
 529 echo "  Should aMule ED2K Links Handler be built?                  ${ED2K:-yes}"
 530 echo
 531 echo "  **** aMuleLinkCreator ****"
 532 echo "  Should aMuleLinkCreator GUI version (alc) be built?        ${ALC:-no}"
 533 echo "  Should aMuleLinkCreator for console (alcc) be built?       ${ALCC:-no}"
 534 echo
 535 echo "  **** aMule Statistics ****"
 536 echo "  Should C aMule Statistics (CAS) be built?                  ${CAS:-no}"
 537 echo "  Should aMule GUI Statistics (wxCas) be built?              ${WXCAS:-no}"
 538 echo "  Should xas XChat2 plugin be installed?                     ${XAS:-yes}"
 539
 540 echo
 541 echo "  **** General Libraries and Tools ****"
 542 echo "  Should ccache support be enabled?                          ${enable_ccache:-no}"
 543 echo "  Libraries aMule will use to build:"
 544 wxinfo="$WX_PORT"
 545 AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 546 AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 547 echo "                                       wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 548 echo "                                       crypto++              ${CRYPTOPP_VERSION_STRING} (${CRYPTOPP_STYLE}, in ${CRYPTOPP_PREFIX})"
 549 AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 550 AS_IF([test x${ENABLE_UPNP} = xyes], [dnl
 551 echo "                                       libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"
 552 ])dnl
 553 if test x${WEB:-no} != xno; then
 554 AS_IF([test $regex_found = no],
 555         [regex_found="Not detected"],
 556         [AS_IF([test -z "$REGEX_LIB"],
 557                 [regex_found=system],
 558                 [regex_found="standalone (in $REGEX_LIB)"])])
 559 echo "                                       regex                 $regex_found"
 560 fi
 561 if test ${enable_nls:-yes} = yes; then
 562 AS_IF([test x$USE_NLS = xno],
 563         [libintl_found="Not detected"],
 564         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 565                 [libintl_found="included"],
 566                 [libintl_found="system"])])
 567 echo "                                       libintl               $libintl_found"
 568 fi
 569 AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 570 AS_IF([test ${ENABLE_IP2COUNTRY:-no} = yes], [echo "                                       libGeoIP              ${geoip_style}"])
 571 if test x$LIBPNG_VERSION != xnot_needed; then
 572 echo "                                       libpng                ${LIBPNG_VERSION:-Not detected}"
 573 fi
 574 if test x$GDLIB_VERSION != xnot_needed; then
 575 echo "                                       libgd                 ${GDLIB_VERSION:-Not detected}"
 576 fi
 577 echo "                                       zlib                  ${ZLIB_VERSION:-Not detected}"