acpid/trunk/PKGBUILD

   1 # Maintainer: Morten Linderud <foxboron@archlinux.org>
   2 # Contributor: Sébastien Luttringer
   3 # Contributor: xduugu
   4 # Contributor: Manolis Tzanidakis
   5 # Contributor: Jonathan Schmidt <j.schmidt@archlinux.us
   6
   7 pkgname=acpid
   8 pkgver=2.0.34
   9 pkgrel=1
  10 pkgdesc='A daemon for delivering ACPI power management events with netlink support'
  11 arch=('x86_64')
  12 url='https://sourceforge.net/projects/acpid2/'
  13 license=('GPL')
  14 depends=('bash')
  15 optdepends=('perl: use perl based examples')
  16 replaces=('acpid2')
  17 backup=('etc/acpi/handler.sh' 'etc/acpi/events/anything')
  18 source=("https://downloads.sourceforge.net/sourceforge/acpid2/$pkgname-$pkgver.tar.xz"
  19         'acpid.service'
  20         'anything'
  21         'handler.sh')
  22 sha256sums=('2d095c8cfcbc847caec746d62cdc8d0bff1ec1bc72ef7c674c721e04da6ab333'
  23             'a8236bbf774f5e90a4daa369731d6d335c3374ddc62f1224fba02a3d6d678111'
  24             'eb5230affb9dba7653890655b94e83f377c689a39131b6b13c8202ba2382c275'
  25             '1c1e39b7ecc57092ba9d747f452fb36d8ae0456e2e64849c9c4a2625d1d57413')
  26
  27 build() {
  28   cd $pkgname-$pkgver
  29   ./configure --prefix=/usr --sbindir=/usr/bin
  30   make
  31 }
  32
  33 package() {
  34   cd $pkgname-$pkgver
  35   make DESTDIR="$pkgdir" install
  36
  37   # default config
  38   install -Dm644 ../anything "$pkgdir/etc/acpi/events/anything"
  39   install -Dm755 ../handler.sh "$pkgdir/etc/acpi/handler.sh"
  40
  41   # systemd
  42   install -Dm644 ../acpid.service "$pkgdir/usr/lib/systemd/system/acpid.service"
  43 }
  44
  45 # vim:set ts=2 sw=2 et: