cl-trivial-gray-streams/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=cl-trivial-gray-streams
   4 _pkgname="${pkgname#cl-}"
   5 pkgver=2.0.0.r47.g2b3823e
   6 pkgrel=1
   7 pkgdesc='Compatibility layer for Gray Streams'
   8 arch=('any')
   9 url='https://trivial-gray-streams.common-lisp.dev'
  10 license=('MIT')
  11 depends=('common-lisp' 'cl-asdf')
  12 makedepends=('git')
  13 checkdepends=('sbcl')
  14 _commit='2b3823edbc78a450db4891fd2b566ca0316a7876'
  15 source=(
  16   "$pkgname::git+https://github.com/trivial-gray-streams/trivial-gray-streams#commit=$_commit"
  17   'run-tests.lisp'
  18 )
  19 b2sums=('SKIP'
  20         '7af6a2946854fcaa07f5ca24d3c1738b8a9eb6762c4fb8f900a3abc3b22913b50d90b29c9676837153ffc2cc8f14833718dd5e40cf8b72b47ff37e999a89efba')
  21
  22 pkgver() {
  23   cd "$pkgname"
  24
  25   # first known commit to receive latest version
  26   local _pkgcommit='99f579bd352156ad6dadcf347696a0a34a9e0f82'
  27   local _pkgver='2.0.0'
  28   git tag "$_pkgver" "$_pkgcommit"
  29
  30   git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
  31 }
  32
  33 check() {
  34   cd "$pkgname"
  35
  36   sbcl --script ../run-tests.lisp
  37 }
  38
  39 package() {
  40   cd "$pkgname"
  41
  42   # create directories
  43   install -vd \
  44     "$pkgdir/usr/share/common-lisp/source/$_pkgname" \
  45     "$pkgdir/usr/share/common-lisp/systems"
  46
  47   # library
  48   cp -vr test ./*.{lisp,asd} "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  49   pushd "$pkgdir/usr/share/common-lisp/systems"
  50   ln -s "../source/$_pkgname/$_pkgname.asd" .
  51   ln -s "../source/$_pkgname/$_pkgname-test.asd" .
  52   popd
  53
  54   # documentation
  55   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README
  56
  57   # license
  58   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYING
  59 }