python-flask/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Alexander Rødseth <rodseth@gmail.com>
   3 # Contributor: Thomas Dziedzic < gostrc at gmail >
   4 # Contributor: Tarmo Heiskanen <turskii@gmail.com>
   5
   6 pkgname=python-flask
   7 pkgver=2.2.5
   8 pkgrel=1
   9 pkgdesc='Micro webdevelopment framework for Python'
  10 url='http://flask.pocoo.org/'
  11 arch=('any')
  12 license=('custom:BSD')
  13 depends=('python-werkzeug' 'python-jinja' 'python-itsdangerous' 'python-click')
  14 makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')
  15 checkdepends=('python-pytest')
  16 optdepends=(
  17   'python-asgiref: async functions and views'
  18   'python-dotenv: loading env vars from files'
  19 )
  20 source=("$pkgname-$pkgver.tar.gz::https://github.com/pallets/flask/archive/${pkgver}.tar.gz")
  21 sha512sums=('6669b3bd8dcb303a7a8d291e4326e05a097e569a255dc6621a64a0261aba16acd4cba6913e5ff5e45f0cd1647c2d147dfa3a49755c5419d805e982aa49887d13')
  22
  23 build() {
  24   cd "flask-$pkgver"
  25   python -m build --wheel --no-isolation
  26 }
  27
  28 check() {
  29   cd "flask-$pkgver"
  30   PYTHONPATH="build/lib" pytest
  31 }
  32
  33 package() {
  34   cd "flask-$pkgver"
  35   python -m installer --destdir="$pkgdir" dist/*.whl
  36   install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
  37 }
  38
  39 # vim:set ts=2 sw=2 et: