acinclude.m4

   1 #                                                       -*- Autoconf -*-
   2 # This file is part of the aMule Project.
   3 #
   4 # Copyright (c) 2003-2008 aMule Team ( admin@amule.org / http://www.amule.org )
   5 #
   6 # Any parts of this program derived from the xMule, lMule or eMule project,
   7 # or contributed by third-party developers are copyrighted by their
   8 # respective authors.
   9 #
  10 # This program is free software; you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 2 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program; if not, write to the Free Software
  22 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  23 #
  24
  25 dnl ---------------------------------------------------------------------------
  26 dnl Helper functions
  27 dnl ---------------------------------------------------------------------------
  28 m4_pattern_forbid(MULE_)dnl Check for unexpanded *MULE_* macros
  29 m4_pattern_allow(AMULE_)dnl Allow the *AMULE_* names
  30
  31 dnl MULE_APPEND(VARNAME, VALUE)
  32 AC_DEFUN([MULE_APPEND], [$1="$$1 $2"])
  33
  34 dnl MULE_PREPEND(VARNAME, VALUE)
  35 AC_DEFUN([MULE_PREPEND], [$1="$2 $$1"])
  36
  37 dnl MULE_ADDFLAG(FLAGTYPE, VALUE)
  38 AC_DEFUN([MULE_ADDFLAG], [MULE_APPEND([MULE[]$1[]FLAGS], [$2])])
  39
  40 dnl MULE_ADDCCXXFLAG(VALUE)
  41 AC_DEFUN([MULE_ADDCCXXFLAG],
  42 [
  43         MULE_ADDFLAG([C], [$1])
  44         MULE_ADDFLAG([CXX], [$1])
  45 ])
  46
  47 dnl MULE_BACKUP(VAR)
  48 AC_DEFUN([MULE_BACKUP], [mule_backup_$1="$$1"])
  49
  50 dnl MULE_RESTORE(VAR)
  51 AC_DEFUN([MULE_RESTORE], [$1="$mule_backup_$1"])
  52
  53 dnl ---------------------------------------------------------------------------
  54 dnl MULE_IF(CONDITION, [IF-TRUE] [, ELIF-CONDITION, [IF-TRUE]]... [, ELSE-BRANCH])
  55 dnl
  56 dnl Works like AS_IF(), but allows elif-branches too.
  57 dnl ---------------------------------------------------------------------------
  58 m4_define([__mule_if_helper],
  59 [m4_if( [$#], 0,,
  60         [$#], 1, [m4_ifvaln([$1], [m4_n([else])  $1])],
  61         [m4_n([elif $1; then])  m4_ifvaln([$2], [$2], :)])dnl
  62 m4_if(m4_eval([$# > 2]), 1, [$0(m4_shiftn(2, $@))])])
  63
  64 m4_define([MULE_IF],
  65 [m4_if( [$#], 0,,
  66         [$#], 1,,
  67         [m4_n([if $1; then])  m4_ifval([$2],[$2], :)
  68 m4_if(m4_eval([$# > 2]), 1, [__mule_if_helper(m4_shiftn(2, $@))])m4_n([fi])])])
  69
  70 dnl ---------------------------------------------------------------------------
  71 dnl MULE_WARNING(MESSAGE)
  72 dnl
  73 dnl Works like AC_MSG_WARN(), but the warning will be reproduced at the end of
  74 dnl the configure run. An empty line is prepended at the final output and a
  75 dnl newline is appended for free.
  76 dnl ---------------------------------------------------------------------------
  77 m4_define([_MULE_WARNINGS],
  78         [m4_ifdef([_m4_divert(BODY)], incr(_m4_divert(BODY)), [5000])])
  79 m4_define([_MULE_WARNCOUNT], [0])
  80
  81 m4_divert_push(_MULE_WARNINGS)dnl
  82 if test ${_mule_has_warnings:-no} = yes; then
  83 echo ""
  84 echo ""
  85 echo " *** Warnings during configuration ***"
  86 fi
  87 m4_divert_pop()dnl
  88
  89 m4_define([MULE_WARNING],
  90 [AC_MSG_WARN(
  91 m4_pushdef([_mule_Prefix], [        ])dnl
  92 m4_foreach([_mule_Line], m4_quote(m4_split([$1], [
  93 ])), [
  94 m4_text_wrap(m4_defn([_mule_Line]), _mule_Prefix)])[]dnl
  95 m4_popdef([_mule_Prefix])dnl
  96 )
  97 _mule_warning_[]_MULE_WARNCOUNT[]=yes
  98 _mule_has_warnings=yes
  99 m4_divert_push(_MULE_WARNINGS)dnl
 100 if test ${_mule_warning_[]_MULE_WARNCOUNT[]:-no} = yes; then
 101 cat <<_MULEEOT
 102
 103 m4_pushdef([_mule_Prefix1], [* ])dnl
 104 m4_pushdef([_mule_Prefix], [  ])dnl
 105 m4_foreach([_mule_Line], m4_quote(m4_split([$1], [
 106 ])), [m4_text_wrap(m4_defn([_mule_Line]), _mule_Prefix, _mule_Prefix1)
 107 m4_define([_mule_Prefix1], _mule_Prefix)dnl
 108 ])[]dnl
 109 m4_popdef([_mule_Prefix])dnl
 110 m4_popdef([_mule_Prefix1])dnl
 111 _MULEEOT
 112 fi
 113 m4_divert_pop()dnl
 114 m4_define([_MULE_WARNCOUNT], incr(_MULE_WARNCOUNT))])
 115
 116 dnl ---------------------------------------------------------------------------
 117 dnl MULE_CHECK_SYSTEM
 118 dnl
 119 dnl Checks host system type, and sets system-specific flags accordingly.
 120 dnl Sets $SYS to the name of the host os.
 121 dnl ---------------------------------------------------------------------------
 122 AC_DEFUN([MULE_CHECK_SYSTEM],
 123 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
 124
 125         case "${host_os}" in
 126         darwin*)
 127                 SYS=darwin
 128                 MULECPPFLAGS="-no-cpp-precomp -D_INTL_REDIRECT_MACROS -DNOPCH";
 129                 MULELDFLAGS="-bind_at_load"
 130                 touch src/Scanner.cpp
 131                 ;;
 132         openbsd*)
 133                 SYS=openbsd
 134                 LIBS="$LIBS -L/usr/local/lib"
 135                 MULECPPFLAGS="-D__OPENBSD__"
 136                 ;;
 137         *cygwin* | *mingw32*)
 138                 SYS=win32
 139                 MULECPPFLAGS="-DNOMINMAX"
 140                 ;;
 141         solaris*)
 142                 SYS=solaris
 143                 RESOLV_LIB="-lresolv -lnsl"
 144                 LIBS="$LIBS -lrt"
 145                 ;;
 146         *netbsd*)
 147                 SYS=netbsd
 148                 # Now this is against autoconf recommendation that configure should not modify CPPFLAGS and LDFLAGS
 149                 # However, these values in NetBSD are required even to run the tests, and this is the easiest way to do it.
 150                 # Still, we prepend them, instead of adding, so the user may override them.
 151                 MULE_PREPEND([CPPFLAGS], [-I/usr/pkg/include])
 152                 MULE_PREPEND([LDFLAGS], [-R/usr/pkg/lib -L/usr/pkg/lib])
 153                 ;;
 154         *irix*)
 155                 SYS=irix
 156                 MULECPPFLAGS="-D__IRIX__"
 157                 ;;
 158         *)
 159                 SYS=unknown
 160                 ;;
 161         esac
 162
 163         # -lpthread is needed by Debian but FreeBSD < 5 doesn't support it
 164         AS_IF([test ${SYS:-unknown} != win32],
 165         [
 166                 AC_MSG_CHECKING([if this is a FreeBSD 4 or earlier system])
 167                 AS_IF([test x"`uname -s`" = xFreeBSD && test 0`uname -r | cut -c 1` -lt 5],
 168                 [
 169                         MULE_ADDFLAG([LD], [-pthread])
 170                         AC_MSG_RESULT(yes)
 171                 ], [
 172                         MULE_ADDFLAG([LD], [-lpthread])
 173                         AC_MSG_RESULT(no)
 174                 ])
 175         ])
 176
 177 AC_SUBST([RESOLV_LIB])dnl
 178 AC_SUBST([MULECPPFLAGS])dnl
 179 AC_SUBST([MULECFLAGS])dnl
 180 AC_SUBST([MULECXXFLAGS])dnl
 181 AC_SUBST([MULELDFLAGS])dnl
 182 AC_SUBST([MULERCFLAGS])dnl
 183 ])
 184
 185 dnl ---------------------------------------------------------------------------
 186 dnl _MULE_CHECK_DEBUG_FLAG
 187 dnl ---------------------------------------------------------------------------
 188 AC_DEFUN([_MULE_CHECK_DEBUG_FLAG],
 189 [AC_REQUIRE([MULE_CHECK_GLIBCXX])dnl
 190
 191         AC_ARG_ENABLE(
 192                 [debug],
 193                 [AS_HELP_STRING([--disable-debug], [disable additional debugging output])],
 194                 [USE_DEBUG=${enableval:-yes}], [USE_DEBUG=yes])
 195
 196         AS_IF([test $USE_DEBUG = yes],
 197         [
 198                 MULE_ADDFLAG([CPP], [-D__DEBUG__])
 199                 MULE_ADDCCXXFLAG([-g])
 200                 AS_IF([test ${GLIBCXX:-no} = yes],      [MULE_ADDFLAG([CPP], [-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC])])
 201                 AS_IF([test ${GCC:-no} = yes],          [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef -ggdb -fno-inline -fmessage-length=0])])
 202                 AS_IF([test ${SYS:-unknown} = win32],   [MULE_ADDFLAG([RC], [-D__DEBUG__])])
 203         ], [
 204                 AS_IF([test ${GCC:-no} = yes], [MULE_ADDCCXXFLAG([-W -Wall -Wshadow -Wundef])])
 205         ])
 206 ])
 207
 208 dnl ---------------------------------------------------------------------------
 209 dnl _MULE_CHECK_PROFILE_FLAG
 210 dnl ---------------------------------------------------------------------------
 211 AC_DEFUN([_MULE_CHECK_PROFILE_FLAG],
 212 [
 213         AC_ARG_ENABLE(
 214                 [profile],
 215                 [AS_HELP_STRING([--enable-profile], [enable code profiling])],
 216                 [USE_PROFILE=${enableval:-no}], [USE_PROFILE=no])
 217
 218         AS_IF([test $USE_PROFILE = yes],
 219         [
 220                 MULE_ADDCCXXFLAG([-pg])
 221                 MULE_ADDFLAG([LD], [-pg])
 222         ])
 223 ])
 224
 225 dnl ---------------------------------------------------------------------------
 226 dnl _MULE_CHECK_OPTIMIZE_FLAG
 227 dnl ---------------------------------------------------------------------------
 228 AC_DEFUN([_MULE_CHECK_OPTIMIZE_FLAG],
 229 [
 230         AC_ARG_ENABLE(
 231                 [optimize],
 232                 [AS_HELP_STRING([--enable-optimize], [enable code optimization])],
 233                 [USE_OPTIMIZE=${enableval:-no}], [USE_OPTIMIZE=no])
 234
 235         AS_IF([test $USE_OPTIMIZE = yes], [MULE_ADDCCXXFLAG([-O2])])
 236 ])
 237
 238 dnl ---------------------------------------------------------------------------
 239 dnl MULE_COMPILATION_FLAGS
 240 dnl
 241 dnl Checks type of compilation requested by user, and sets various flags
 242 dnl accordingly.
 243 dnl ---------------------------------------------------------------------------
 244 AC_DEFUN([MULE_COMPILATION_FLAGS],
 245 [
 246         _MULE_CHECK_DEBUG_FLAG
 247         _MULE_CHECK_OPTIMIZE_FLAG
 248         _MULE_CHECK_PROFILE_FLAG
 249
 250         AC_MSG_CHECKING([if the applications should be statically linked])
 251         AC_ARG_ENABLE(
 252                 [static],
 253                 [AS_HELP_STRING([--enable-static], [produce a statically linked executable])],
 254                 [AS_IF([test ${enableval:-no} = yes], [MULE_ADDFLAG([LD], [-static])])])
 255         AC_MSG_RESULT(${enableval:-no})
 256
 257         MULE_ADDFLAG([CPP], [-DUSE_WX_EXTENSIONS])
 258 ])
 259
 260 dnl ---------------------------------------------------------------------------
 261 dnl MULE_CHECK_GLIBCXX
 262 dnl
 263 dnl Checks whether we use the GNU C++ Library.
 264 dnl ---------------------------------------------------------------------------
 265 AC_DEFUN([MULE_CHECK_GLIBCXX],
 266 [dnl
 267 AC_REQUIRE([AC_PROG_EGREP])dnl
 268 AC_REQUIRE([AC_PROG_CXXCPP])dnl
 269 AC_LANG_ASSERT([C++])dnl
 270
 271         AC_MSG_CHECKING([if we're using the GNU C++ library])
 272         AC_PREPROC_IFELSE([
 273                 AC_LANG_SOURCE([[
 274                         #include <string>
 275                         #ifndef __GLIBCXX__
 276                         #error Non-GNU C++ library found.
 277                         #endif
 278                 ]])
 279         ], [GLIBCXX=yes], [GLIBCXX=no])
 280         AC_MSG_RESULT([$GLIBCXX])
 281 ])
 282
 283 dnl ---------------------------------------------------------------------------
 284 dnl MULE_CHECK_WX_SUPPORTS_LARGEFILE
 285 dnl
 286 dnl Test that wxWidgets is built with support for large-files. If not
 287 dnl configure is terminated.
 288 dnl ---------------------------------------------------------------------------
 289 AC_DEFUN([MULE_CHECK_WX_SUPPORTS_LARGEFILE],
 290 [AC_LANG_ASSERT([C++])dnl
 291
 292         dnl Backup current flags and setup flags for testing
 293         MULE_BACKUP([CPPFLAGS])
 294         MULE_APPEND([CPPFLAGS], [$WX_CPPFLAGS])
 295
 296         AC_MSG_CHECKING([that wxWidgets has support for large files])
 297         AC_PREPROC_IFELSE([
 298                 AC_LANG_SOURCE([[
 299                         #include <wx/wx.h>
 300                         #include <wx/filefn.h>
 301                         #ifndef wxHAS_LARGE_FILES
 302                                 #error No LargeFile support!
 303                         #endif
 304                 ]])
 305         ], [
 306                 AC_MSG_RESULT([yes])
 307         ], [
 308                 AC_MSG_RESULT([no])
 309                 AC_MSG_ERROR([
 310         Support for large files in wxWidgets is required by aMule.
 311         To continue you must recompile wxWidgets with support for
 312         large files enabled.])
 313         ])
 314
 315         dnl Restore backup'd flags
 316         MULE_RESTORE([CPPFLAGS])
 317 ])
 318
 319
 320 dnl --------------------------------------------------------------------------
 321 dnl MULE_CHECK_CCACHE
 322 dnl
 323 dnl Checks if ccache is requested and available, and makes use of it
 324 dnl --------------------------------------------------------------------------
 325 AC_DEFUN([MULE_CHECK_CCACHE],
 326 [
 327         AC_ARG_ENABLE([ccache],
 328                 [AS_HELP_STRING([--enable-ccache], [enable ccache support for fast recompilation])])
 329
 330         AC_ARG_WITH([ccache-prefix],
 331                 [AS_HELP_STRING([--with-ccache-prefix=PREFIX], [prefix where ccache is installed])])
 332
 333         AC_MSG_CHECKING([whether ccache support should be added])
 334         AC_MSG_RESULT([${enable_ccache:-no}])
 335
 336         AS_IF([test ${enable_ccache:-no} = yes], [
 337                 AC_MSG_CHECKING([for ccache presence])
 338                 AS_IF([test -z "$with_ccache_prefix"], [
 339                         ccache_full=`which ccache`
 340                         with_ccache_prefix=`dirname ${ccache_full}`
 341                 ])
 342                 AS_IF([$with_ccache_prefix/ccache -V >/dev/null 2>&1], [
 343                         AC_MSG_RESULT([yes])
 344                         CC="$with_ccache_prefix/ccache $CC"
 345                         CXX="$with_ccache_prefix/ccache $CXX"
 346                         BUILD_CC="$with_ccache_prefix/ccache $BUILD_CC"
 347                 ], [
 348                         enable_ccache=no
 349                         AC_MSG_RESULT([no])
 350                 ])
 351         ])
 352 ])
 353
 354
 355 dnl ----------------------------------------------------
 356 dnl MULE_CHECK_BFD
 357 dnl check if bfd.h is on the system and usable
 358 dnl ----------------------------------------------------
 359 AC_DEFUN([MULE_CHECK_BFD],
 360 [AC_REQUIRE([MULE_CHECK_NLS])dnl
 361
 362         AC_MSG_CHECKING([for bfd])
 363         result=no
 364         for bfd_ldadd in "" "${LIBINTL}"; do
 365                 MULE_BACKUP([LIBS])
 366                 MULE_BACKUP([LDFLAGS])
 367                 MULE_PREPEND([LIBS], [-lbfd -liberty ${bfd_ldadd} ${ZLIB_LIBS}])
 368                 MULE_APPEND([LDFLAGS], [${ZLIB_LDFLAGS}])
 369                 AC_LINK_IFELSE([
 370                         AC_LANG_PROGRAM([[
 371                                 #include <ansidecl.h>
 372                                 #include <bfd.h>
 373                         ]], [[
 374                                 char *dummy = bfd_errmsg(bfd_get_error());
 375                         ]])
 376                 ], [
 377                         result=yes
 378                         BFD_CPPFLAGS="-DHAVE_BFD"
 379                         BFD_LIBS="-lbfd -liberty ${bfd_ldadd}"
 380                         MULE_RESTORE([LIBS])
 381                         MULE_RESTORE([LDFLAGS])
 382                         break
 383                 ])
 384                 MULE_RESTORE([LIBS])
 385                 MULE_RESTORE([LDFLAGS])
 386         done
 387
 388         AC_MSG_RESULT([$result])
 389
 390         AS_IF([test $result = no],
 391                 [MULE_WARNING([bfd.h not found or unusable, please install binutils development package if you are a developer or want to help testing aMule])])
 392
 393 AC_SUBST([BFD_CPPFLAGS])dnl
 394 AC_SUBST([BFD_LIBS])dnl
 395 ])
 396
 397
 398 dnl ----------------------------------------------------
 399 dnl MULE_CHECK_FLEX_EXTENDED
 400 dnl check if flex can produce header files
 401 dnl ----------------------------------------------------
 402 AC_DEFUN([MULE_CHECK_FLEX_EXTENDED],
 403 [
 404         AC_MSG_CHECKING([for extended flex capabilities])
 405
 406         extended_flex=`flex --help | grep header-file`
 407         AS_IF([test -n "$extended_flex"], [HAVE_FLEX_EXTENDED=yes], [HAVE_FLEX_EXTENDED=no])
 408         AC_MSG_RESULT($HAVE_FLEX_EXTENDED)
 409
 410         AS_IF([test $HAVE_FLEX_EXTENDED = no], [AC_MSG_NOTICE([Your flex version doesn't support --header-file flag. This is not critical, but an upgrade is recommended])])
 411 ])
 412
 413
 414 dnl ----------------------------------------------------
 415 dnl MULE_CHECK_EXCEPTIONS
 416 dnl Checks for broken exception-handling. This is needed
 417 dnl because exception handling is broken for some archs/
 418 dnl compilers.
 419 dnl ----------------------------------------------------
 420 AC_DEFUN([MULE_CHECK_EXCEPTIONS],
 421 [AC_LANG_ASSERT([C++])dnl
 422
 423         AC_MSG_CHECKING([for exception-handling])
 424         AC_RUN_IFELSE([
 425                 AC_LANG_PROGRAM(, [[
 426                         try {
 427                                 throw 1;
 428                         } catch (int) {
 429                                 return 0;
 430                         }
 431                         return 1;
 432                 ]])
 433         ], [
 434                 AC_MSG_RESULT([yes])
 435         ], [
 436                 AC_MSG_RESULT([no])
 437                 AC_MSG_ERROR([Exception handling does not work. Broken compiler?])
 438         ], [
 439                 AC_MSG_RESULT([undeterminable])
 440                 MULE_WARNING(
 441                         [Cross-compilation detected, so exception handling cannot be tested.
 442                         Note that broken exception handling in your compiler may lead to unexpected crashes.])
 443         ])
 444 ])
 445
 446
 447 dnl ---------------------------------------------------------------------------
 448 dnl MULE_CHECK_CXXABI
 449 dnl
 450 dnl This function will test the header <cxxabi.h> and abi::__cxa_demangle()
 451 dnl ---------------------------------------------------------------------------
 452 AC_DEFUN([MULE_CHECK_CXXABI],
 453 [AC_LANG_ASSERT([C++])dnl
 454
 455         AC_MSG_CHECKING([for <cxxabi.h> and __cxa_demangle()])
 456         AC_LINK_IFELSE([
 457                 AC_LANG_PROGRAM([[
 458                         #include <cxxabi.h>
 459                 ]], [[
 460                         int status;
 461                         char * demangled = abi::__cxa_demangle("", 0, 0, &status);
 462                         std::type_info *ti = abi::__cxa_current_exception_type();
 463                 ]])
 464         ], [
 465                 AH_TEMPLATE([HAVE_CXXABI], [Define to 1 if you have the <cxxabi.h> header which declares abi::__cxa_demangle()])
 466                 AC_DEFINE([HAVE_CXXABI])
 467                 AC_MSG_RESULT([yes])
 468         ], [
 469                 AC_MSG_RESULT([no])
 470         ])
 471 ])
 472
 473
 474 dnl ---------------------------------------------------------------------------
 475 dnl MULE_CHECK_EXECINFO
 476 dnl
 477 dnl This function will test the header <execinfo.h> and backtrace()
 478 dnl ---------------------------------------------------------------------------
 479 AC_DEFUN([MULE_CHECK_EXECINFO],
 480 [
 481         AC_MSG_CHECKING([for <execinfo.h> and backtrace()])
 482         AC_LINK_IFELSE([
 483                 AC_LANG_PROGRAM([[
 484                         #include <execinfo.h>
 485                 ]], [[
 486                         void *bt[1];
 487                         int n = backtrace(&bt, 1);
 488                         const char **bt_syms = backtrace_symbols(bt, n);
 489                 ]])
 490         ], [
 491                 AH_TEMPLATE([HAVE_EXECINFO], [Define to 1 if you have the <execinfo.h> header which declares backtrace()])
 492                 AC_DEFINE([HAVE_EXECINFO])
 493                 AC_MSG_RESULT([yes])
 494         ], [
 495                 AC_MSG_RESULT([no])
 496         ])
 497 ])
 498
 499
 500 dnl ---------------------------------------------------------------------------
 501 dnl MULE_DENOISER
 502 dnl
 503 dnl Test for denoising level and add denoiser commands to config.status
 504 dnl ---------------------------------------------------------------------------
 505 AC_DEFUN([MULE_DENOISER],
 506 [
 507         AC_ARG_WITH([denoise-level],
 508                 [AS_HELP_STRING([--with-denoise-level=<level>], [Specifies denoising level (0-4):])
 509                 AS_HELP_STRING([], [0 - Do nothing])
 510                 AS_HELP_STRING([], [4 - Suppress all normal output])
 511                 AS_HELP_STRING([], [(for more information see src/utils/scripts/denoiser.rules)])
 512         ])
 513
 514         AC_MSG_CHECKING([denoising level])
 515         AS_IF([test ${with_denoise_level:-5} = yes], [with_denoise_level=5])
 516         AS_IF([test ${with_denoise_level:-5} = no], [with_denoise_level=0])
 517         AS_IF([test ${with_denoise_level:-5} -gt 4],
 518                 [AS_IF([test "${svndate:+set}" = "set"], [with_denoise_level=0], [with_denoise_level=4])])
 519         AC_MSG_RESULT([$with_denoise_level])
 520
 521         AC_CONFIG_COMMANDS([denoiser], [[if test $denoiserlevel -gt 0; then
 522                 if test ! -d src/utils/scripts; then mkdir -p src/utils/scripts; fi
 523                 sed -e "1{x;s/.*/1/;x;};/^[     ]*\$/d;/^#if /{/level.*$denoiserlevel/{x;s/^/1/;x;b0;};x;s/^/0/;x;:0;d;};/^#else/{x;/^1/{s/1/0/;b1;};s/0/1/;:1;x;d;};/^#endif/{x;s/.//;x;d;};/^[        ]*#/d;x;/^1/{x;b;};x;d" \
 524                         $srcdir/src/utils/scripts/denoiser.rules > src/utils/scripts/denoiser.sed
 525                 for i in `find . -name 'Makefile' -print`; do
 526                         if test -n "`head -n 1 $i | grep '^#'`"; then
 527                                 sed -f src/utils/scripts/denoiser.sed $i > $i.tmp && mv $i.tmp $i
 528                         fi
 529                 done
 530         fi]], [denoiserlevel=$with_denoise_level])
 531 ])