librdkafka/trunk/PKGBUILD

   1 # Maintainer: Anatol Pomozov
   2 # Contributor: Andrew Sun <adsun701 at gmail dot com>
   3 # Contributor: Joel Teichroeb <joel at teichroeb dot net>
   4 # Contributor: Alim Gokkaya <alimgokkaya at gmail dot com>
   5
   6 pkgname=librdkafka
   7 pkgver=2.1.1
   8 pkgrel=1
   9 pkgdesc='The Apache Kafka C/C++ library'
  10 arch=(x86_64)
  11 url='https://github.com/edenhill/librdkafka'
  12 license=(BSD)
  13 depends=(
  14   curl
  15   gcc-libs
  16   glibc
  17   libsasl
  18   lz4
  19   openssl
  20   zlib
  21   zstd
  22 )
  23 makedepends=(python rapidjson)
  24 source=(librdkafka-$pkgver.tar.gz::https://github.com/edenhill/librdkafka/archive/v$pkgver.tar.gz)
  25 sha256sums=('7be1fc37ab10ebdc037d5c5a9b35b48931edafffae054b488faaff99e60e0108')
  26
  27 build() {
  28   cd $pkgname-$pkgver
  29   ./configure --prefix=/usr
  30   make
  31 }
  32
  33 check() {
  34   make -k check -C $pkgname-$pkgver
  35 }
  36
  37 package() {
  38   make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  39   install -vDm 644 $pkgname-$pkgver/LICENSE* -t "$pkgdir/usr/share/licenses/$pkgname/"
  40 }