cargo-deb/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: Sematre <sematre at gmx dot de>
   3
   4 pkgname=cargo-deb
   5 pkgver=1.43.1
   6 pkgrel=1
   7 pkgdesc="Cargo subcommand that generates Debian packages"
   8 arch=('x86_64')
   9 url="https://github.com/kornelski/cargo-deb"
  10 license=('MIT')
  11 depends=('xz')
  12 makedepends=('cargo')
  13 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  14 sha256sums=('ed2d35ae4fedab28498d5eb3490485df9fdd6209d59f6ac575cf78261e18d16f')
  15
  16 prepare() {
  17   cd "$pkgname-$pkgver"
  18   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  19 }
  20
  21 build() {
  22   cd "$pkgname-$pkgver"
  23   cargo build --release --frozen
  24 }
  25
  26
  27 check() {
  28   cd "$pkgname-$pkgver"
  29   cargo test --frozen -- --skip "dependencies::resolve_test"
  30 }
  31
  32 package() {
  33   cd "$pkgname-$pkgver"
  34   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  35   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  36   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  37 }
  38
  39 # vim:set ts=2 sw=2 et: