librtmp0/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: xduugu <xduugu@gmx.com>
   4 # Contributor: Elis Hughes <elishughes@googlemail.com>
   5 # Contributor: kaptoxic <kaptoxic@yahoo.com>
   6 # Contributor: Arthur Skowronek <eisensheng@mailbox.org>
   7
   8 pkgname=librtmp0
   9 pkgver=2.4
  10 pkgrel=5
  11 pkgdesc='Toolkit for RTMP streams'
  12 arch=('x86_64')
  13 url='https://rtmpdump.mplayerhq.hu/'
  14 license=('GPL2' 'LGPL2.1')
  15 depends=('glibc' 'gnutls' 'zlib')
  16 makedepends=('git')
  17 provides=('librtmp.so')
  18 options=('!makeflags')
  19 _commit='c28f1bab7822de97353849e7787b59e50bbb1428'
  20 source=("git+https://git.ffmpeg.org/rtmpdump#commit=${_commit}")
  21 sha256sums=('SKIP')
  22
  23 prepare() {
  24   cd rtmpdump
  25   git cherry-pick -n eea470fa5f9a5481a36dedd257549595ef7480d6
  26   git cherry-pick -n 8e3064207fa7535baad07fd06b65630ec8b31a08
  27   git cherry-pick -n 7340f6dbc6b3c8e552baab2e5a891c2de75cddcc
  28 }
  29
  30 build() {
  31   cd rtmpdump
  32   sed -e 's/^CRYPTO=OPENSSL/#CRYPTO=OPENSSL/' -e 's/#CRYPTO=GNUTLS/CRYPTO=GNUTLS/' -i Makefile -i librtmp/Makefile
  33
  34   make \
  35     OPT="$CFLAGS" \
  36     XLDFLAGS="$LDFLAGS"
  37 }
  38
  39 package() {
  40   cd rtmpdump
  41
  42   make \
  43     prefix='/usr' \
  44     sbindir='/usr/bin' \
  45     mandir='/usr/share/man' \
  46     DESTDIR="${pkgdir}" \
  47     install
  48   rm -rf "${pkgdir}"/usr/{bin,include,lib/{librtmp.{a,so},pkgconfig},share}
  49 }
  50
  51 # vim: ts=2 sw=2 et: