python-osqp/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2
   3 _pyname=osqp
   4 pkgname=python-$_pyname
   5 pkgver=0.6.2.post9
   6 pkgrel=1
   7 pkgdesc='Python wrapper for OSQP: the Operator Splitting QP Solver'
   8 url='https://osqp.org/'
   9 license=(Apache)
  10 arch=(x86_64)
  11 depends=(python-scipy python-qdldl)
  12 makedepends=(python-build python-installer python-setuptools python-wheel cmake)
  13 checkdepends=(python-pytest intel-oneapi-mkl)
  14 source=(https://pypi.org/packages/source/${_pyname:0:1}/$_pyname/$_pyname-$pkgver.tar.gz)
  15 sha256sums=('16b03bc7c5db921de0d97a308ed874d21af9080660eddd5e7cadb2ba3428b0ff')
  16
  17 build() {
  18   cd $_pyname-$pkgver
  19   python -m build --wheel --no-isolation --skip-dependency-check
  20 }
  21
  22 check() {
  23   cd $_pyname-$pkgver
  24   python -m venv --system-site-packages test-env
  25   test-env/bin/python -m installer dist/*.whl
  26   test-env/bin/python -m pytest -v
  27 }
  28
  29 package() {
  30   cd $_pyname-$pkgver
  31   python -m installer --destdir="$pkgdir" dist/*.whl
  32   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  33 }