python-pycryptodome/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
   4
   5 pkgname='python-pycryptodome'
   6 pkgver=3.17.0
   7 pkgrel=2
   8 license=('BSD')
   9 arch=('x86_64')
  10 pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 3."
  11 url='https://www.pycryptodome.org/'
  12 depends=('python' 'gmp')
  13 makedepends=('gmp' 'python-'{build,installer,wheel} 'python-setuptools')
  14 conflicts=('python-crypto')
  15 provides=('python-crypto')
  16 replaces=('python-crypto')
  17 source=("pycryptodome-${pkgver}.tar.gz::https://github.com/Legrandin/pycryptodome/archive/v${pkgver}.tar.gz")
  18 sha512sums=('c0a0754c0dd1d8138e8dd27c034e3f3469237eb5f205d86d0c5e2377fd7672c6ed0df9717292a73d380daaabe88c3be80b575ca1149f4c70f08d82aed0d4b39c')
  19
  20 build() {
  21   cd "$srcdir/pycryptodome-$pkgver"
  22   python -m build -wn
  23 }
  24
  25 check() {
  26   cd "$srcdir/pycryptodome-$pkgver"
  27   python -m unittest discover
  28 }
  29
  30 package() {
  31   cd "pycryptodome-$pkgver"
  32   python -m installer -d "$pkgdir" dist/*.whl
  33   install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
  34
  35   rm -r "$pkgdir"/usr/lib/python3.*/site-packages/Crypto/SelfTest/
  36 }