dzen2/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Mark Taylor <skymt0@gmail.com>
   4
   5 pkgname=dzen2
   6 pkgver=0.9.5.14.488ab66
   7 _commit=488ab66019f475e35e067646621827c18a879ba1
   8 pkgrel=2
   9 pkgdesc='General purpose messaging, notification and menuing program for X11'
  10 url='https://github.com/robm/dzen'
  11 arch=('x86_64')
  12 license=('MIT')
  13 depends=('libx11' 'libxpm' 'libxinerama' 'libxft')
  14 makedepends=('git')
  15 source=(${pkgname}::"git+https://github.com/robm/dzen#commit=${_commit}")
  16 sha512sums=('SKIP')
  17
  18 pkgver() {
  19   cd ${pkgname}
  20   printf "%s.%s.%s" "$(grep 'VERSION = ' config.mk|cut -d' ' -f3|cut -d- -f1)" \
  21     "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  22 }
  23
  24 prepare() {
  25   cd ${pkgname}
  26   sed -i 's|DZEN_XMP|DZEN_XPM|g' main.c
  27
  28   CFLAGS="${CFLAGS} -Wall -Os \${INCS} -DVERSION=\\\"\${VERSION}\\\" -DDZEN_XINERAMA -DDZEN_XPM -DDZEN_XFT `pkg-config --cflags xft`"
  29   LIBS=" -L/usr/lib -lc -lXft -lXpm -lXinerama -lX11"
  30
  31   echo "CFLAGS=${CFLAGS}" >> config.mk
  32   echo "LIBS=${LIBS}" >> config.mk
  33   echo "LDFLAGS=${LDFLAGS} ${LIBS}" >> config.mk
  34 }
  35
  36 build() {
  37   cd ${pkgname}
  38   make X11INC=/usr/include X11LIB=/usr/lib
  39   make -C gadgets X11INC=/usr/include X11LIB=/usr/lib
  40 }
  41
  42 package() {
  43   cd ${pkgname}
  44   make PREFIX=/usr MANPREFIX=/usr/man DESTDIR="${pkgdir}" install
  45   make -C gadgets PREFIX=/usr MANPREFIX=/usr/man DESTDIR="${pkgdir}" install
  46   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  47   install -Dm 644 README* -t "${pkgdir}/usr/share/doc/${pkgname}"
  48 }
  49
  50 # vim: ts=2 sw=2 et: