python-kombu/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: mutantmonkey <aur@mutantmonkey.in>
   3
   4 pkgname=python-kombu
   5 pkgver=5.2.4
   6 pkgrel=2
   7 pkgdesc='A messaging library for Python'
   8 arch=('any')
   9 url="https://kombu.readthedocs.org/"
  10 license=('BSD')
  11 options=('!emptydirs')
  12 depends=('python-amqp' 'python-vine')
  13 optdepends=('python-boto3: for Amazon SQS support'
  14             'python-brotli: for brotli compression support'
  15             'python-librabbitmq: C optimization for AMQP transport'
  16             'python-msgpack: for MessagePack support'
  17             'python-pycurl: for Amazon SQS support'
  18             'python-pymongo: for MongoDB support'
  19             'python-pyro: for Pyro support'
  20             'python-redis: for Redis support'
  21             'python-sqlalchemy: for SQLAlchemy support'
  22             'python-yaml: for YAML support'
  23             'python-zstandard: for zstd compression support')
  24             # 'python-consul: for Consul K/V store Transport support': Not packaged yet
  25             # 'python-etcd: for etcd support': Not packaged yet
  26             # 'python-kazoo: for Zookeeper support': Not packaged yet
  27             # 'python-pycouchdb: for CouchDB support': Not packaged yet
  28             # 'python-softlayer-messaging: for SoftLayer Message Queue support': Not packaged yet
  29 makedepends=('python-setuptools')
  30 checkdepends=('python-boto3' 'python-brotli' 'python-case' 'python-librabbitmq' 'python-msgpack' 'python-pycurl'
  31               'python-pymongo' 'python-pyro' 'python-pytest' 'python-pytest-sugar' 'python-pytz'
  32               'python-redis' 'python-sqlalchemy' 'python-yaml')
  33 source=("https://github.com/celery/kombu/archive/v$pkgver/$pkgname-$pkgver.tar.gz"
  34         "fix-requirements.patch")
  35 sha512sums=('8a7bcf3e7f94f7653d6c74a2ea15034c731a27a414d00dde008c31ffa8d292a15e8cc27a44c1f23541f24c863297f0cd11104d2bffaaa512c87526c704be5bcf'
  36             '7beefe78a25f305b8c0d6e9812291c78ed6cfc0c4d167092bbcd86423e020263b2f1af74d959a6e571791198851fe559175de8ca8fd6e4eaaf29ca54b61312bc')
  37
  38 prepare() {
  39   cd kombu-$pkgver
  40   sed -i "/import azureservicebus/i pytest.importorskip('azure.servicebus')" t/unit/transport/test_azureservicebus.py
  41
  42   patch -Np1 -i ${srcdir}/fix-requirements.patch
  43 }
  44
  45 build() {
  46   cd kombu-$pkgver
  47   python setup.py build
  48 }
  49
  50 check() {
  51   cd kombu-$pkgver
  52   python -m pytest
  53 }
  54
  55 package() {
  56   cd kombu-$pkgver
  57   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  58   install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  59 }