menyoki/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2
   3 pkgname=menyoki
   4 pkgver=1.7.0
   5 pkgrel=1
   6 pkgdesc="Screen{shot,cast} and perform ImageOps on the command line"
   7 arch=('x86_64')
   8 url="https://github.com/orhun/menyoki"
   9 license=('GPL3')
  10 depends=('gcc-libs' 'libxrandr' 'libsixel')
  11 makedepends=('cargo')
  12 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  13 sha512sums=('fca337a78a4dddfde3b1fde2d42a33df098a868e50fe324c710354834acb8e5198e4112c52441a78e763cd9a875feb0d020af13c7a5305385d580dc34d7ce7f9')
  14 options=('!lto')
  15
  16 prepare() {
  17   cd "$pkgname-$pkgver"
  18   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  19 }
  20
  21 build() {
  22   cd "$pkgname-$pkgver"
  23   cargo build --release --frozen --features sixel
  24 }
  25
  26 check() {
  27   cd "$pkgname-$pkgver"
  28   cargo test --frozen
  29 }
  30
  31 package() {
  32   cd "$pkgname-$pkgver"
  33   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  34   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  35   install -Dm 644 "man/$pkgname.1" -t "$pkgdir/usr/share/man/man1"
  36   install -Dm 644 "man/$pkgname.conf.5" -t "$pkgdir/usr/share/man/man5"
  37   install -Dm 644 "completions/$pkgname.bash" "${pkgdir}/usr/share/bash-completion/completions/$pkgname"
  38   install -Dm 644 "completions/$pkgname.fish" -t "${pkgdir}/usr/share/fish/completions"
  39   install -Dm 644 "completions/$pkgname.zsh" "${pkgdir}/usr/share/zsh/site-functions/_$pkgname"
  40 }