librepo/trunk/PKGBUILD

   1 # Contributor: larchunix
   2 # Maintainer: Jelle van der Waa <jelle@archlinux.org>
   3
   4 pkgname=librepo
   5 pkgver=1.15.1
   6 pkgrel=2
   7 pkgdesc="Repodata downloading library"
   8 arch=('x86_64')
   9 url="https://github.com/rpm-software-management/$pkgname"
  10 license=('GPL')
  11 depends=('curl' 'glib2' 'gpgme' 'libxml2' 'openssl')
  12 makedepends=('cmake' 'python')
  13 checkdepends=('check' 'python-gpgme' 'python-pyxattr' 'python-requests')
  14 optdepends=('python: for python bindings')
  15 source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz" "gpgme-config.patch")
  16 sha256sums=('4af9edb3219030d35f4972ce520444f7534bd9c94729456ec0aea76e868a103a'
  17             'b72de91a72209c37fd58edd76422d8aa862aceb3309ab7b70d1ac2f5fcbb503f')
  18
  19 prepare() {
  20   cd "$pkgname-$pkgver"
  21   # https://github.com/rpm-software-management/librepo/issues/269
  22   patch -Np1 -i ${srcdir}/gpgme-config.patch
  23 }
  24
  25 build() {
  26   cd "$pkgname-$pkgver"
  27
  28   cmake -B build \
  29         -DCMAKE_BUILD_TYPE=None \
  30         -DCMAKE_C_FLAGS_RELEASE='-DNDEBUG' \
  31         -DCMAKE_INSTALL_PREFIX=/usr \
  32         -DCMAKE_INSTALL_LIBDIR=lib \
  33         -DENABLE_DOCS=OFF \
  34         -DENABLE_PYTHON=ON \
  35             -DWITH_ZCHUNK=OFF
  36
  37   make -C build
  38 }
  39
  40 check() {
  41   cd "$pkgname-$pkgver"
  42
  43   make -C build ARGS="-V" test
  44 }
  45
  46 package() {
  47   cd "$pkgname-$pkgver"
  48
  49   make -C build DESTDIR="$pkgdir/" install
  50
  51   install -Dp -m644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  52 }