libmemcached-awesome/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2
   3 pkgname=libmemcached-awesome
   4 pkgver=1.1.4
   5 pkgrel=2
   6 pkgdesc="C/C++ client library and tools for the memcached server"
   7 arch=('x86_64')
   8 url="https://awesomized.github.io/libmemcached/"
   9 license=('BSD')
  10 depends=('gcc-libs' 'libsasl' 'libevent')
  11 makedepends=('cmake' 'memcached' 'python-sphinx' 'python-sphinx_rtd_theme')
  12 provides=('libmemcached')
  13 conflicts=('libmemcached')
  14 replaces=('libmemcached')
  15 options=('!debug') # some interaction with FIXTURES_OPTIONS_CONFIG makes it
  16                    # look in the wrong directory (/usr/src/..) for the file
  17 source=(https://github.com/awesomized/libmemcached/archive/$pkgver/$pkgname-$pkgver.tar.gz)
  18 sha256sums=('c477e1f6510e1dc698e84f3717ce690a8f65b94c616ecaa62306cce0f5e3116a')
  19
  20 build() {
  21   CFLAGS+=' -ffat-lto-objects'
  22   CXXFLAGS+=' -ffat-lto-objects'
  23
  24   cmake -B build -S libmemcached-$pkgver \
  25     -DCMAKE_BUILD_TYPE=None \
  26     -DCMAKE_INSTALL_PREFIX=/usr \
  27     -DBUILD_DOCS=ON \
  28     -DBUILD_DOCS_MANGZ=OFF \
  29     -DBUILD_TESTING=ON \
  30     -DENABLE_SASL=ON \
  31     -DENABLE_HASH_HSIEH=ON \
  32     -DENABLE_HASH_FNV64=ON \
  33     -DENABLE_HASH_MURMUR=ON \
  34     -DENABLE_MEMASLAP=ON \
  35     -DENABLE_OPENSSL_CRYPTO=ON
  36   cmake --build build
  37 }
  38
  39 check() {
  40   cd build
  41   ctest --output-on-failure
  42 }
  43
  44 package() {
  45   DESTDIR="$pkgdir" cmake --install build
  46   install -Dm644 libmemcached-$pkgver/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  47 }
  48
  49 # vim:set ts=2 sw=2 et: