deepin-file-manager/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
   3 # Contributor: Xu Fasheng <fasheng.xu[AT]gmail.com>
   4
   5 pkgname=deepin-file-manager
   6 pkgver=5.8.3
   7 pkgrel=3
   8 epoch=1
   9 pkgdesc='Deepin File Manager'
  10 arch=('x86_64')
  11 url="https://github.com/linuxdeepin/dde-file-manager"
  12 license=('GPL3')
  13 # startdde: for com.deepin.SessionManager
  14 depends=('deepin-qt5integration' 'deepin-anything' 'disomaster' 'docparser' 'file' 'gio-qt'
  15          'libmediainfo' 'lucene++' 'avfs' 'polkit-qt5' 'poppler' 'ffmpegthumbnailer' 'jemalloc'
  16          'kcodecs' 'startdde' 'htmlcxx' 'libgsf' 'mimetic' 'boost-libs' 'taglib')
  17 makedepends=('boost' 'qt5-tools' 'deepin-dock' 'deepin-movie' 'deepin-gettext-tools')
  18 optdepends=('deepin-manual: for help menual'
  19             'deepin-shortcut-viewer: for shortcut display'
  20             'deepin-screensaver: for screensaver chooser'
  21             'deepin-movie: for video preview'
  22             'deepin-terminal: for opening in terminal'
  23             'deepin-compressor: for compress/decompress')
  24 groups=('deepin')
  25 provides=('deepin-desktop')
  26 conflicts=('deepin-desktop')
  27 replaces=('deepin-desktop')
  28 source=("https://github.com/linuxdeepin/dde-file-manager/archive/$pkgver/$pkgname-$pkgver.tar.gz"
  29         $pkgname-fix-crash-426.patch::https://github.com/linuxdeepin/dde-file-manager/pull/426.patch)
  30 sha512sums=('0d3cd2335714a66359e1b98a9acaae09f49660dd51c7f479e867c54b2f8add7726afdc2002fa31dcf178c7ede48364e3688cd51f5483fd6e71bd0cf67217a5f1'
  31             'd27e606930349f906407cd3710894c8ed1080d0a0b9bcfedf01221b830530439b17c369f8c46897ab278b4c083f96ffba64bb024a0e177ccdd716fe5b82d6685')
  32
  33 prepare() {
  34   cd dde-file-manager-$pkgver
  35   patch -p1 -i ../$pkgname-fix-crash-426.patch
  36   sed -e 's|systembusconf.path = /etc/dbus-1/system.d|systembusconf.path = /usr/share/dbus-1/system.d|' \
  37       -i src/dde-file-manager-daemon/dde-file-manager-daemon.pro
  38 }
  39
  40 build() {
  41   cd dde-file-manager-$pkgver
  42   qmake-qt5 PREFIX=/usr filemanager.pro
  43   make
  44 }
  45
  46 package() {
  47   cd dde-file-manager-$pkgver
  48   make INSTALL_ROOT="$pkgdir" install -j1
  49 }